;;;;;;;;;;;;;;;;;;;
;;;  VARIABLES  ;;;
;;;;;;;;;;;;;;;;;;;

globals
[ electric-field
  contact?
  trail-color
  streamer-color
  streamers-out?
  strike-id
  cloud-height
  ground-height
]

breeds
[ vapors         ;; electrically neutral water vapor
  positrons      ;; positively charged particles
  electrons      ;; negatively charged particles
]

turtles-own
[ location ]

patches-own 
[ plocation
  plasma-count   ;; used to delay transformation of plasma back into air
  plasma-id      ;; number of electron that 'burned' through here
  resistance     ;; 0 to 1 scale of how difficult it is ionize this air
]

;;;;;;;;;;;;;;
;;;  MAIN  ;;;
;;;;;;;;;;;;;;

to setup
  ca
  set cloud-height screen-edge-y - 8
  set ground-height 8 - screen-edge-y
  set-default-shape turtles "circle"
  set-default-shape electrons "electron"
  set-default-shape positrons "positron"
  set electric-field 0
  set contact? false
  set trail-color 119
  set streamer-color white
  set strike-id -1
  set streamers-out? false
  build-world
  place-ground-charges
end

to go
  if contact? 
  [ strike ]
  every 0.2
  [ run-water-cycle
    move-charges
    create-path
  ]
end

;;;;;;;;;;;;;;;
;;;  SETUP  ;;;
;;;;;;;;;;;;;;;

to build-world
  ask patches
  [ set plasma-id -1
    set resistance 1
    set plocation "world"
    set plasma-count 5
  ]
  ask patches with [ pycor < ground-height ]
  [ ifelse ( pycor < 2 - screen-edge-y or
           ( pxcor > 10 - screen-edge-x and
             pxcor < -10 + screen-edge-x ) )
    [ set pcolor brown ]
    [ set pcolor blue 
      set plocation "water"
    ]
  ]
  ask patches with [ pycor > cloud-height ] 
  [ set pcolor grey ]
  ask patches with [ pycor >= ground-height and pycor <= cloud-height ]
  [ set pcolor black
    set resistance ( random 100 ) / 100
    set plocation "air"
  ]
end

to place-ground-charges
  create-custom-positrons 60
  [ set location "ground"
    set xcor ( screen-edge-x - 11 - random ( 2 * screen-edge-x - 21 ) )
    set ycor ( ground-height - 1 - random 8 )
    set color orange
  ]
  create-custom-electrons 60
  [ set location "ground"
    set xcor ( screen-edge-x - 11 - random ( 2 * screen-edge-x - 21 ) )
    set ycor ( ground-height - 1 - random 8 )
    set color yellow
  ]
end

;;;;;;;;;;;;;;;;;;;;;
;;;  WATER CYCLE  ;;;
;;;;;;;;;;;;;;;;;;;;;

to run-water-cycle
  evaporate
  precipitate
  vapor-advance
end

to evaporate
  if ((( random 10 ) / 10 ) < evaporation-rate )
  [ create-custom-vapors 1 
    [ set location "air"
      set xcor (-1 * screen-edge-x + ( random 11 ))  ;; somewhere in the water
      set ycor ground-height - 1                   ;; water's surface
      set heading 0
      set color cyan
    ]
  ]
end

to precipitate
  if (( any electrons with [ location = "cloud" ] ) and
      (( random 10 ) / 10 ) < precipitation-rate )
  [ ask random-one-of electrons with [ location = "cloud"   ] [ die ]
    ask random-one-of positrons with [ location = "cloud"   ] [ die ]
    set electric-field ( electric-field - 1 )
    create-custom-vapors 1 
    [ set location "air"
      set xcor ( screen-edge-x - ( random 11 ))    ;; somewhere over the water
      set ycor cloud-height + 1
      set heading 180
      set color cyan
    ]
  ]
end

to vapor-advance
  ask vapors [ fd 1 ]
  while [ any vapors with [ ycor > cloud-height ] ]
  [ ask random-one-of vapors with [ ycor > cloud-height ]
      [ die ]
    create-custom-electrons 1
    [ set location "cloud"
      set xcor ( screen-edge-x - random ( 2 * screen-edge-x ))
      set ycor ( cloud-height + 1 + random 3 )
      set color yellow
    ]
    create-custom-positrons 1
    [ set location "cloud"
      set xcor ( screen-edge-x - random ( 2 * screen-edge-x ))
      set ycor ( cloud-height + 6 + random 3 )
      set color orange
    ]
    set electric-field ( electric-field + 1 )
  ]
  while [ any vapors with [ ycor < ground-height ] ]
  [ ask random-one-of vapors with [ ycor < ground-height ] 
    [ die ]
  ]
end

;;;;;;;;;;;;;;;;;;;;;;;;;
;;;  CHARGE MOVEMENT  ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;

to move-charges
  no-display
  
  ;; charges in the gorund
  ask positrons with [ location = "ground" ]
  [ if (( random electric-field ) > 40 )
    [ set heading towards-nowrap random-one-of electrons with [ location != "ground" ]
      fd 1
      if ( ycor > ground-height - 1 ) [ set ycor ground-height - 1 - ( random 3 ) ]
      if ( xcor < -1 * screen-edge-x + 10 ) [ set xcor -1 * screen-edge-x + 11 ]
      if ( xcor > screen-edge-x - 10) [ set xcor screen-edge-x - 11 ]
    ]
  ]
  ask electrons with [ location = "ground" ]
  [ if (( random electric-field ) > 40 )
    [ set heading 180 + towards-nowrap random-one-of electrons with [ location != "ground" ]
      fd 1
      if ( ycor < ground-height - 8 or ycor > 0 ) [set ycor 3 - screen-edge-y - random 3 ]
      if ( xcor < -1 * screen-edge-x + 11 ) [ set xcor -1 * screen-edge-x + 12 ]
      if ( xcor > screen-edge-x - 11) [ set xcor screen-edge-x - 12 ]
    ]
  ]
  
  ;; charges in the cloud
  ask positrons with [ location = "cloud" ]
  [ set heading random 360
    fd 1
    if ( ycor < screen-edge-y - 2 ) [ set ycor ( cloud-height + 6 + random 3 ) ]
  ]
  ask electrons with [ location = "cloud" ]
  [ ifelse pcolor-of patch-at 0 -1 != grey and
           pcolor-of patch-at 0 -1 != black
    [ set location "follower"
      set ycor ( ycor - 1 )
      ask patch-here
      [ set pcolor trail-color
        set plasma-count 5
      ]
    ]
    [ set heading random 360
      fd 1
      if ( ycor < cloud-height + 1 ) [ set ycor ( cloud-height + 1 + random 3 ) ]
      if ( ycor > cloud-height + 3 ) [ set ycor ( cloud-height + 1 + random 3 ) ]
    ]
  ]
  display
end

;;;;;;;;;;;;;;;;;;;;;;;
;;;  PATH CREATION  ;;;
;;;;;;;;;;;;;;;;;;;;;;;

to create-path
  if( electric-field > 80 )
  [ go-leaders
    go-streamers
  ]
  dissipate-path
end

to go-leaders
  ;; choose electrons to act as leaders
  if ( random 100 >= 90 and any electrons with [ ycor = cloud-height + 1 and 
                                                 not any neighbors with [ pcolor = trail-color ] ])
  [ ask random-one-of electrons with [ ycor = cloud-height + 1 and
                                       not any neighbors with [ pycor < ycor-of myself and pcolor != black ] ]
    [ setxy pxcor-of min-one-of neighbors with [ pycor < pycor-of myself ] [ resistance ]
            pycor-of min-one-of neighbors with [ pycor < pycor-of myself ] [ resistance ]
      set location "leader"
      ask patch-here
      [ set plasma-id who-of myself
        set plasma-count 5
        set pcolor trail-color
      ]
    ]
  ]
  
  ;; advance leading electrons
  ask electrons with [ location = "leader" ]
  [ ifelse any neighbors with [ pcolor = streamer-color or pcolor = brown ]
    [ set contact? true
      ifelse any neighbors with [ pcolor = streamer-color ]
      [ set strike-id plasma-id-of random-one-of neighbors with [ pcolor = streamer-color ]
        ask patches with [ pcolor = streamer-color and pycor > ycor-of myself and plasma-id = strike-id ]
        [ set pcolor black
          set plasma-id -1
          set resistance 1
          if any turtles-here
          [ ask random-one-of turtles-here [ die ] ]
        ]
      ]
      [ set strike-id who
        ask random-one-of neighbors with [ pcolor = brown ]
        [ set plasma-id strike-id ]
      ]
    ]
    [ ifelse any neighbors with [ pcolor = trail-color and pycor < ycor-of myself ]
      [ set location "follower" ]
      [ if random 10 < 5
        [ setxy pxcor-of min-one-of neighbors with [ ( pycor < ycor-of myself ) ] [ resistance ]
                pycor-of min-one-of neighbors with [ ( pycor < ycor-of myself ) ] [ resistance ]
          ask patch-here
          [ set plasma-id who-of myself
            set plasma-count 5
            set pcolor trail-color
          ]
        ]
      ]
    ]
  ]
  
  ;; advance following electrons, some may become leaders
  ask electrons with [ location = "follower" ]
  [ ifelse (( random 100 < 5 ) and 
            ( count neighbors with [ pycor < ycor-of myself and pcolor = black ] = 2 ))
    [ set location "leader"
      setxy pxcor-of min-one-of neighbors with [ ( pycor < ycor-of myself ) and ( pcolor = black ) ] [ resistance ]
            pycor-of min-one-of neighbors with [ ( pycor < ycor-of myself ) and ( pcolor = black ) ] [ resistance ]
      ask patch-here [ set plasma-id who-of myself ]
    ]
    [ if random 10 < 5 and any neighbors with [ pycor < ycor-of myself and pcolor != black ]
      [ setxy pxcor-of random-one-of neighbors with [ pycor < ycor-of myself and pcolor != black ]
              pycor-of random-one-of neighbors with [ pycor < ycor-of myself and pcolor != black ]
      ]
    ]
    ask patch-here
    [ set pcolor trail-color
      set plasma-count 5
    ]
  ]
end

to dissipate-path
  ask patches with [ plocation = "air" and pcolor != black and pcolor != streamer-color ]
  [ set plasma-count ( plasma-count - 1 )
    if (plasma-count < 0 )
    [ set pcolor ( pcolor - 1 )
      if (pcolor mod 10 = 0 ) [ set pcolor black ]
      set plasma-count 5
    ]
  ]
end

;;;;;;;;;;;;;;;;;;;
;;;  STREAMERS  ;;;
;;;;;;;;;;;;;;;;;;;

to go-streamers
  if( electric-field = 120 )
  [ create-streamers ]
  if( streamers-out? = true and electric-field < 120 )
  [ destroy-streamers ]
end

to create-streamers
  repeat random 10
  [ if any positrons with [ ycor = ground-height - 1 ]
    [ ask random-one-of positrons with [ ycor = ground-height - 1 ]
      [ ask patch-here [ set plasma-id who-of myself ]
        setxy pxcor-of min-one-of neighbors with [ pycor > ycor-of myself ] [ resistance ]
              pycor-of min-one-of neighbors with [ pycor > ycor-of myself ] [ resistance ]
        ask patch-here
        [ set plasma-id who-of myself
          set pcolor streamer-color
        ]
        set location "streamer"
        ;; grow each streamer to a random length
        repeat random 10
        [ setxy pxcor-of min-one-of neighbors with [ pycor > ycor-of myself ] [ resistance ]
                pycor-of min-one-of neighbors with [ pycor > ycor-of myself ] [ resistance ]
          ask patch-here
          [ set plasma-id who-of myself
            set pcolor streamer-color
          ]
        ]
      ]
    ]
  ]
  set streamers-out? true
end

to destroy-streamers
  ask positrons with [ location = "streamer" ] [ die ]
  ask patches with [ pcolor = streamer-color ]
  [ set pcolor black
    set plasma-id -1
  ]
  ask patches with [ plasma-id != -1 and pcolor = brown ]
  [ set plasma-id -1 ]
  set streamers-out? false
end

;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;  LIGHTNING STRIKE  ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;

to strike
  ;; destroy streamers
  ask patches with [ pcolor = streamer-color ]
  [ ifelse( plasma-id = strike-id )
    [ set pcolor trail-color 
      set plasma-count 5
    ]
    [ set pcolor black
      set plasma-id -1
      set resistance 1
      while [ any turtles-here ]
      [ ask random-one-of turtles-here [ die ] ]
    ]
  ]
  ask positrons with [ location = "streamer" ]
  [ set location "strike" ]
  
  ;; strike
  while [ electric-field > 20 ]
  [ positron-strike
    electron-strike
    dissipate-path
  ]
  
  ;; cleanup
  ask patches [ set plasma-id -1 ]
  ask patches with [ plocation = "air" ]
  [ set resistance ( random 100 ) / 100 ]
  ;; prevent electrons from moving from cloud into strike before it dissipates
  ask patches with [ pycor = cloud-height ] 
  [ set pcolor black ]
  ;; in case strike went through water
  ask patches with [ plocation = "water" ] [ set pcolor blue ]
  ask positrons with [ location = "strike" ] [ die ]
  ask electrons with [ location = "leader" or location = "follower" ] 
  [ set location "cloud" ]
  ask turtles with [ location = "ground" ] [ die ]
  place-ground-charges
  set contact? false
  set electric-field count electrons with [ location = "cloud" ]
end

to positron-strike
  ;; ground positrons flow through plasma path towards cloud
  ifelse( any positrons with [ location = "ground" ] )
  [ ask random-one-of positrons with [location = "ground" ]
    [ set location "strike" 
      setxy pxcor-of random-one-of patches with [ pycor = ground-height and plasma-id = strike-id ] ground-height
      ask patch-here [ set pcolor trail-color ]
    ]
    set electric-field ( electric-field - 1 )
    ask random-one-of electrons with [ location = "cloud" ][ die ]
    ask random-one-of positrons with [ location = "cloud" ][ die ]
  ]
  [ create-custom-positrons 5
    [ set location "ground"
    set xcor ( screen-edge-x - 11 - random ( 2 * screen-edge-x - 21 ) )
    set ycor ( ground-height - 1 - random 8 )
    set color orange
    ]
  ]
  ask positrons with [ location = "strike" ]
  [ ifelse not any neighbors with [ pycor > ycor-of myself and pcolor != black ]
    [ setxy pxcor-of min-one-of neighbors with [ pycor > ycor-of myself ] [ resistance ]
            pycor-of min-one-of neighbors with [ pycor > ycor-of myself ] [ resistance ]
    ]
    [ setxy pxcor-of random-one-of neighbors with [ pycor > ycor-of myself and pcolor != black ]
            pycor-of random-one-of neighbors with [ pycor > ycor-of myself and pcolor != black ]
    ]
    ;; positron's journey ends when it reaches the cloud or encounters an electron
    ifelse pcolor-of patch-here = grey
    [ die ]
    [ ask patch-here [ set pcolor trail-color ]
      if any electrons-here
      [ ask random-one-of electrons-here [ die ]
        die
      ]
    ]
  ]
end

to electron-strike
  if any electrons with [ location = "follower" or location = "leader" ]
  [ ask electrons with [ location = "follower" or location = "leader" ]
    [ ifelse not any neighbors with [ pycor > ycor-of myself and pcolor != black ]
      [ die  ;; stranded in the air
        ask random-one-of positrons with [ location = "cloud" ] [ die ]
        set electric-field ( electric-field - 1 )
      ]
      [ setxy pxcor-of random-one-of neighbors with [ pycor > ycor-of myself and pcolor != black ]
              pycor-of random-one-of neighbors with [ pycor > ycor-of myself and pcolor != black ]
        ifelse pcolor-of patch-here = grey
        [ set location "cloud" ]
        [ ask patch-here [ set pcolor trail-color ] ]
      ]
    ]
  ]
end
@#$#@#$#@
GRAPHICS-WINDOW
26
31
733
388
50
25
7.0
1
10
0
0

CC-WINDOW
410
395
725
494
Command Center

BUTTON
33
394
100
427
NIL
setup
NIL
1
T
OBSERVER

BUTTON
107
394
170
427
NIL
go
T
1
T
OBSERVER

MONITOR
34
429
170
478
Electric Field Strength
electric-field
1
1

SLIDER
207
401
379
434
evaporation-rate
evaporation-rate
0
1
1.0
0.1
1
NIL

SLIDER
207
438
379
471
precipitation-rate
precipitation-rate
0
1.0
0.0
0.1
1
NIL

@#$#@#$#@
WHAT IS IT?
-----------
Lightning is one of the most visually impressive and frequently occurring natural phenomena on Earth.  However, very few people actually have a solid understanding of what causes lightning, how it works, and why it occurs.  This model attempts to illustrate lightning strikes from beginning to end at the very low level of individual charges.  The user will observe how the behavior and interaction of extremely small charges can lead to the very powerful and visually impressive action of a lightning strike.

In order to thoroughly understand the phenomenon of lighting one must have a strong understanding of electrical physics and thermodynamics.  In order to be meaningful this model avoids such complicated topics and instead provides a more general basis for charge and particle behavior.  The emphasis in this model is to understand lightning as it relates to individual charges, not the underlying forces behind the charges themselves.


HOW IT WORKS
------------
The initial cause of a lightning strike is a separation of charge within a cloud.  Positively charged particles accumulate at the top of the cloud while negatively charged particles concentrate themselves at the bottom of the cloud.  Unfortunately, it is currently unknown why this charge separation occurs.  This model illustrates a widely held theory in this respect.  The water cycle itself is the primary cause.  As water vapor rises it often acquires a charge as it interacts with dirt, ice, and other materials during its ascent towards the cloud.  Once in the cloud the heavier vapor particles have a negative charge and thus sink to the cloud's bottom.  The actual mechanism behind the creation of charge separation is unimportant in the actual strike and so the water cycle and charge separation are included in this model solely to demonstrate how the charge separation may occur.  Vapors rise off of the water's surface with a frequency specified by the EVAPORATION-RATE slider.  The vapors then rise toward the sky until they reach the cloud, at which time they spawn opposing charges in the upper and lower regions of the cloud.  The ELECTRIC-FIELD is measured by the number of negatively charged particles (electrons) in the cloud.  Since the strength of an electric field is directly proportional to the amount of charge in that field, this is a reasonable measure.

Within the cloud the charges move in a random manner.  However, they are constrained to their charge regions.  The positive charges do not try to reach the negatives nor vice versa.  In this way the charge separation and electric field strength is maintained.  Occasionally charge may dissipate from the cloud.  While the actual mechanism for this dissipation is also unknown, it is illustrated in this model by precipitation in the same manner as the charge buildup.  Charge leaves the cloud at a rate specified by the PRECIPITATION-RATE slider.  When the EVAPORATION-RATE equals the PRECIPITATION-RATE the strength of ELECTRIC-FIELD will remain fairly constant.

When ELECTRIC-FIELD has strength of 40 or greater the charges in the ground begin to be affected.  The negative charges in the bottom of the cloud have such a high concentration that they force the electrons on the Earth's surface deep into the ground.  This also has the affect of pulling the positive charges (positrons) in the Earth's surface to a very shallow depth.  Thus, the ground has a strong positive charge and the cloud has a strong negative charge.  The two surfaces act like two parallel plates (for those who know a bit of electrical physics).  This charge disparity cannot continue forever, and lightning is nature's solution to the problem.

Charge continues to build until the ELECTRIC-FIELD hits the critical value of 80.  With field strength of such a large magnitude the electrons in the cloud begin "breaking down" the air around the cloud and converting it into plasma.  Plasma is the same material that comprises stars.  Without going into too much detail, plasma is matter (in this case air) that has been ionized.  The positive and negative components of the air itself are pulled apart and separated from each other.  This separation allows the electrons to flow through the plasma much more easily than they could through normal air.  The plasma is created in a chain-reaction manner as electrons flowing through the plasma force the air around them to become plasma in turn.  In this way electrons in the cloud "burn out" paths towards the earth.  The paths are known as "step leaders" and grow from cloud to ground in a tentacle-like manner.  The chain reaction that allows the step leaders to grow in size does not have to take place in a straight line.  Air is not homogenous and is littered with impurities that affect the formation of step leaders.  These impurities cause the air to not ionize equally in all directions.  Impurities in the air may cause some patches of air to turn into plasma more easily than others.  Rather than direct lines from cloud to ground, lightning takes the path of least resistance.  This is what gives lightning strikes the forked and jagged patterns that everyone can recognize.  In this model this is illustrated by assigning each patch of air a RESISTANCE value.  Electrons will ionize air and progress towards the ground always trying to follow the path of least resistance.

As the step leaders progress to the ground the ELECTRICAL-FIELD likely will still be increasing in magnitude.  Once it reaches a value of 120 the charges in the ground react by letting off what are known as "streamers".  Streamers are the positive equivalent of the negative step leaders created by clouds.  However, streamers are not self-sufficient and thus do not grow indefinitely towards the cloud.  All objects on the Earth's surface will emit a streamer, though depending on the size and material of the object the streamer's length may vary.  A tall building will release a larger streamer than a person on the sidewalk.  The streamer's release is what causes people to often feel a tingling sensation before a lightning strike.  The positive charges in the ground are reaching out to the negative charges in the sky.  Streamers are released much more quickly than a step leader since they are much smaller and only extend a very limited distance.

Step leaders progress towards the ground until they encounter either the ground or a streamer.  In both cases the "circuit" is completed and charge may flow freely between cloud and ground.  Since step leaders and streamers grow in an irregular way the strike may occur at an otherwise unexpected place.  It is not uncommon for lightning to strike a 6-foot tall person instead of the 40-foot tree nearby.  Once a connection has been made charges begin to move through the path.  Contrary to popular understanding, the actual lightning strike flows from the ground up.  The large concentration of positive charges on the earth's surface flow very quickly through the plasma stream towards the sky and neutralize the electrons in the cloud.  The flash of light that is seen is the rapid movement of charge through the air, exactly the same as the light you see during a spark of static electricity.  This massive movement of charge results in an enormous current that generates an equally enormous amount of heat around the strike.  The current and heat are what cause damage to people and objects during a lightning strike.  When the strike occurs the air surrounding the lightning's path reaches temperatures hotter than the surface of the sun.

When a step leader completes the path between cloud and ground, the charges that were forming other step leaders quickly flow back up towards the cloud.  This rapid movement of charge causes secondary strikes that usually accompany a lightning strike.  While the step leader that actually makes contact is known as the primary strike, several secondary strikes are often visible for short periods of time in the sky surrounding the cloud.  These strikes do not extend all the way to the ground, but can still be impressive to watch.  There may be several primary strikes within a given lightning strike, but only one set of secondary strikes.  In this model you may observe secondary strikes as the electrons in the step leaders move back into the cloud once contact is made.

Once the massive negative charge in the cloud has been neutralized the flow of charge through the air comes to a stop.  The plasma becomes de-ionized and once again becomes air as the step leaders are destroyed.  The environment is now ready to begin the process anew.


HOW TO USE IT
-------------
To run the model the user needs only press SETUP and then GO.

SETUP - this button builds the 'world' and places charges within the ground.

GO - this button runs the model.  The process will run over and over without ever stopping.

EVAPORATION-RATE - this slider specifies the rate at which water evaporates to the cloud.  With a value of 0 no evaporation will take place.  With a value of 1 water will evaporate with every time step.  Evaporation is directly responsible for the buildup of charge in the cloud.

PRECIPIATION-RATE - this slider specifies the rate at which water precipitates from the cloud.  With a value of 0 no precipitation will take place.  With a value of 1 water will precipitate with every time step.  Precipitation is directly responsible for the dissipation of charge in the cloud.

ELECTRIC-FIELD - this monitor displays the current strength of the electric field between the cloud and the ground.  This value is the number of electrons present in the cloud.


THINGS TO NOTICE
----------------
Observe the forked and irregular pattern formed by the step leaders.  This irregularity is dictated by the random resistances of the air patches and is what gives lightning its distinctive visual appearance.

Observe how the lightning strike itself is actually the flow of positive charges from the ground upwards towards the cloud.  While the path the lightning takes is created by the electrons, it is the positrons that actually move during the strike.

Try and observe the secondary strikes at the very beginning of a primary strike.  These strikes are caused by electrons flowing back into the cloud.


THINGS TO TRY
-------------
What happens when precipitation is less than evaporation?  More than?  Equal?  How does this help explain why lightning does not form in every storm and every cloud?


EXTENDING THE MODEL
-------------------
Create two separate smaller clouds instead of one giant one.  Perhaps allow for cloud-to-cloud lightning strikes as well as cloud-to-ground.

Add various sliders to allow the user to control the thresholds at which step-leaders are formed, charges react to each other, streamers are released, etc.

Add objects on the ground and observe how object height impacts where lightning strikes occur.


CREDITS AND REFERENCES
----------------------
Created by Jason Alt
http://pubweb.northwestern.edu/~jba441/nlogo/Lightning.html
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

circle
false
0
Circle -7566196 true true 35 35 230

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

bee
true
0
Polygon -256 true false 151 152 137 77 105 67 89 67 66 74 48 85 36 100 24 116 14 134 0 151 15 167 22 182 40 206 58 220 82 226 105 226 134 222
Polygon -16777216 true false 151 150 149 128 149 114 155 98 178 80 197 80 217 81 233 95 242 117 246 141 247 151 245 177 234 195 218 207 206 211 184 211 161 204 151 189 148 171
Polygon -7566196 true true 246 151 241 119 240 96 250 81 261 78 275 87 282 103 277 115 287 121 299 150 286 180 277 189 283 197 281 210 270 222 256 222 243 212 242 192
Polygon -16777216 true false 115 70 129 74 128 223 114 224
Polygon -16777216 true false 89 67 74 71 74 224 89 225 89 67
Polygon -16777216 true false 43 91 31 106 31 195 45 211
Line -1 false 200 144 213 70
Line -1 false 213 70 213 45
Line -1 false 214 45 203 26
Line -1 false 204 26 185 22
Line -1 false 185 22 170 25
Line -1 false 169 26 159 37
Line -1 false 159 37 156 55
Line -1 false 157 55 199 143
Line -1 false 200 141 162 227
Line -1 false 162 227 163 241
Line -1 false 163 241 171 249
Line -1 false 171 249 190 254
Line -1 false 192 253 203 248
Line -1 false 205 249 218 235
Line -1 false 218 235 200 144

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 46 130
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150
Polygon -7566196 true true 270 14
Polygon -7566196 true true 276 21

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

electron
false
0
Circle -256 true false 35 34 231
Rectangle -16777216 true false 83 135 219 160

positron
false
0
Circle -44544 true false 33 31 235
Rectangle -16777216 true false 92 132 217 162
Rectangle -16777216 true false 138 92 173 196

@#$#@#$#@
NetLogo 1.2beta2
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@