breeds 
[ 
  human 
  airplane 
  sound 
]

turtles-own 
[ 
  age                    ;; keeps track of the age of soundwaves to determine which sound particles belong to which circular wave
]

globals 
[ 
  clock                  ;; keeps the time as ticks                    
  colorNumber            ;; used to change the colors of soundwaves slightly 
  tempx                  ;; temporary x coordinate to be used in creation of turtles
  tempy                  ;; temporary y coordinate to be used in creation of turtles
  chosen_observerX       ;; x coordinate of the position of the chosen human observer
  chosen_observerY       ;; y coordinate of the position of the chosen human observer
  stopAirplane           ;; if equals to 1, airplane has gotten out of the screen
  terminate              ;; used to terminate the highlighting of the soundwave circles
]

;; PROCEDURE DEFINITION: initializes the global variables and sets up the shapes of turtles
to setup
  ca
  set-default-shape human "human"
  set-default-shape airplane "airplane2"
  set-default-shape sound "sound"
  set colorNumber 12
  set clock 0
  set stopAirplane 0
  set chosen_observerX 0
  set chosen_observerY 0
  set terminate 0
  draw-map                       
end

;; PROCEDURE DEFINITION: draws the initial screen with a plane and 5 human observers
to draw-map
  cg
  ;; make the screen white and draw a black frame
  ask patches
   [ set pcolor white ]
  ask patches with [pycor = (screen-edge-y * -1)]
   [ set pcolor black ]
  ask patches with [pycor = screen-edge-y]
   [ set pcolor black ]
  ask patches with [pxcor = (screen-edge-x * -1)]
   [ set pcolor black ]
  ask patches with [pxcor = screen-edge-x]
   [ set pcolor black ]

  ;; create the initial human observers
  create-custom-human 5 
  [ 
    set size 3
    set color brown
    if (black != (value-from patch-at tempx tempy [ pcolor ]))
       [ setxy (random (screen-size-x - 3)) (-1 * (random (screen-edge-y - 1))) ]
  ]
  
  ;; create the airplane
  create-custom-airplane 1
  [ 
    set size 4
    setxy -80 40
    set heading 90
  ]
end

;; PROCEDURE DEFINITION: to place a human observer randomly at the bottom half of the screen
to place-random-observer
  create-custom-human 1
   [ set size 3
     set color brown
     set tempx (random (screen-size-x - 3))
     set tempy (-1 * (random (screen-edge-y - 1)))
     if (black != (value-from patch-at tempx tempy [ pcolor ]))    ;; do not place the turtle on black edges
       [ setxy tempx tempy ]
   ]
end

;; PROCEDURE DEFINITION: randomly replace 5 human observers at the bottom half of the screen
to relocate-observers
  ask turtles with [ breed = human ] [ die ]
  create-custom-human 5 []
  ask turtles with [ breed = human ]            ;; randomize position of the turtles
  [ set size 3
    set color brown
    if (black != (value-from patch-here [ pcolor ]))
    [ setxy (random (screen-size-x - 1)) (-1 * (random (screen-edge-y - 1))) ] 
  ]
end

;; PROCEDURE DEFINITION: clears all soundwaves from the screen and redraws the airplane at the same initial position
to reset-plane-position
  ask airplane [ die ]
  ask sound [ die ]
  ask human [ set color brown ]
  set colorNumber 12
  create-custom-airplane 1
  [ 
    set size 4
    setxy -80 40
    set heading 90
  ]
end

;; PROCEDURE DEFINITION: 1. increments the clock, 2. moves the plane, 3. generates the soundwave, 4. plots the graph (Forever button)
to go
  set clock (clock + 1)
  move-airplane 
  generate-soundwave
  do-plot
end

;; PROCEDURE DEFINITION: moves the airplane forward one step at a time until it reaches the end of the screen
to move-airplane
 ask turtles with [ breed = airplane ]
  [ ifelse ((value-from (patch-here) [ pxcor ]) < 80)            ;; move forward
      [ fd speed_of_airplane / (740 + (1.34 * Temperature)) ]    ;; divides the airplane speed by the formula of the speed of sound
      [ set stopAirplane 1    ;; kill the turtle when plane reaches the end of screen
        die ]
  ]
end

;; PROCEDURE DEFINITION: forms the soundwaves with different colors by incrementing the colorNumber counter
to generate-soundwave
  set colorNumber (colorNumber + 0.2)
  if (stopAirplane != 1)                  ;; while the airplane is still moving
  [
    create-custom-sound 100               ;; create 100 turtles - all facing outward
    [ set color colorNumber
      set age 0                           ;; initialize the age of the soundwave circle
      set size 2
      setxy (value-from (turtle 5) [ xcor ]) (value-from (turtle 5) [ ycor ]) ]    ;; create the soundwaves where the plane is located
  ]
  ask sound
  [  
    set age (age + 1)                     ;; incrementing the age of soundwaves
    ifelse (pcolor != black)              ;; move the soundwaves forward by 1 if the current patch is not black
    [ 
      fd 1 
      check-human-here
    ]
      [ die ]                           ;; otherwise, kill soundwaves
  ]
end

;; PROCEDURE DEFINITION: checks if any soundwaves are intersecting any human observers
to check-human-here
  locals [ ageList firstAge ]
  if ((count human-here) > 0)        ;; if so, changes color of both the human and soundwaves
  [ 
    ask turtles-here with [breed = human] [ set color green ]                     ;; the waves hitting the human observers are blocked
    ask turtles-here in-radius 3 with [breed = sound] [ set color white]          ;; thus, they become white
    set ageList (values-from turtles with [(breed = sound) and (color = white)] [ age ])       
    set firstAge (first ageList)            ;; get the first age from the list, the first touching wave's age to the human observer
    if ((firstAge > 0) and (terminate = 0)) [ 
      ask sound with [age = firstAge] [ set color blue  ;; highlight the soundwave circle that touches the first observer with blue
                                        set size 3 ]    ;; and enlarge them to make them more visible   
      set terminate 1
    ]
  ]
end 

;; PROCEDURE DEFINITION: forever button to select a human observer on the screen
to choose-observers
  choose-observer
end

;; PROCEDURE DEFINITION: gets the x,y coordinates of the mouse-click and chooses the corresponding human observer
to choose-observer
  locals [ rangeXi rangeXj rangeYi rangeYj ]
  if mouse-down?                    ;; if mouse-click occurs
  [
    ask human with [ color = blue ] [ set color brown ]
    set rangeXi (mouse-xcor - 5)    ;; range variables are for drawing an imaginary square around the turtles
    set rangeXj (mouse-xcor + 5)    ;; so that each mouse-click within a certain patch-radius from the turtle
    set rangeYi (mouse-ycor - 5)    ;; chooses that specific turtle
    set rangeYj (mouse-ycor + 5)
    if ((count turtles with [ ((xcor >= rangeXi) and (xcor <= rangeXj)) and 
                              ((ycor >= rangeYi) and (ycor <= rangeYj)) ]) >= 1)
    [ 
      ask turtles with [ ((xcor >= rangeXi) and (xcor <= rangeXj)) and 
                         ((ycor >= rangeYi) and (ycor <= rangeYj)) ]
                         [ set color blue 
                           set chosen_observerX xcor        ;; set these global variables to the values of the coordinates
                           set chosen_observerY ycor ]      ;; of the chosen observer for further usage
    ]
  ]
end

;; PROCEDURE DEFINITION: draws the two plots: One for the Intensity of the Waves measured by the chosen observer, the other is for speed ratios
to do-plot 
  locals [ rangeXi rangeYi rangeXj rangeYj]
  set-current-plot "Speed Ratios"
  set-current-plot-pen "Speed of Sound" 
  plot (740 + (1.34 * Temperature))        ;; the speed of sound formula
  set-current-plot-pen "Airplane Speed"
  plot Speed_of_airplane
  
  set-current-plot "Intensity of the Waves Heard"
  set-current-plot-pen "Intensity"
  if ((chosen_observerX != 0) and (chosen_observerY != 0)) [         ;; measure the volume of the soundwaves in the imaginary square
    set rangeXi (chosen_observerX - 5)                               ;; that is drawn around the chosen observer to hear all incoming 
    set rangeXj (chosen_observerX + 5)                               ;; soundwaves
    set rangeYi (chosen_observerY - 5)
    set rangeYj (chosen_observerY + 5)
    plot (3.5 * (count turtles with [ ((xcor >= rangeXi) and (xcor <= rangeXj)) and     ;; Multiply it by 3.5 to get the decibel value
                               ((ycor >= rangeYi) and (ycor <= rangeYj)) ]))
  ]
end

@#$#@#$#@
GRAPHICS-WINDOW
388
13
1012
395
90
55
3.447513812154696
1
10
0
1

CC-WINDOW
537
404
852
524
Command Center

BUTTON
18
11
73
44
Setup
setup
NIL
1
T
OBSERVER

BUTTON
94
11
157
44
Go
go
T
1
T
OBSERVER

SLIDER
178
11
367
44
Speed_of_airplane
Speed_of_airplane
1
3750
3750
1
1
mph

BUTTON
18
53
167
86
Place Random Observer
place-random-observer
NIL
1
T
OBSERVER

SLIDER
178
49
338
82
Temperature
Temperature
-100
200
20
1
1
Celcius

PLOT
17
384
378
541
Speed Ratios
time
speeds
0.0
300.0
200.0
3750.0
true
true
PENS
"Speed of Sound" 1.0 0 -65536 true
"Airplane Speed" 1.0 0 -16745473 true

BUTTON
18
97
143
130
Relocate Observers
relocate-observers
NIL
1
T
OBSERVER

BUTTON
18
142
146
175
Reset Plane Position
Reset-plane-position
NIL
1
T
OBSERVER

MONITOR
178
87
306
136
The speed of sound
(740 + (1.34 * Temperature))
3
1

BUTTON
178
143
301
176
Choose Observer
choose-observers
T
1
T
OBSERVER

PLOT
17
186
377
372
Intensity of the Waves Heard
time
volume
0.0
300.0
0.0
200.0
true
true
PENS
"Intensity" 1.0 0 -16776961 true

MONITOR
320
87
377
136
Mach
Speed_of_airplane / \n(740 + (1.34 * Temperature))
3
1

@#$#@#$#@
WHAT IS IT?
-----------
This model explores the behavior of subsonic and supersonic sound waves in the air and human perception of them. As a sidenote, subsonic means the speed being lower than the speed of sound, and supersonic means just the opposite. When an object moves at a speed slower than the speed of sound in the medium, it creates circular shaped sound waves inside one another. However, if the object's speed is faster than the speed of sound in the medium, it creates circular shaped sound waves ahead of one another, thus forming a conical shape of sound waves in the air. 

There is an interesting point to this phenomena. Let's assume there is a plane flying at a subsonic speed over you. You will hear the first sound wave that the plane produces first, the second one secondly, and so on. However, when the plane is flying at a supersonic speed, the speed of sound becomes relatively slow that the first sound wave you hear is not the first one that is created by the plane. In fact, it is one of the sound waves which is created after the first couple of sound waves. In short, there is a "falling behind" issue in supersonic wave creation. Therefore, when a supersonic plane passes over you, you encounter the phenomena called a "Sonic Boom", which is carried over to you by the "Shockwave". Shockwaves are created because of the sound waves(the circles in this model) produced by the plane being separated by a small distance. Therefore, they add up when received by the auditory system, resulting in a short intense thunder-like sound, which is the "Sonic Boom".

In general, when an object moves at a speed faster than the speed of sound in the medium, it creates a region of intense sound. This is the sonic boom created by objects moving at supersonic speed. If a supersonic airplane flies over you, you will hear a sonic boom which will sound like a short thunder-like noise. This short thunder-like noise causes the human auditory system to perceive the direction that the plane is coming from incorrectly. When hearing subsonic sounds, the auditory system is very successful at perceiving the direction of the sounds being created mainly because the sound waves are heard in order. However, supersonic sound waves are mostly heard in different orders so this confuses our auditory system's perception of the direction of sound source.

This model shows you the shapes of these different sound wave types produced by an airplane, the sound wave which hits a human observer in different cases and the sonic boom encountered by the human observer.

IMPORTANT NOTE: Each red particle coming out of the plane represents a sound particle. The circle they form represents the sound waves.

For those who are not familiar with these concepts, the speed of sound changes with varying temperature. Below is the formula that is used in my model to calculate the speed of sound:

|	Speed of Sound (in mph) = 740 + 1.34 * (Temperature)

Also, below is the formula for calculating the Mach Number:

|	Mach Number = Speed of Flying Object / Speed of Sound
	

HOW TO USE IT
-------------
1) Click on SETUP to setup the screen with the airplane and 5 initial human observers.
2) Click on PLACE RANDOM OBSERVER to add any random human observers on the screen.
3) Click on CHOOSE OBSERVER to choose one of the human observers to explore the Sonic Boom and Initial Hitting Sound Wave phenomena.
4) Unclick on CHOOSE OBSERVER after choosing a human observer.
5) Set the Speed of Airplane and Temperature by moving the sliders. You can see how the value of the speed of sound changes in the SPEED OF SOUND monitor. Also, you can view the current mach number in the MACH monitor. 
6) Click on GO to start running the model. You can change the values of the sliders dynamically while running the model. In addition, you can re-click on CHOOSE OBSERVER to change the selected human observer on the screen anytime as the model is running.
7) View the SPEED RATIOS plot to see how the speed of airplane and the speed of sound changes according to your dynamic changes in the sliders.
8) View the INTENSITY OF THE WAVES HEARD plot to see the Sonic Boom and the intensity of sound waves in the selected human observer's hearing radius with respect to time. 

Note: Do not try to reset plane position while the plane is flying (the GO button is on). First, stop the plane and then reset its position.

THINGS TO NOTICE
----------------
When the airplane is flying below Mach 1, the sound waves it generates form a circular shape as a whole. However, when the airplane exceeds Mach 1, then the sound waves it generates form a conical shape as a whole. This is explained by the "falling behind" phenomena, mentioned above in the second paragraph.

Note that Sonic Boom occurs at the sudden peak point in the INTENSITY OF THE WAVES HEARD plot. Then, the total volume of sound gradually decreases.

The first sound wave encountered by any human observer highlights itself as a thicker blue wave. Note how the order of this sound wave changes as you change the airplane speed and the speed of sound.


THINGS TO TRY
-------------
Try setting the airplane speed just below the speed of sound and see how the circles are being formed inside one another. 

Then, try setting its speed to maximum (3750mph) value in the slider and see how the first wave hitting the selected human observer is not the first wave created. 

After that, start running the model as decreasing the plane's speed by a specific amount each time the model runs to see how the first wave hitting the human observer changes each time.

Try comparing the intensities of Sonic Booms from the sound waves generated at different speeds by the airplane.


EXTENDING THE MODEL
-------------------
There may be some other flying objects placed on the screen and interference of the sound waves in the air can be measured on the screen. In addition, the model can have an option to analyze the sound waves traveling in another medium than air, such as water. 


CREDITS AND REFERENCES
----------------------
This model has been constructed and implemented by Umut Tekin. You may obtain a copy of the model from http://www.angelfire.com/ut2/umuttekin/. For any academic, commercial and/or non-commercial use, please consult Umut Tekin (u-tekin@northwestern.edu) for obtaining a permission to use the model.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159
Rectangle -7566196 true true 48 84 96 151
Rectangle -7566196 true true 60 83 121 177

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

circle
false
0
Circle -7566196 true true 35 35 230

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

bee
true
0
Polygon -256 true false 151 152 137 77 105 67 89 67 66 74 48 85 36 100 24 116 14 134 0 151 15 167 22 182 40 206 58 220 82 226 105 226 134 222
Polygon -16777216 true false 151 150 149 128 149 114 155 98 178 80 197 80 217 81 233 95 242 117 246 141 247 151 245 177 234 195 218 207 206 211 184 211 161 204 151 189 148 171
Polygon -7566196 true true 246 151 241 119 240 96 250 81 261 78 275 87 282 103 277 115 287 121 299 150 286 180 277 189 283 197 281 210 270 222 256 222 243 212 242 192
Polygon -16777216 true false 115 70 129 74 128 223 114 224
Polygon -16777216 true false 89 67 74 71 74 224 89 225 89 67
Polygon -16777216 true false 43 91 31 106 31 195 45 211
Line -1 false 200 144 213 70
Line -1 false 213 70 213 45
Line -1 false 214 45 203 26
Line -1 false 204 26 185 22
Line -1 false 185 22 170 25
Line -1 false 169 26 159 37
Line -1 false 159 37 156 55
Line -1 false 157 55 199 143
Line -1 false 200 141 162 227
Line -1 false 162 227 163 241
Line -1 false 163 241 171 249
Line -1 false 171 249 190 254
Line -1 false 192 253 203 248
Line -1 false 205 249 218 235
Line -1 false 218 235 200 144

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 46 130
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150
Polygon -7566196 true true 270 14
Polygon -7566196 true true 276 21

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

airplane
true
0
Rectangle -16776961 true false 33 101 270 201
Polygon -16776961 true false 45 124 29 60 89 117
Polygon -16776961 true false 34 118 28 60 52 119
Polygon -1 true false 13 156
Circle -1 true false 56 128 32
Circle -1 true false 102 127 32
Circle -1 true false 156 128 34
Circle -1 true false 221 129 29

human
false
0
Rectangle -16711936 true false 138 120 164 197
Polygon -16711936 true false 138 196 133 251 145 253 149 196
Polygon -16711936 true false 152 196 154 254 167 253 163 196
Circle -16711936 true false 137 88 30
Polygon -7566196 true true 136 122 111 168 122 173 138 133 136 122
Polygon -16711936 true false 135 122 112 168 120 172 138 134
Polygon -16711936 true false 164 122 186 169 177 174 161 136
Rectangle -6524078 true false 105 47 189 261
Circle -6524078 true false 125 2 48
Circle -7566196 true true 136 24 18
Circle -7566196 true true 134 15 32
Circle -7566196 true true 121 2 54
Rectangle -7566196 true true 105 48 189 259
Polygon -7566196 true true 102 47 61 152 77 159 105 77
Polygon -7566196 true true 189 47 235 151 221 157 186 74

sound
true
0
Circle -65536 true false 126 126 45
Circle -7566196 true true 78 78 138

sound2
true
0
Circle -65536 true false 93 91 111

airplane2
true
0
Rectangle -16776961 true false 42 105 43 105
Rectangle -16776961 true false 115 57 185 266
Polygon -16776961 true false 114 265 57 265 117 233

@#$#@#$#@
NetLogo 1.2beta4 (Rev C)
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@