;; Setup Procedures
  globals [ke-change count-forward-reactions count-reverse-reactions forward-rate reverse-rate]
 turtles-own [KE]
to setup
  ca
  cct bluemols
  [ set color blue
    randomize
  ]
  cct yellowmols
  [ set color yellow
    randomize
  ]
  cct greenmols
  [set color green
    randomize
    ]
  cct brownmols
  [set color brown
    randomize
  ]
  ;; adjust the y-range of the plot to fit the number of molecules
  set-current-plot "concentrations"
  set-plot-y-range 0 max (list yellowmols bluemols greenmols brownmols)
  set-current-plot "Temperature (kinetic energy)"
  set-plot-y-range 40 60
  ask turtles
    [set KE (random-normal (initial-temp) (.4 * initial-temp))]
  let diff mean values-from turtles [ke] - initial-temp
  ask turtles
    [set ke ke - diff]
  set forward-rate []
  set reverse-rate []
  set-current-plot "KE distribution"
  set-plot-x-range 0 2 * int max values-from turtles [ke]
  set-plot-pen-interval 20
  histogram-from turtles [ke]
end

to randomize
  set shape "circle"
  setxy random-float screen-size-x
        random-float screen-size-y
  rt random-float 360
end


;; Runtime Procedures

;; In GO, turtles move according to a number of different checks and
;;  procedures.  Note that all turtles must have executed the procedure
;;  CHECK-FOR-SPACE before any turtle can continue with CHECK-FOR-REACTION
;;  because they are broken up into two seperate ask blocks.  This ensures
;;  that every turtle will be on its own patch before any turtles checks for
;;  a reaction.
;;  In UPDATE-KE, the kinetic energy change from one cycle of the model 
;;  is distributed randomly to all turtles unless Hold-temp is switched on.
;;  TALLY-FORWARD and TALLY-REVERSE tally the number of forward and reverse
;;  reactions, respectively, in the most recent 20 turns of GO
to GO
  update-plot
  set ke-change 0
  set count-forward-reactions 0
  set count-reverse-reactions 0
  ask turtles
  [ fd 1 
    wiggle
    check-for-space
  ]
  ask turtles
  [ check-for-reaction ]
  if hold-temp = false [update-ke]
  TALLY-FORWARD
  TALLY-REVERSE
end

;; In WIGGLE, turtles are given a slight random twist to their heading.
to wiggle
  rt random-float 2
  lt random-float 2
end

;; In CHECK-FOR-SPACE, each turtle moves forward until it is alone in its
;;  own patch.  Note that the procedure calls itself if the check is true.
;;  This technique is called recursion.  CHECK-FOR-SPACE is called in GO.
to check-for-space
  if (count turtles-here > 1) 
  [ fd 1 check-for-space ]
end

;; In CHECK-FOR-REACTION, every turtle checks for a turtle it can react with within
;;  a radius which approximates the eight patches surrounding it.  Blue turtles can
;;  react with yellow turtles, and brown turtles can react with green turtles.
to check-for-reaction
  if color = blue and any? turtles in-radius 1 with [color = yellow]
  [ ke-forward random-one-of turtles in-radius 1 with [color = yellow] ]
  if color = brown and any? turtles in-radius 1 with [color = green]
  [ ke-reverse random-one-of turtles in-radius 1 with [color = green] ]
end
;; In ke-forward and ke-reverse, the collision is checked for sufficient energy
;; and a reaction sector (chance of correctly oriented collision) is applied
;; For example, if the difficulty forward is set to 10, it means that only 1
;; collision out of 10, with sufficient activation energy, will actually react.

to ke-forward [t]
  if ke + ke-of t > Ea-forward and random (difficulty-forward - 1) = 0
  [react-forward random-one-of turtles in-radius 1 with [color = yellow]]
end

to ke-reverse [t]
  if ke + ke-of t > Ea-reverse and random (difficulty-reverse - 1) = 0
  [react-reverse random-one-of turtles in-radius 1 with [color = green]]
end
  
;; In REACT-FORWARD and REACT-REVERSE, the turtle changes the its color and the color
;;  of the turtle they are reacting with, sets a random heading, and jumps away to
;;  avoid further interaction.  They are the same except for their colors.
;; Also, the kinetic energy increases (exothermic direction) or decreases (endothermic).
;; The increase or decrease is stored temporarily in KE-change and, at
;; the end of a turn of GO, divided randomly among all turtles by UPDATE-KE, 
;; unless the Hold-temp switch is on.
;; The procedures UPDATE-FORWARD and UPDATE-REVERSE count the number of forward and reverse
;; reactions in one turn of GO.  TALLY-FORWARD and TALLY-REVERSE keep the data for the most
;; recent 20 turns in a list, which is used by the Rate plot to generate a "moving-window" 
;; estimate of the rate of forward and reverse reactions.

to react-forward [t]
  set color-of t brown
  set color green
  set ke-change ke-change + Ea-reverse - Ea-forward
  update-forward
  rt random-float 360
  jump 2
end



to react-reverse [t]
  set color-of t blue
  set color yellow
  set ke-change ke-change + Ea-forward - Ea-reverse
  update-reverse
  rt random-float 360
  jump 2
end

to UPDATE-KE
  let newtemp mean values-from turtles [ke] + (ke-change / count turtles)
  ask turtles 
  [set ke (random-normal (newtemp) (.4 * newtemp))]
  let diff mean values-from turtles [ke] - newtemp
  ask turtles
  [set ke ke - diff
  ]
  
end

to UPDATE-FORWARD  
  set count-forward-reactions count-forward-reactions + 1
end

to UPDATE-REVERSE
  set count-reverse-reactions count-reverse-reactions + 1
end

;; In NEWT (new temperature) turtles are assigned a new random KE with mean
;; equal to the new temperature
to NEWT [new-temp]
  ask turtles
    [set ke random-normal (new-temp) (new-temp / 2.5)]
  let diff mean values-from turtles [ke] - new-temp
  ask turtles
    [set ke ke - diff]
end

;; In NEWBL, NEWBR, NEWY, and NEWG the existing turtles of the indicated color are killed and replace
;; by a new number of turtles chosen by the user, of the same color.  KE's are reassigned by calling the
;; NEWT procedure with the old temperature so that the change in turtle number does not affect the 
;; temperature.

to NEWBL [num]
  let k mean values-from turtles [ke]
  ask turtles with [color = blue] [die]
  crt num
  ask turtles with [ke = 0]
    [set color blue
    randomize
    ]
  newt k
end


to NEWBR [num]
  let k mean values-from turtles [ke]
  ask turtles with [color = brown] [die]
  crt num
  ask turtles with [ke = 0] 
    [set color brown
    randomize
    ]
  newt k
end


to NEWY [num]
  let k mean values-from turtles [ke]
  ask turtles with [color = yellow] [die]
  crt num
  ask turtles with [ke = 0] 
  [set color yellow
    randomize
  ]
  newt k
end


to NEWG [num]
  let k mean values-from turtles [ke]
  ask turtles with [color = green] [die]
  crt num
  ask turtles with [ke = 0] 
    [set color green
    randomize
    ]
  newt k  
end

to TALLY-FORWARD 
  set forward-rate fput count-forward-reactions forward-rate
  if length forward-rate =  21 [set forward-rate remove-item 20 forward-rate]
end

to TALLY-REVERSE
  set reverse-rate fput count-reverse-reactions reverse-rate
  if length reverse-rate = 21 [set reverse-rate remove-item 20 reverse-rate]
end

;; In UPDATE-PLOT, each pen in "concentrations" plots its corresponding turtle count.
;; In the Temperature plot, the average KE of all the turtles is shown.
;; In the Rates plot, the number of successful collisions in the last 20 turns of GO is
;; plotted separately for the forward (blue pen) and reverse (red pen) reactions.
;; In the Reaction quotient plot, the current value of the reaction quotient is plotted.
;; In the KE distribution plot, histograms of the original KE distribution (black) and the
;; current one (blue) are shown.
to update-plot
  set-current-plot "concentrations"
  set-current-plot-pen "Yellows"
    plot count turtles with [color = yellow]
  set-current-plot-pen "Blues"          
    plot count turtles with [color = blue]
  set-current-plot-pen "Browns"
    plot count turtles with [color =  brown]
  set-current-plot-pen "Greens"
    plot count turtles with [color = green]
  set-current-plot "Temperature (kinetic energy)"
  set-current-plot-pen "Temp"
    plot mean values-from turtles [ke] 
  set-current-plot "Rates"
  set-current-plot-pen "Forward"
    if length forward-rate > 0 [plot (reduce [?1 + ?2] forward-rate) / (length forward-rate)]
  set-current-plot-pen "Reverse"
    if length reverse-rate > 0 [plot (reduce [?1 + ?2] reverse-rate) / (length reverse-rate)]
  set-current-plot "Reaction Quotient"
  set-current-plot-pen "Reaction quotient"
    plot count turtles with [color = green] * count turtles with [color = brown] / 
       count turtles with [color = blue] / count turtles with [color = yellow]
  set-current-plot "KE distribution"
  set-current-plot-pen "current"
  set-plot-pen-interval 20
    histogram-from turtles [ke]
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky. All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
; Converted from StarLogoT to NetLogo, 2001.  Updated 2002.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo Chemical Equilibrium model.
; http://ccl.northwestern.edu/netlogo/models/ChemicalEquilibrium.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/ChemicalEquilibrium
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
459
10
774
346
30
30
5.0
1
10
1
1
1
0

CC-WINDOW
5
570
783
665
Command Center

BUTTON
269
172
346
205
setup
setup
NIL
1
T
OBSERVER
T
NIL

BUTTON
368
173
458
206
go / pause
go
T
1
T
OBSERVER
T
NIL

SLIDER
9
73
121
106
yellowmols
yellowmols
0
500
280
10
1
NIL

SLIDER
9
106
121
139
bluemols
bluemols
0
500
400
10
1
NIL

MONITOR
72
155
122
204
blues
count turtles with [color = blue]
3
1

MONITOR
20
155
70
204
yellows
count turtles with [color = yellow]
3
1

MONITOR
129
156
179
205
greens
count turtles with [color = green]
3
1

MONITOR
180
156
230
205
browns
count turtles with [color = brown]
3
1

PLOT
13
207
237
373
Concentrations
time
molecules
0.0
100.0
0.0
200.0
true
true
PENS
"Yellows" 1.0 0 -256 false
"Blues" 1.0 0 -16776961 false
"Greens" 1.0 0 -11352576 false
"Browns" 1.0 0 -6524078 false

SLIDER
123
74
239
107
greenmols
greenmols
0
500
50
10
1
NIL

SLIDER
123
107
239
140
brownmols
brownmols
0
500
90
10
1
NIL

SLIDER
262
73
362
106
Ea-forward
Ea-forward
0
150
80
5
1
 

SLIDER
401
74
499
107
Ea-reverse
Ea-reverse
0
150
30
5
1
NIL

MONITOR
469
158
526
207
av. KE
mean values-from turtles [ke]
3
1

PLOT
471
208
705
374
Temperature (kinetic energy)
time
KE
0.0
100.0
0.0
10.0
true
false
PENS
"Temp" 1.0 0 -65281 true

SLIDER
251
108
381
141
difficulty-forward
difficulty-forward
1
50
1
1
1
NIL

SLIDER
388
108
519
141
difficulty-reverse
difficulty-reverse
1
50
1
1
1
NIL

SWITCH
606
352
704
385
Hold-temp
Hold-temp
1
1
-1000

PLOT
241
208
466
373
Rates
time
Rates
0.0
100.0
0.0
20.0
true
false
PENS
"Forward" 1.0 0 -16776961 true
"Reverse" 1.0 0 -65536 true

MONITOR
12
405
122
454
Reaction-quotient
count turtles with [color = green] * count turtles with [color = brown] / \ncount turtles with [color = blue] / count turtles with [color = yellow]
5
1

PLOT
130
406
330
556
Reaction quotient
time
NIL
0.0
101.0
0.0
2.0
true
false
PENS
"Reaction quotient" 1.0 0 -16777216 false

TEXTBOX
39
52
92
70
Reactants

TEXTBOX
153
52
202
70
Products

TEXTBOX
268
51
356
69
Forward Reaction

TEXTBOX
409
50
497
68
Reverse reaction

PLOT
374
406
574
556
KE distribution
KE
# of molecules
0.0
150.0
0.0
10.0
true
false
PENS
"start" 1.0 0 -16777216 true
"KE" 1.0 0 -16776961 true
"current" 1.0 0 -16776961 true

SLIDER
13
13
114
46
Initial-temp
Initial-temp
0
200
40
10
1
NIL

@#$#@#$#@
WHAT IS IT?
-----------
This is a modification to the "Netlogo chemical equilibrium model" by Uri Wilensky.  New features that have been added to the basic model include the following:

1.  The individual molecules have a property designated ke (kinetic energy).  During setup, the ke is assigned as a random-normal variable as described below.  The ke can change as the simulation runs.

2.  The system as a whole has a property designated temperature, calculated as the mean of the kinetic energies.  In real life, temperature (of an ideal gas) is proportional to mean kinetic energy.  Since we are using a proportionality constant of one, the energy and temperature should not be interpreted in conventional units.

During setup, the user sets the initial temperature with a slider.  The ke's are then assigned as random numbers from a normal distribution with mean = initial temperature and SD = .4 * initial temperature.  (This approximates the Maxwell distribution, albeit imperfectly.)  If, as usually happens, the random numbers do not have precisely the desired mean, all the ke's are adjusted up or down by the same amount to obtain the desired mean. A graph displays the distribution of kinetic energies as a histogram. 

3.  Both the forward and reverse reactions are assigned an activation energy (which may be, and usually are, different), set by the user with sliders.  When molecules of the correct colors collide, they can react only if their combined ke exceeds the activation energy.  By setting temperature low relative to the activation energy, the frequency of the reaction will be decreased because many collisions will have too little energy.

4.  Both the forward and reverse reactions are assigned another characteristic, which I've labeled "difficulty".  Chemists will recognize this as the more familiar orientation factor.  Most collisions fail because the molecules are not oriented properly to break old bonds and form new ones.  The difficulty factor is used by the simulation as an attenuator.  If the factor is set to 10, for example, then every time you have a potential reaction (right colors, enough kinetic energy), a random drawing is held, with a 1 in 10 chance of success, to see whether the reaction will be allowed to take place.  The higher the difficulty setting, the lower the chances.

5.  The simulation has a toggle switch called hold-temp.  If this switch is ON, it is similar to conducting a real reaction in a temperature-controlled environment.  Any heat produced or absorbed by the reaction is transferred to/absorbed from the environment and the temperature of the system remains constant.  If the switch is OFF, it is similar to running the reaction in an insulated environment.  In this case, heat changes are retained within the system, causing the temperature to change.  The simulation keeps track of the energy changes as reactions occur.  At the end of each turn of the simulation, the new temperature is calculated and new kinetic energies are assigned to all molecules (whether they participated in a productive collision or not), using the same procedure as during initial ke assignment in setup.

6.  I've created "new" commands to facilitate playing with disturbances to equilibrium.  These are entered in the command center (while the simulation is running or paused, but I think paused is easier to digest because you can take time to predict the effect, then restart the simulation and see if you were right).  These commands all take a number as an argument (100 just for illustration purposes):

newbl 100 	changes the number of blue molecules to 100
newbr 100	changes the number of brown molecules to 100
newg 100	changes the number of green molecules to 100
newy 100	changes the number of yellow molecules to 100
newt 100	changes the temperature to 100 (can be used regardless of the hold-temp 			toggle)

7.  Several additional graphs and monitors have been added to track new features.  

The rate graph tracks the average number of forward reactions per cycle (blue line) and the average number of reverse reactions per cycle (red line).  For the first twenty turns of the simulation, it averages the reactions from all the turns since the beginning of the simulation; after that it averages the most recent 20 turns.

The temperature graph shows the temperature (average ke) over time.

The reaction quotient graph shows the evaluation of the equilibrium constant expression [GR][BR]/([BL][YE]).  At equilibrium, this value should be independent of the initial concentrations, but is sensitive to temperature, activation energies, and difficulty settings.

The ke distribution graph shows the initial distribution of kinetic energy (black line) as well as the current distribution (blue line).  Note that as temperature increases, the distribution broadens; conversely, it narrows as temperature goes down.

WHO MADE THESE MODIFICATIONS?
-----------
Russ Maurer
Hawken School
PO Box 8002
Gates Mills, OH
rmaur@hawken.edu

Please send me your feedback or suggestions!

The following is the description of the original model by Uri Wilensky:

WHAT IS IT?
-----------
This project shows how a simple chemical system comes to different equilibrium states depending on the concentrations of the initial reactants.  Equilibrium is the term we use to describe a system in which there are no macroscopic changes.  This means that the system "looks" like nothing is happening.  In fact, in all chemical systems microscopic processes continue but in a balance that yields no changes at the macroscopic level.  This model simulates two simple reactions of four molecules.   

The reactions can be written A + B yields C + D.  And at the same time, of course, C + D yields A + B.

A classic real-life example that would illustrate such reactions is the reactions of carbon monoxide with nitrous dioxide to produce carbon dioxide and nitrous monoxide.  The reverse is also possible.  All the reactants are gases.  We could watch such an equilibrium system because NO2 is a reddish colored gas which is visible. However, the combining of nitrous dioxide (NO2) with carbon monoxide (CO) results in the colorless products nitrous monoxide (NO) and carbon dioxide (CO2), and so the system loses its reddish color.  And yet, not all the color is lost. Ultimately the system comes to equilibrium with some of the "reactants" and some of the "products" present.

How much "reactant" and "product" a system ends up with depends on a number of factors.  The inherent kinetics of the reaction are of vital concern: For instance, some reactions tend to go in a particular direction because energy is released in that direction.  A system's equilibrium is also affected by the concentrations of the reactants -- this is modeled here -- and by the system's temperature.


HOW TO USE IT
-------------
As stated above, this model simulates a chemical system of four different molecules.  They are represented on the graphics screen as turtles of four different colors.  In this simulation, yellow molecules react with blue molecules to produce brown molecules and green molecules.  

The model is setup by first adjusting the YELLOWMOLS and BLUEMOLS sliders and pushing the SETUP button.  YELLOWMOLS sets how many yellow molecules the simulation starts with, while BLUEMOLS sets how many blue molecules the simulation starts with.


The GO button sets the simulation in motion.  Molecules move randomly and react with each other, changing color to represent rearrangement of atoms into different molecular structures.  The system soon comes into equilibrium.

Four monitors show how many of each kind of molecule are present in the system.  There is also a plot which plots the number of each kind of molecule present versus time.



THINGS TO NOTICE
----------------
Notice that the number of product molecules is limited by the smallest amount of reactant product.  Notice that there are always the same number of reactant products since they are formed in a one-to-one correspondence with each other. 


THINGS TO TRY
-------------
How do different amounts of the two reactants affect the final equilibrium.  Are absolute amounts important, is it the difference between the amounts, or is it a ratio of the two reactants that matters?  

Try setting the YELLOWMOLS slider to 400 and the BLUEMOLS slider to 20, 40, 100, 200, and 400 in five successive simulations.  What sort of equilibrium state do you predict in each case?  Are certain ratios predictable?


EXTENDING THE MODEL
-------------------
What if the forward and reverse reaction rates were the variables controlled instead of initial concentrations.  You could compare such a simulation with the one in this model and see if concentration and reaction rates act independently of each other, as measured by the final equilibrium state.  

You could also extend the program by allowing the user to introduce new molecules into the simulation while it is running.  How would the addition of fifty blue molecules affect a system that was already at equilibrium?


CREDITS AND REFERENCES
----------------------
To refer to this model in academic publications, please use: Wilensky, U. (2002). NetLogo Chemical Equilibrium model. http://ccl.northwestern.edu/netlogo/models/ChemicalEquilibrium. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use: Copyright 2002 by Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/ChemicalEquilibrium for terms of use.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7566196 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7566196 true true 150 285 285 225 285 75 150 135
Polygon -7566196 true true 150 135 15 75 150 15 285 75
Polygon -7566196 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7566196 true true 96 182 108
Circle -7566196 true true 110 127 80
Circle -7566196 true true 110 75 80
Line -7566196 true 150 100 80 30
Line -7566196 true 150 100 220 30

butterfly
true
0
Polygon -7566196 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7566196 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7566196 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7566196 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7566196 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7566196 true true 47 195 58
Circle -7566196 true true 195 195 58

circle
false
0
Circle -7566196 true true 30 30 240

circle 2
false
0
Circle -7566196 true true 16 16 270
Circle -16777216 true false 46 46 210

cow
false
0
Polygon -7566196 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7566196 true true 73 210 86 251 62 249 48 208
Polygon -7566196 true true 25 114 16 195 9 204 23 213 25 200 39 123

face happy
false
0
Circle -7566196 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7566196 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7566196 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7566196 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7566196 true true 60 15 75 300
Polygon -7566196 true true 90 150 270 90 90 30
Line -7566196 true 75 135 90 135
Line -7566196 true 75 45 90 45

flower
false
0
Polygon -11352576 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7566196 true true 85 132 38
Circle -7566196 true true 130 147 38
Circle -7566196 true true 192 85 38
Circle -7566196 true true 85 40 38
Circle -7566196 true true 177 40 38
Circle -7566196 true true 177 132 38
Circle -7566196 true true 70 85 38
Circle -7566196 true true 130 25 38
Circle -7566196 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -11352576 true false 189 233 219 188 249 173 279 188 234 218
Polygon -11352576 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7566196 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7566196 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7566196 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7566196 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7566196 true 150 0 150 300

pentagon
false
0
Polygon -7566196 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7566196 true true 110 5 80
Polygon -7566196 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7566196 true true 127 79 172 94
Polygon -7566196 true true 195 90 240 150 225 180 165 105
Polygon -7566196 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7566196 true true 135 90 165 300
Polygon -7566196 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7566196 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7566196 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7566196 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7566196 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7566196 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7566196 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7566196 true true 30 30 270 270

square 2
false
0
Rectangle -7566196 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7566196 true true 60 270 150 0 240 270 15 105 285 105
Polygon -7566196 true true 75 120 105 210 195 210 225 120 150 75

target
false
0
Circle -7566196 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7566196 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7566196 true true 120 120 60

tree
false
0
Circle -7566196 true true 118 3 94
Rectangle -6524078 true false 120 195 180 300
Circle -7566196 true true 65 21 108
Circle -7566196 true true 116 41 127
Circle -7566196 true true 45 90 120
Circle -7566196 true true 104 74 152

triangle
false
0
Polygon -7566196 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7566196 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7566196 true true 4 45 195 187
Polygon -7566196 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7566196 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7566196 false true 24 174 42
Circle -7566196 false true 144 174 42
Circle -7566196 false true 234 174 42

turtle
true
0
Polygon -11352576 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -11352576 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -11352576 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -11352576 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -11352576 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7566196 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7566196 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7566196 true 150 285 150 15
Line -7566196 true 15 150 285 150
Circle -7566196 true true 120 120 60
Line -7566196 true 216 40 79 269
Line -7566196 true 40 84 269 221
Line -7566196 true 40 216 269 79
Line -7566196 true 84 40 221 269

x
false
0
Polygon -7566196 true true 270 75 225 30 30 225 75 270
Polygon -7566196 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 2.1.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@