; DisDB (Distributed Dynamic BAcktracking)  for the graph-coloring problem
; by Ionel Muscalagiu - mionel@fih.utt.ro 
; and Jose Vidal

breeds [vertices ]
;
;edges is a list of lists: a 2D array indexed by who. The value is 1 if there is a link, 0 otherwise.
;num-colors
;domain is the list of allowed colors
globals [edges domain no-more-messages tmp nr_cicluri gata number-of-edges]
;MyContext (current-view in the ABT) is a list indexed by queen number [col0 col1 col2...] col = -1 if unknown.
;nogoods is a list of inconsistent positions [0 1 1 0 ... ] where 0 is good and 1 is no-good.
;ParentA it the set of agents constrained with self and appearing at higher levels in the hierarchy
;ChildrenA  is the set of agents constrained with self  appearing at lower levels in the hierarchy
;the-neighbors is a list of the 'who' of all vertices that have a constraint with me
;
;message-queue contains the incoming messages. We take new ones out from the head.
;messages-recieved_ok is the number of messages info (ok in the ABT algorithm) this vertice has received.
;messages-recieved_nogood is the number of messages back (nogood in the ABT algorithm) this vertice has received.
vertices-own [message-queue parent parent-agent Children ChildrenA ParentA level  the-neighbors  dfs-neighbors dfs-change
              MyValue_colorn MyContext nogoods consistent messages-received_ok messages-received_nogood messages-received]


;returns a list of legnth n where each item is v
to-report make-list [n v]
    locals [res]
    set res []
    repeat n [
        set res fput v res]
    report res
end

to make-link [v1 v2]
    locals [aux]
    if (v2 < v1)[
        set aux v2
        set v2 v1
        set v1 aux]
    if (not neighbors? v1 v2) [
        set edges replace-item v1 edges (lput v2 (item v1 edges))
    ]
end

to-report neighbors? [v1 v2]
    locals [aux]
    if (v2 < v1) [
        set aux v2
        set v2 v1
        set v1 aux]
    report member? v2 (item v1 edges)
end

;reports true if edges and num-vertices represent a connected graph
;trebuie sa verificam pentru ca altfel nu are sens sa mai rezolvam problema
to-report connected?
    locals [clique i j]
    set i 0
    set clique []
    set clique lput i clique
    set i 1
    set j 0
    while [j < num-vertices][
         while [i < num-vertices][
             if (not member? i clique)[
                 if (not empty? filter [neighbors? ? i] clique)[
                     set clique lput i clique
                     if (length clique = num-vertices)[
                         report true
                     ]
                  ]
             ]
             set i i + 1
          ]
          set j j + i
    ]
    report false
end

;sets 'edges' and 'the-neighbors'
to make-edges
    locals [edges-created v1 v2 aux]
    set edges make-list num-vertices []
    set edges-created 0
    if num-vertices * edge-density > (num-vertices * (num-vertices - 1)) / 2 
    [set edge-density ( num-vertices - 1 ) / 2]
    
    while [edges-created < num-vertices * edge-density][
        set v1 (random-int-or-float num-vertices)
        set v2 (random-int-or-float num-vertices)
        if (v1 > v2) [
            set aux v2
            set v2 v1
            set v1 aux
        ]
        if (v1 != v2 and (not neighbors? v1 v2))[
            make-link v1 v2
            set edges-created (edges-created + 1)
        ]
    ]
    set v1 0
    while [v1 < num-vertices][
        set tmp (item v1 edges)
        set (the-neighbors-of (turtle v1)) []
        set v2 0
        while [v2 < num-vertices][
            if (neighbors? v1 v2)[
                set (the-neighbors-of (turtle v1)) lput v2 the-neighbors-of (turtle v1)
            ]
            set v2 v2 + 1
        ]
        set v1 v1 + 1
    ]
    if (not connected?)[
        print "Graph not connected. Generating again..."
        make-edges]
   set number-of-edges edges-created  
end

to load-edges_file
    locals [edges-created v1 v2 aux]
    file-open "graf.txt"
    set num-vertices file-read
    set edge-density file-read
    set number-of-edges file-read 
    set edges make-list num-vertices []
    set edges-created 0      
    while [edges-created < num-vertices * edge-density][
        set v1 file-read 
        set v2 file-read
        if (v1 > v2) [
            set aux v2
            set v2 v1
            set v1 aux
        ]
        if (v1 != v2 and (not neighbors? v1 v2))[
            make-link v1 v2
            set edges-created (edges-created + 1)
        ]
    ]
    set v1 0
    show edge-density
    show num-vertices
    while [v1 < num-vertices][
        set tmp (item v1 edges)
        set (the-neighbors-of (turtle v1)) []
        set v2 0
        while [v2 < num-vertices][
            if (neighbors? v1 v2)[
                set (the-neighbors-of (turtle v1)) lput v2 the-neighbors-of (turtle v1)
            ]
            set v2 v2 + 1
        ]
        set v1 v1 + 1
    ]
 file-close 
end


to set-parent
    locals [parents]
    set parents filter [? < who] dfs-neighbors
    ifelse (empty? parents) [
        set parent -1 ;the root
    ][
        if (dfs-change) [ 
            set parent max parents
            
         ]
    ]
end
to set-level
    ifelse (parent = -1)[
        set level 0
    ][
        set level (level-of parent-agent) + 1
    ]
end

; n is length of list
; el is the element
to-report get-list [n el]
  locals [i lst]
  set i 0
  set lst []
  while [i < n] [
    set lst fput el lst
    set i i + 1]
  report lst
end

;vertice function
to find-best-position
    locals [possible-patches siblings best-patch]
    ifelse (parent = -1) [
        set xcor 0
    ][
        set siblings vertices with [self != myself and (level = level-of myself or who = parent-of myself)]
        set possible-patches patches with [distance-nowrap myself < 20 and (pycor = round ycor-of myself)]
        set best-patch max-one-of possible-patches [sum values-from siblings [log (distance-nowrap myself + .1) 2]]
        set xcor (pxcor-of best-patch)
        if (xcor < 0 - screen-edge-x + 50) [set xcor 0 - screen-edge-x + 50]
        if (xcor > screen-edge-x - 10) [set xcor screen-edge-x - 10]
    ]          
end

;vertices function. Draws an edge from this vertice to other-vertice
to draw-edge [other-vertice col]
    locals [dista oc ox oy]
    set oc color
    set ox xcor
    set oy ycor
    set color col
    set dista distance-nowrap other-vertice
    set heading towards-nowrap other-vertice
    pen-down
    fd dista
    pen-up
    set color oc
    setxy ox oy
    set heading 0
end

to draw-edges
    locals [v1]
    set v1 0
    while [v1 < num-vertices][
        no-display
        ask (turtle v1) [
            without-interruption [
                foreach the-neighbors [
                    draw-edge (turtle ?) blue
                ]
            ]
        ]
        display
        set v1 v1 + 1
    ]
      
end    


to set-dfs-tree
    ask vertices [
        set dfs-neighbors the-neighbors
        set parent -2
        set children []
        set message-queue []
        set dfs-change true
        set-parent
        ]
 
     
    ;sets the parent-agent and children        
    ask vertices [
        if (parent != -1) [
            set parent-agent (turtle parent)
            set children-of parent-agent fput who (children-of parent-agent)
        ]
    ]
    
   

end

  
to setup-vertices
    locals [i]
    set nr_cicluri 0
    show "Setup"
    
    set domain []
    set i 0
    while [i < num-colors][
        set domain lput item i [15 105 64 125 45 85 35 55 5] domain
        set i i + 1
    ]
  create-vertices num-vertices
  ask vertices [
    set size 12
    set shape "circle" 
    set heading 0
    set parent -2
    set messages-received 0
    set messages-received_ok 0
    set messages-received_nogood 0
    set MyContext get-list num-vertices -1
    set nogoods get-list num-vertices 0
    set message-queue []
    if (who != 0)
    [
    set-current-plot "Messages"
    create-temporary-plot-pen "" + who
    set-current-plot-pen "" + who
    set-plot-pen-color (5 + 10 * who) mod 140
    
    ]
    set color item (random-int-or-float num-colors) domain
    set Myvalue_colorn position color domain
    ]
    make-edges
    ;load-edges_file
end

to setup-patches
  locals [i]
  
  set-dfs-tree
    repeat num-vertices [
        ask vertices [
            set-level
            ]
    ]
    
   set i max values-from vertices [level]
   ; set i 8 
    ask vertices [
        ;set level who + 1
        set ycor (screen-edge-y - 20) - (level * ((screen-size-y - 30) / i))
        
        ]
    repeat 8 [
        ask vertices [
           find-best-position
        ]
    ]
    draw-edges
    
end

to WriteSolution
Show "Solution "
ask vertices [
show MyValue_colorn + " "
]
end



to setup
  ca
  file-close
  clear-output
  setup-vertices
  setup-patches
  set gata false
  ask vertices [
  ComputeParentA_ChildrenA
  initialize
  ]
  
end

to ComputeParentA_ChildrenA
locals [i]
set ChildrenA []
set ParentA []
foreach the-neighbors
[
  if (? > who )  
    [set ChildrenA lput ? ChildrenA]
  if (? < who )  
    [set ParentA lput ? ParentA]
]
end

to update
  set no-more-messages true
  set nr_cicluri nr_cicluri + 1
  if (nr_cicluri > Max_cycle) 
   [Stop]

  ask vertices [
    if (not empty? message-queue)[
      set no-more-messages false]]
  if (no-more-messages) 
  [
    WriteSolution
    stop
   ]
  if (gata) [
    show "no solution"
    stop]
  ask vertices [handle-message]
  ask vertices [
    set-current-plot "Messages"
    create-temporary-plot-pen "q" + who
    plot messages-received_nogood
    ;plot messages-received_ok
       
    ]
  if (show-trace)[
    print "=============="
    ask vertices [
      show "view=" + MyContext
      show "nogood=" + nogoods]]
end


to receive-message [msg]
  without-interruption [
    set message-queue lput msg message-queue]
end

to-report retrieve-message
  locals [msg]
  without-interruption [
    set msg first message-queue
    set message-queue butfirst message-queue
    ]
  report msg
  
end


to initialize
 locals [msg]
  set consistent true
  foreach childrenA
    [
     set msg (list "info" (list who MyValue_colorn) )
     ask turtles with [who = ? ]
         [receive-message msg]
    ] 
end

;this is the DisDB procedure in the paper
to handle-message
  locals [msg xj dj]
  if (empty? message-queue) [stop]
  set msg retrieve-message
  if (first msg = "stop")
   [set gata true
   stop]
  if (first msg = "info")
    [set messages-received_ok messages-received_ok + 1
    GoAHead msg]
  if (first msg = "back")
    [ 
    set messages-received_nogood messages-received_nogood + 1
    ResolveConflict item 1 msg item 2 msg] 
end

 ;this is the CheckAgentView procedure in the ABT algorithm  
 to GoAHead  [msg ]
    locals [xj dj  i j TempValue ]
    if (msg != "" )
     [
     set xj item 0 (item 1 msg)
     set dj item 1 (item 1 msg)
     UpdateContextInfo xj dj 
     ]
    if (not consistent ) 
       [
       set TempValue ChooseValue
       ifelse (TempValue > -1 )
        [ 
        set MyValue_colorn TempValue
        set color item MyValue_colorn domain
        foreach childrenA
         [
          set msg (list "info" (list who MyValue_colorn) )
          ask turtles with [who = ? ]
              [receive-message msg]
         ]
         ]
         [ResolveNogoods]
      ]
  end       

to UpdateContextInfo [Qj Vj ]
 locals [i j ]
    set MyContext replace-item Qj MyContext Vj
    ;set i Qj 
    set consistent true
    set i 0
    while [ i < who  ] ;for each vertice
    [
     
      if ((item i MyContext != -1 ) and (neighbors? i who) and ( MyValue_colorn = (item i MyContext)))
             [ 
             set consistent false
             ]   
      set i i + 1
     
    ]         
    set nogoods get-list num-colors 0
    set i 0
    while [ i < who ] ;for each vertice
        [set j 0
         while [ j < num-colors ] ;for each color 
            [
             if ((neighbors? i who) and ( j = (item i MyContext)))
                [set nogoods replace-item j nogoods 1]   
             set j (j + 1)]
         set i (i + 1)]    
      
end

to-report Is-obsolete [msgNogood Sender]
    locals [i res]
    set i 0
    set res false
    while [i < who]
     [if  ((item i MsgNogood != -1 ) and (item i MyContext != -1 ) and (item i msgNogood) != (item i MyContext) and member? i ParentA) 
     [set res true]            
      set i (i + 1)]
    if ( (item who MsgNogood != -1 ) and ((item who msgNogood) != MyValue_colorn))
      [set res true]
    ;Show MyValue_colorn + " " + msgNogood + "  " + MyContext  
    report res  
end

to ResolveConflict [msgNogood Sender]
    locals [ i j msg TempValue]

    ;if it is consistent with the agent view, otherwise it is discarded due to obsolescence.
   ifelse ( Not Is-obsolete msgNogood Sender)
    ;An accepted nogood is used to update the agent view of agents not in PArentA
     ;update MyContext
    [set i 0
    while [i <  who]
     [
     if (((item i msgNogood) != -1) and (not member? i ParentA)) 
       [set MyContext (replace-item i MyContext (item i msgNogood))]            
     set i (i + 1)
     ]
    set nogoods replace-item MyValue_colorn nogoods 1 ;mark current position as no good
    ;set consistent false
    set TempValue ChooseValue
    ifelse (TempValue > -1 )
     [ 
        set MyValue_colorn TempValue
        ;set consistent true
        set color item MyValue_colorn domain
        set msg (list "info" (list who MyValue_colorn) )
        foreach childrenA
         [
           ask turtles with [who = ? ]
              [receive-message msg]
         ]
     ]
     [ResolveNogoods]
     ]
     [
      if not( (item who msgNogood != -1 ) and ((item who msgNogood) != MyValue_colorn))
       [ 
         set msg (list "info" (list who MyValue_colorn) )
         ;Show "s-a trimis la " + Sender
         ask turtles with [who = Sender ]
            [receive-message msg]
       ]
     ]
 end 


to-report agents-in-context [cont]
    locals [i res]
    set i 0
    set res []
    while [i < who][
      if ((item i cont != -1) )
        [
           set res lput i res
        ]
        set i i + 1
    ]
    report res
end

to-report rhs [ n ]
locals [whon gasit lagent]
 set lagent agents-in-context MyContext
 set whon n - 1
 set gasit false 
 while [not gasit ]
  [
   ifelse ( member? whon lagent ) 
     [set gasit true]
   [set whon whon - 1] 
   ]  
  report whon
end



;this is the BackTrack procedure in the ABT algorithm    
 to ResolveNogoods
    locals [msg i j wng]     
    ifelse (who = 0);newNogood=empty; 
        [set gata true 
        set msg "stop"
        receive-message msg
        ]
       [ set msg (list "back" MyContext who )
         set wng rhs who
         ask turtles with [who = wng ]
            [receive-message msg]
         
         set MyContext (replace-item wng MyContext -1)
         set i 0
         while [i < who]
         [
           if (((item i MyContext) != -1) and (not member? i ParentA)) 
                [set MyContext (replace-item i MyContext -1)]            
           set i (i + 1)
         ]
         UpdateContextConflict wng
       ]  
end


to UpdateContextConflict  [wng]
   locals [i j msg TempValue]
  
   set nogoods get-list num-colors 0
   set i 0
   while [ i < who ] ;for each vertice
        [set j 0
         while [ j < num-colors ] ;for each color
            [
             if ((neighbors? i who) and ( j = (item i MyContext)))
                [set nogoods replace-item j nogoods 1]   
             set j (j + 1)]
       set i (i + 1)]    
       set TempValue ChooseValue
       ifelse (TempValue > -1 )
        [ 
        set MyValue_colorn TempValue
        set color item MyValue_colorn domain
        foreach childrenA
         [
          set msg (list "info" (list who MyValue_colorn) )
          ask turtles with [who = ? ]
              [receive-message msg]
         ]
         ]
         [ResolveNogoods]
   
   end

 
to-report ChooseValue
 locals [i j ]
   set i 0
   set j 0
   while [ i < num-colors and j = 0]
        [if ( item i nogoods = 0 )
            [
             set j 1
             report i
             ]
         set i (i + 1)]
  ; setxy (i - screen-edge-x) (screen-edge-y - who)
   report -1      
end 

























@#$#@#$#@
GRAPHICS-WINDOW
259
10
730
496
153
151
1.502
1
10
1
1
1

CC-WINDOW
738
10
996
598
Command Center

BUTTON
0
10
81
43
NIL
setup
NIL
1
T
OBSERVER
T

SLIDER
2
45
174
78
num-vertices
num-vertices
0
30
10
1
1
NIL

BUTTON
82
10
163
43
NIL
update
NIL
1
T
OBSERVER
T

BUTTON
163
10
245
45
NIL
update
T
1
T
OBSERVER
T

SWITCH
4
78
109
111
show-trace
show-trace
1
1
-1000

PLOT
-2
289
331
608
Messages
Nr de cicluri
Mesaje nogood pe agent
0.0
10.0
0.0
10.0
true
false
PENS
"Messages" 1.0 2 -16777216 true
"default" 1.0 0 -16777216 true

MONITOR
176
47
276
96
Msgs nogood
sum (values-from vertices [messages-received_nogood])
0
1

MONITOR
176
99
242
148
Msgs ok
sum (values-from vertices [messages-received_ok])
3
1

MONITOR
3
152
114
201
Number of cycles
nr_cicluri
0
1

SLIDER
4
113
176
146
edge-density
edge-density
0.5
5
1.5
0.1
1
NIL

SLIDER
106
151
278
184
num-colors
num-colors
0
10
3
1
1
NIL

SLIDER
72
199
244
232
max_cycle
max_cycle
0
1000000
999999
1
1
NIL

@#$#@#$#@
Title: Graph Coloring using DisDB 
Author: Ionel Muscalagiu and Jose M Vidal
Description:
We solve the graph coloring problem using the 
DisDB algorithm from  <ul>
 <li>Christian Bessiere, Arnold Maestre, Pedro Meseguer.  
<a href="http://www-sop.inria.fr/coprin/jnpc2002/actes_jnpc02/bessiere57.ps">
Distributed Dynamic Backtracking (english version).</a> or
<a href="http://www.lirmm.fr/~bessiere/stock/jnpc01-ddb.ps">
Distributed Dynamic Backtracking. </a>
In  Proceedings of the CP00 Workshop on Distributed Constraint Satisfaction Problems, Singapore, Thailand, 2000.</li>
</ul>
<p>
In the constraint graph, constraints are oriented forming a directed acyclic graph, from which an agent hierarchy may be built using heuristic criteria (max-degree, for instance) following the DisAO ordering scheme [Hamadi et al., 1998]. If no heuristic is used, this hierarchy defaults to lexicographic ordering among agents. Considering a generic agent self in the hierarchy, Gama<SUP>-</SUP>(self), it the set of agents constrained with self and appearing at higher levels in the hierarchy. Conversely, Gama<SUP>+</SUP>(self)  is the set of agents constrained with self  appearing at lower levels in the hierarchy. This hierarchy induces a partial order among agents, which should be completed to form the total order  (using for instance agents identifiers) to ensure completeness.
</p>
<p>
The DisDB algorithm is executed on each agent, keeping its own agent view and nogood store. The agent view of  self is the set of values that it believes to be assigned to agents before self  in the total order. The agent view is always consistent with the nogoods in the store. Agents exchange assignments and nogoods. DisDB always accepts new assignments, updating the agent view accordingly. When receiving a nogood, it is accepted if it is consistent with the agent view in Gama <SUP> -</SUP> (self) and self , otherwise it is discarded due to obsolescence. An accepted nogood is used to update the agent view of agents not in Gama<SUP>-</SUP>(self), and the set of stored nogoods. When all values of an agent are discarded by some nogood, the set of stored nogoods is resolved as in the centralised case, generating a new nogood which is sent to the variable in its right-hand side. This variable plus all variables in the left-hand side of the new nogood that are not in Gama<SUP>-</SUP>(self) are unassigned in the agent view, and nogoods are updated accordingly. The process  terminates when achieving quiescence, meaning that a solution has been found, or when the empty nogood is generated, meaning that the problem is unsolvable.

</p>
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -256 true false 151 152 137 77 105 67 89 67 66 74 48 85 36 100 24 116 14 134 0 151 15 167 22 182 40 206 58 220 82 226 105 226 134 222
Polygon -16777216 true false 151 150 149 128 149 114 155 98 178 80 197 80 217 81 233 95 242 117 246 141 247 151 245 177 234 195 218 207 206 211 184 211 161 204 151 189 148 171
Polygon -7566196 true true 246 151 241 119 240 96 250 81 261 78 275 87 282 103 277 115 287 121 299 150 286 180 277 189 283 197 281 210 270 222 256 222 243 212 242 192
Polygon -16777216 true false 115 70 129 74 128 223 114 224
Polygon -16777216 true false 89 67 74 71 74 224 89 225 89 67
Polygon -16777216 true false 43 91 31 106 31 195 45 211
Line -1 false 200 144 213 70
Line -1 false 213 70 213 45
Line -1 false 214 45 203 26
Line -1 false 204 26 185 22
Line -1 false 185 22 170 25
Line -1 false 169 26 159 37
Line -1 false 159 37 156 55
Line -1 false 157 55 199 143
Line -1 false 200 141 162 227
Line -1 false 162 227 163 241
Line -1 false 163 241 171 249
Line -1 false 171 249 190 254
Line -1 false 192 253 203 248
Line -1 false 205 249 218 235
Line -1 false 218 235 200 144

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@