breed [bins bin]
breed [pritrucks pritruck]
breed [pubtrucks pubtruck]

globals
[
  grid-x-inc               ;; the amount of patches in between two roads in the x direction
  grid-y-inc               ;; the amount of patches in between two roads in the y direction
  bin-population           ;  the number of bins
  new-load                 ;  waste units to be added per tick per bin
  total-waste-coll-pri     ;  waste units loaded on private trucks
  total-waste-coll-pub     ;  waste units loaded on public trucks
  total-waste-uncoll       ;  waste units still inside bins
 
  ;; patch agentsets
  intersections ;; agentset containing the patches that are intersections
  roads         ;; agentset containing the patches that are roads
  bin-spots     ;  agentset containing the patches with spots for bins
]

bins-own
[
  bin-load        ; waste units inside bin                
]

patches-own
[
  intersection?   ;; true if the patch is at the intersection of two roads
]

pritrucks-own
[
  up-car?   ;; true if the turtle moves downwards and false if it moves to the right
  load      ;; the current load of waste on a truck
  cost      ;; the cost of operation
  full?     ;; true if the waste on the truck has reached the max-capacity
]

pubtrucks-own
[
  up-car?   ;; true if the turtle moves downwards and false if it moves to the right
  load      ;; the current load of waste on a truck
  cost      ;; the cost of operation
  full?     ;; true if the waste on the truck has reached the max-capacity
]


;;;;;;;;;;;;;;;;;;;;;;
;; Setup Procedures ;;
;;;;;;;;;;;;;;;;;;;;;;


;------------------------------------------------------------------------------------------------------
;; Initialize the display by giving the global and patch variables initial values.
;; Create num-cars of turtles if there are enough road patches for one turtle to
;; be created per road patch. Set up the plots.
to setup

  ca
  setup-globals

  ;; First we ask the patches to draw themselves and set up a few variables
  setup-patches
  setup-bins

  if (num-private-trucks + num-public-trucks > 4 * ( grid-size-x + grid-size-y ) )
  [
    user-message (word "There are too many trucks for the amount of "
                       "road.  Either increase the amount of roads "
                       "by increasing the GRID-SIZE-X or "
                       "GRID-SIZE-Y sliders, or decrease the "
                       "number of trucks by lowering the NUMBER slider.\n"
                       "The setup has stopped.")
    stop
  ]

  ;; Now create the turtles and have each created turtle call the functions setup-cars and set-car-color
  create-pritrucks num-private-trucks
  [
    setup-pritrucks
  ]

  create-pubtrucks num-public-trucks
  [
    setup-pubtrucks
  ]

end


;------------------------------------------------------------------------------------------------------
;; Initialize the global variables to appropriate values
to setup-globals

  set grid-x-inc world-width / grid-size-x
  set grid-y-inc world-height / grid-size-y
  
  set total-waste-coll-pri 0
  set total-waste-coll-pub 0
  set total-waste-uncoll 0

end


;------------------------------------------------------------------------------------------------------
;; Make the patches have appropriate colors, set up the roads and intersections agentsets,
;; and initialize the traffic lights to one setting
to setup-patches

  ;; initialize the patch-owned variables and color the patches to a base-color
  ask patches
  [
    set intersection? false
    set pcolor brown + 3
  ]

  set roads patches with
    [(floor((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = 0) or
    (floor((pycor + max-pycor) mod grid-y-inc) = 0)]
  
  set intersections roads with
    [(floor((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = 0) and
    (floor((pycor + max-pycor) mod grid-y-inc) = 0)]

  set bin-spots patches with 
  [
    (
      (floor((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = 1) and
      (floor((pycor + max-pycor) mod grid-y-inc) = 1)
    )
    or
    (
      (floor((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = grid-x-inc - 1) and
      (floor((pycor + max-pycor) mod grid-y-inc) = 1)
    )
    or
    (
      (floor((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = 1) and
      (floor((pycor + max-pycor) mod grid-y-inc) = grid-y-inc - 1)
    )
    or
    (
      (floor((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = grid-x-inc - 1) and
      (floor((pycor + max-pycor) mod grid-y-inc) = grid-y-inc - 1)
    )
  ]

  ask roads [ set pcolor white ]

  ask intersections [ set pcolor gray + 3 ]

  ask bin-spots [ set pcolor 58 ]
  
  ; depot patch is yellow
  ask roads with [ ( pxcor = 16 ) and ( pycor = 16 ) ]
  [
    set pcolor yellow
  ]
  
  set bin-population count patches with [pcolor = 58]
    
  setup-intersections

end


;------------------------------------------------------------------------------------------------------
;; Give the intersections appropriate values
to setup-intersections

  ask intersections
  [
    set intersection? true
  ]

end


;------------------------------------------------------------------------------------------------------
to setup-bins

  create-bins bin-population
  [
    move-to one-of bin-spots with [not any? turtles-on self]
    set shape "box"
    set color green
    set size 1
    set bin-load random load-inc-step

    display-waste-in-bins
  ]

end


;------------------------------------------------------------------------------------------------------
;; Initialize the turtle variables to appropriate values and place the turtle on an empty road patch.
to setup-pritrucks  ;; turtle procedure

  set color blue
  set shape "truck"
  put-on-empty-road
  set load 0
  set cost 0
  set full? false
  set label ""

  ifelse intersection?
  [
    ifelse random 2 = 0
    [ set up-car? true ]
    [ set up-car? false ]
  ]
  [
    ; if the turtle is on a vertical road (rather than a horizontal one)
    ifelse (floor((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = 0)
    [ set up-car? true ]
    [ set up-car? false ]
  ]
  ifelse up-car?
  [ set heading 180 ]
  [ set heading 90 ]

end


;------------------------------------------------------------------------------------------------------
;; Initialize the turtle variables to appropriate values and place the turtle on an empty road patch.
to setup-pubtrucks  ;; turtle procedure

  set color red
  set shape "truck"
  put-on-empty-road
  set load 0
  set cost 0
  set full? false
  set label ""
  
  ifelse intersection?
  [
    ifelse random 2 = 0
    [ set up-car? true ]
    [ set up-car? false ]
  ]
  [
    ; if the turtle is on a vertical road (rather than a horizontal one)
    ifelse (floor((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = 0)
    [ set up-car? true ]
    [ set up-car? false ]
  ]
  ifelse up-car?
  [ set heading 180 ]
  [ set heading 90 ]

end


;------------------------------------------------------------------------------------------------------
;; Find a road patch without any turtles on it and place the turtle there.
to put-on-empty-road  ;; turtle procedure

  move-to one-of roads with [not any? turtles-on self]

end



;;;;;;;;;;;;;;;;;;;;;;;;
;; Runtime Procedures ;;
;;;;;;;;;;;;;;;;;;;;;;;;


;------------------------------------------------------------------------------------------------------
;; Run the simulation
to go

  ; change bins' content every hour = 60 minutes (ticks)
  if ( ticks mod 60 = 0 )
  [   
    ; "update" garbage disposed in the bins
    set new-load random load-inc-step

    ask bins
    [
      ifelse (bin-load < max-capacity-of-bins)
      [
        set bin-load bin-load + new-load  ; increases bin-load if waste units less than 100
        set color green  ; bins that are not full yet  stay green
      ]
      [
        set color black  ; FULL bins (waste units equal and more than 100) turn black
      ]
    ]
  ]
  
  display-waste-in-bins

  ; move garbage trucks
  ask pritrucks [ advance-trucks ]
  ask pubtrucks [ advance-trucks ]

  ; check and collect waste from bins
  ask pritrucks [ check-and-collect-waste ]
  ask pritrucks [ display-truck-load ]
  ask pritrucks [ check-capacity]
  
  ask pubtrucks [ check-and-collect-waste ]
  ask pubtrucks [ display-truck-load ]
  ask pubtrucks [ check-capacity]

  ; calculate Key Performance Indices
  set total-waste-coll-pri total-waste-coll-pri + sum [ load ] of pritrucks
  set total-waste-coll-pub total-waste-coll-pub + sum [ load ] of pubtrucks
  set total-waste-uncoll sum [ bin-load ] of bins
  
  ; refresh plots every hour = 60 minutes (ticks)
  if ( ticks mod 60 = 0 )
  [
    do-plotting
  ]
  
  ; refresh output every 24 hours = 1440 minutes (ticks)
  if ( ticks mod 1440 = 0 )
  [
    report-kpis
  ]
  
  tick

end


;------------------------------------------------------------------------------------------------------
;; Display units of waste inside a bin
to display-waste-in-bins

  ask bins [ set label "" ]
  if show-bin-load? [
    ask bins [ set label round bin-load ]
  ]

end


;------------------------------------------------------------------------------------------------------
;; Driving trucks
to advance-trucks
    ; decide new route on intersection
    if intersection?
    [
      let new-heading random 3
      ; new-heading 0 maintains current direction

      ; new-heading 1 turns right
      if (new-heading = 1)
      [
        rt 90
      ]

      ; new-heading 2 turns left
      if (new-heading = 2)
      [
        lt 90
      ]
    ] 
    
    ; drives one patch ahead
    if (not full?)
    [
      fd 1
      
      ; increase cost for public trucks on a tick basis
          if ( member? self pubtrucks )
          [
            set cost cost + ( cost-per-hour / 60 )
          ]
    ]
end



;------------------------------------------------------------------------------------------------------
;; Checking and collecting from bins
to check-and-collect-waste
  
    ; check if there are bins in the vicinity
    let bins-around (bins in-radius 1)
    
    ; calculate neighboring bins' load 
    let waste-around sum [bin-load] of bins-around 
    
    ; collect waste on the truck
    set load load + waste-around
    
      
    ; set neighboring bins to be empty of waste
    ask bins-around
    [
      set bin-load 0
    ]
    
    ; increase cost for private trucks on a waste unit basis
    if ( member? self pritrucks )
    [
      set cost cost + (waste-around * cost-per-waste-unit) 
    ]
     
end



;------------------------------------------------------------------------------------------------------
;; Display load of each garbage truck
to display-truck-load
  
    set label ""
    if (show-truck-load?)
    [
      set label load
    ]

end


;------------------------------------------------------------------------------------------------------
;; Check current load versus max-capacity of each garbage truck
to check-capacity
    
    if ( member? self pritrucks )
    [
      if ( load > max-capacity-of-private-trucks )
      [
        set full? true
        set color 0
        move-to-depot
      ]
    ]

    if ( member? self pubtrucks )
    [
      if ( load > max-capacity-of-public-trucks )
      [
        set full? true
        set color 0
        move-to-depot
      ]
    ]

end


;------------------------------------------------------------------------------------------------------
;; Move a FULL garbage truck to the depot
to move-to-depot
    
    ; move to upper-right patch with coordinates (16,16)
    setxy 16 16
    set heading 180
    
    ; unload waste
    set load 0
    set full? false

    ; restore original color
    if ( member? self pritrucks )
    [
        set color blue
    ]

    if ( member? self pubtrucks )
    [
        set color red
    ]
    
end




;;;;;;;;;;;;;;;;;;;;;;;;;
;; Plotting Procedures ;;
;;;;;;;;;;;;;;;;;;;;;;;;;


;; plot the data from this pass thru the go procedure
to do-plotting
  
  plot-new-value "Total Cost" "public-cost-pen" sum [ cost ] of pubtrucks
  plot-new-value "Total Cost" "private-cost-pen" sum [ cost ] of pritrucks
  plot-new-value "Total Waste Collected" "public-waste-collected-pen" total-waste-coll-pub
  plot-new-value "Total Waste Collected" "private-waste-collected-pen" total-waste-coll-pri
  plot-new-value "Total Waste Uncollected" "waste-uncollected-pen" total-waste-uncoll
  
end


to plot-new-value [ name-of-plot pen value ]
  
  set-current-plot name-of-plot
  set-current-plot-pen pen
  plot value
  
end


;; report basic statistics in the output area to monitor and assess the garbage collection process
to report-kpis
  
  output-type "Day : " output-print ticks / 1440
  output-type "Cost per waste unit collected         [Euro]  " output-print precision ( ( sum [ cost ] of pubtrucks + sum [ cost ] of pritrucks ) / ( total-waste-coll-pub + total-waste-coll-pri ) ) 3 
  output-type "Waste units (inside bins)/(bins+trucks)  [%]  " output-print round ( 100 * total-waste-uncoll / ( sum [ load ] of pubtrucks + sum [ load ] of pritrucks + total-waste-uncoll ) ) 
  output-print "----------------------------" 

end
@#$#@#$#@
GRAPHICS-WINDOW
302
10
774
503
16
16
14.0
1
10
1
1
1
0
1
1
1
-16
16
-16
16
0
0
1
minutes

SLIDER
9
10
104
43
grid-size-x
grid-size-x
1
9
3
1
1
NIL
HORIZONTAL

SLIDER
9
53
105
86
grid-size-y
grid-size-y
1
9
3
1
1
NIL
HORIZONTAL

BUTTON
146
10
291
58
Setup
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
7
260
144
293
load-inc-step
load-inc-step
1
50
20
1
1
NIL
HORIZONTAL

SWITCH
8
166
138
199
show-bin-load?
show-bin-load?
0
1
-1000

BUTTON
145
79
292
130
Go
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
7
343
141
376
num-private-trucks
num-private-trucks
0
20
8
1
1
NIL
HORIZONTAL

SLIDER
6
465
141
498
num-public-trucks
num-public-trucks
0
20
8
1
1
NIL
HORIZONTAL

SLIDER
148
344
293
377
cost-per-waste-unit
cost-per-waste-unit
0
50
5
1
1
NIL
HORIZONTAL

SLIDER
150
465
292
498
cost-per-hour
cost-per-hour
0
50
25
1
1
NIL
HORIZONTAL

SLIDER
7
385
201
418
max-capacity-of-private-trucks
max-capacity-of-private-trucks
0
500
200
10
1
NIL
HORIZONTAL

SLIDER
7
506
200
539
max-capacity-of-public-trucks
max-capacity-of-public-trucks
0
500
200
10
1
NIL
HORIZONTAL

SWITCH
144
166
294
199
show-truck-load?
show-truck-load?
0
1
-1000

PLOT
784
10
1230
153
Total Cost
hours
Euro
0.0
100.0
0.0
100.0
true
false
PENS
"private-cost-pen" 1.0 0 -13345367 true
"public-cost-pen" 1.0 0 -2674135 true

PLOT
783
162
1002
317
Total Waste Collected
hours
Waste units
0.0
100.0
0.0
100.0
true
false
PENS
"private-waste-collected-pen" 1.0 0 -13345367 true
"public-waste-collected-pen" 1.0 0 -2674135 true

TEXTBOX
69
321
263
341
PRIVATE TRUCKS [BLUE]
14
105.0
0

TEXTBOX
82
444
232
462
PUBLIC TRUCKS [RED]
14
15.0
0

PLOT
1011
162
1230
316
Total Waste Uncollected
hours
Waste units
0.0
10.0
0.0
10.0
true
false
PENS
"waste-uncollected-pen" 1.0 0 -16777216 true

OUTPUT
782
328
1232
550
12

TEXTBOX
113
236
166
254
BINS
14
0.0
1

SLIDER
152
260
294
293
max-capacity-of-bins
max-capacity-of-bins
0
100
60
1
1
NIL
HORIZONTAL

@#$#@#$#@
WHAT IS IT?
-----------
This model simulates the garbage collection operations in part of a city grid.


HOW IT WORKS
------------
BINS (agents) situated in the corners of blocks of a city (patches) are receiving waste units from local residents. The load increase step and the maximum capacity of the bins can be modified. Bin content increases randomly in a range defined by the load increase step on a hourly basis. When a bin reaches (and slightly exceeds) its capacity, it turns black and stops receiving more waste.

Garbage collection is undertaken by two different fleets of GARBAGE TRUCKS (breeds of agents). All trucks move around across the city road network with a speed of 1 road-patch/minute and have a maximum load capacity according to their type. PUBLIC (red) trucks' operation cost is defined on a time basis while PRIVATE (blue) trucks' operation cost is proportional to the collected waste units.

As soon as a garbage truck is full, its color turns black and is "teleported" to the north-eastern point of the city (yellow patch), where it dumps its waste. All empty garbage trucks return to duty.


HOW TO USE IT
-------------
Before starting the execution of the model the user should define the dimensions of the city and the bins' and garbage trucks' parameters.

During runtime, the tools for assessing the operation are graphs showing the cost of garbage collection and the volume of collected waste per type of truck as well as how many waste units are currently still inside the bins across the whole city on a hourly basis.

A text output area is refreshed on a daily basis in order to provide the values of certain key performance indices such as "Cost per waste unit collected" and "Percentage of waste units (inside bins)/(bins+trucks)". 


THINGS TO NOTICE
----------------
Changing the speed slider to a slower setting can give a sense of detail, while setting it to a faster speed one can quickly advance days of operation.

When the garbage trucks start to fall behind with waste collection bins situated far from the garbage depot (yellow patch) are the first ones to reach their maximum capacity due to their greater distance.


THINGS TO TRY
-------------
The efficiency of the operation is positively influenced by increasing the number of the trucks and their capacity, however this can seriously increase the cost if not done cautiously.


EXTENDING THE MODEL
-------------------
One extra feature would be the flexibility to place the bins in spots other than block corners. Also, a new population (breed) of bins can be added that would collect the recycling waste, which should be assigned to a third fleet(breed) of garabge trucks specialized for this type of waste. Finally, it would be more realistic if garbage trucks could drive back to empty their content, instead of being instantly teleported.


NETLOGO FEATURES
----------------
No particularly interesting features of NetLogo were used.


RELATED MODELS
--------------
The movement of the truck-agents is largely based on the cars of the "Traffic Grid" model from the Models Library. 


CREDITS AND REFERENCES
----------------------
This model has been developed by Christos Tzivanakis (2012) a student in the Department of Information Technology of A.?.?.?. of Thessaloniki (Greece) as part of his undergraduate thesis on "Intelligent Agent Applications" under the supervision of Dr. Demosthenes Stamatis.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
0
Rectangle -7500403 true true 151 225 180 285
Rectangle -7500403 true true 47 225 75 285
Rectangle -7500403 true true 15 75 210 225
Circle -7500403 true true 135 75 150
Circle -16777216 true false 165 76 116

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.1.3
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 1.0 0.0
0.0 1 1.0 0.0
0.2 0 1.0 0.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@