;; Note: 600 ticks is one "hour"
; Decalaring variables
breed [Tcells Tcell] ; There are two "breeds" of cells, tumour and healthy, represented by Tcells and Hcells, respectively
breed [Hcells Hcell]
Tcells-own [hypoxic?] ; Each cell can also have a variable. See Extending The Model on the Info tab.
globals[
Tsurvive ; number of tumour cells remaining
Hsurvive ; number of healthy cells remaining
numdoses ; number of fractions completed
lifeT ; lifetime of tumour cells
lifeH ; lifetime of healthy cells
]
;; The other variables are declared through creating the inputs in the interface tab:
;; "fractions", "hours", "dose", "alpha" and "beta".
;; This is what happens when the SETUP button is pushed
to setup
clear-all ;all old data is cleared
set lifeT 720 ; in hours.
set lifeH 2160
create-Tcells 5000 [ ;Make 5000 tumour cells
setxy (random 45) random-ycor ; Distribute them randomly on the right side of the tissue sample
set shape "dot" ; Gives their shape, colour, and size
set color red
set size 4 ]
create-Hcells 5000 [ ; Same for the healthy cells, put put them only on the left
setxy (random -45) random-ycor
set shape "dot"
set color green
set size 4 ]
reset-ticks ;reset the counter
end
;; This is what happens when the GO button is pushed
to go
if (count Tcells <= 5 or count Hcells <= 20) [ ; Set cutoff point: If there are 5 or less Tcells or 20 or less Hcells, the program stops
output-write round (100 * count Hcells / 5000) ; This prints the information that shows up in the box in the interface
output-print "% of the healthy cells remain and "
output-write numdoses
output-print " treatments were given."
output-print "Total dose delivered:"
output-write numdoses * dose
output-print " Gy"
stop]
plot-surviving ; calls the plotting procedures (see below)
plot-logSurvival
;; put tick here instead if you don't want the radiation to start on tick 0
ask Hcells [ ;; on each tick, the healthy cells have a probability of dividing
if (random-float lifeH * 600 <= 1) [hatch 1];;
if (count turtles-here > 1)[ ; if there is more than one cell in a region
ifelse xcor > 0 ; if the cells position is to the right of the center of the sample
[set heading 270] ; Spins cell to be "facing" to the left - corresponds to when xcor>0
[set heading random-float 359] ; Has cell point in a random direction - corresponds to when turtles-here>1
fd 1] ; move forward in direct of heading by one unit
]
ask Tcells [
if (random-float lifeT * 600 <= 1) [hatch 1]
if (count turtles-here > 1)[
ifelse xcor < 0
[set heading 90]
[set heading random-float 359]
fd 1]
]
;; Procedure for when treatment is given
if (ticks mod (hours * 600) = 0 and ticks < Fractions * hours * 600) [ ; specifies when radiation is applied
; The following equations determines if each cell survives the treatment
ask Tcells [ ; call on each tumour cell
if (random-float 1.0 < 1 - exp((-1 * ((Dose * alpha) + (beta * Dose ^ 2))))) [die]] ; this is where you could add an extra condition to check if the cell is hypoxic, and have only oxic cells die.
ask Hcells [
if (random-float 1.0 < 1 - exp((-1 * ((Dose * 0.1) + (0.1 * Dose ^ 2))))) [die]]
set numdoses numdoses + 1 ; counts the number of treatments given
]
tick ; Raises tick counter by 1
end
;; the two plotting procedures:
to plot-surviving ; plots the number of remaining cells after each tick
set-current-plot "Survival"
set-current-plot-pen "Tumour"
plotxy ticks count Tcells ;; plots the number of Tcells versus the number of ticks so far
set-current-plot-pen "Healthy"
plotxy ticks count Hcells
end
to plot-logSurvival
set-current-plot "logSurvival"
set-current-plot-pen "TumourL"
plotxy ticks log count Tcells 10 ; the 10 specifies log base 10
set-current-plot-pen "HealthyL"
plotxy ticks log count Hcells 10
end
@#$#@#$#@
GRAPHICS-WINDOW
230
11
628
410
-1
-1
4.29
1
10
1
1
1
0
0
0
1
-45
45
-45
45
0
0
1
ticks
30.0
BUTTON
14
508
69
541
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1
BUTTON
103
509
158
542
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1
PLOT
640
371
960
676
Survival
ticks
Number of remaining cells
0.0
10.0
0.0
10.0
true
true
"" ""
PENS
"Tumour" 1.0 0 -2674135 true "" ""
"Healthy" 1.0 0 -10899396 true "" ""
INPUTBOX
88
339
144
399
beta
0.04
1
0
Number
INPUTBOX
7
339
66
399
alpha
0.3
1
0
Number
INPUTBOX
88
173
151
233
hours
8.0
1
0
Number
INPUTBOX
91
81
153
141
Fractions
30.0
1
0
Number
PLOT
638
10
964
322
logSurvival
ticks
log (number of remaining cells)
0.0
10.0
0.0
4.0
true
true
"" ""
PENS
"TumourL" 1.0 0 -2674135 true "" ""
"HealthyL" 1.0 0 -14439633 true "" ""
OUTPUT
229
447
631
555
15
TEXTBOX
11
54
214
92
Enter the number of fractions
15
0.0
1
TEXTBOX
8
138
231
203
Enter the time between fractions
15
0.0
1
TEXTBOX
9
297
221
335
Enter the alpha and beta values for the tumour cells
15
0.0
1
TEXTBOX
9
236
227
274
Enter the dose per fraction
15
0.0
1
TEXTBOX
6
407
223
502
Press \"setup\" before each trial and \"go\" to start. The program will stop automatically when only 0.1% of the tumour cells remain.
15
0.0
1
TEXTBOX
11
10
161
35
Set-up options
20
0.0
1
TEXTBOX
642
327
960
403
The above is a semi-log plot of the number of cells remaining versus elapsed time.
15
0.0
1
TEXTBOX
644
685
970
761
The above is a plot of the number of cells remaining versus elapsed time.
15
0.0
1
SLIDER
8
259
180
292
dose
dose
0
6
1.2
0.2
1
NIL
HORIZONTAL
@#$#@#$#@
# A NetLogo Model For Fractionated Radiation Treatment
## WHAT IS IT?
This is a basic model of the effect of radiation treatment on healthy tissue and tumour tissue as predicted by the Linear Quadratic (LQ) model of cell survival. The healthy tissue is modelled in green and the cancer cells in red. As predicted by the LQ model, the two types of cells respond differently to radiation. The LQ model assumes the surviving fraction to be given by:
S = exp (-α*d -β*d2)
where d is the dose and α and β are free parameters used to fit the model to experimental results from the irradiation of different tissue types.
The "tissue sample" seen in the interface represents the interface between a tumour and the surrounding normal tissue.
This model can be used to develop an understanding of fractionated radiation treatment planning. During fractionated radiation treatment, a patient receives small doses of radiation over many treatments.
## HOW IT WORKS
Each cell has a probability of undergoing cell division; since cancerous cells divide more rapidly, their probability of dividing is higher. When the radiation is applied, each cell has a probability of dying, according to the LQ model. By adjusting the time between treatments and the dose per fraction, an ideal treatment can be developed such that a maximum about of healthy tissue remains after 99.9% of the cancer has been eliminated.
The model starts with 5000 of each type of cell, and the first fraction is applied on the first tick.
## HOW TO USE IT
The SETUP button creates the tissue sample. The GO button runs the treatment simulation.
The set-up options determine the type of treatment. The `Fractions` input sets the maximum number of fractions that are applied. The time between fractions is given by the `hours` input. The dose applied per fraction, in Gray, is given by the `dose` input.
The `alpha` and `beta` inputs can be used to adjust the parameters for the tumour.
## THINGS TO NOTICE
#### Interface layout
If you want to re-adjust the layout of the interface tab to better fit your computer screen, you can select each item and move it or adjust its size.
#### Plots
There are two plots included in the model. On the Survival plot, the number of each cell type is plotted for each tick, while on the logSurvival plot, the population is a semi-log plot, meaning the log of the population is plotted. Most of the plots of cell survival in the literature are on semi-log scales. Looking at the equation for cell survival in the LQ model, what is the benefit to a semi-log scale? Consider how the plots look when the populations are small.
#### Regrowth
Looking at the Survival plot, notice the increase in population between fractions. The tumour cells are more likely to divide and therefore have more regrowth between fractions.
## THINGS TO TRY
* Apply only a single fraction of radiation. Compare the ratio of surviving tumour and healthy cells directly after treatment using the Survival plot. What is the dose at which more tumour cells survive the radiation than healthy cells? Allow the simulation to continue running. What happens?
* Use the graphing software of your choice to plot the above equation for cell survival for alpha beta values of (0.1, 0.1) and (0.3, 0.04). Use a semi-log plot and a range of 0 to 8. Verify that the dose you found for the point at which equal amounts of tumour and healthy cells survive corresponds to the point where the two equations cross.
* Develop a fractionated treatment schedule by adjusting the time between doses and the dose amount. Set the number of fractions to 20 so that the program ends before the treatment ends. Try some of the following:
* A conventional treatment: 2 Gy every 24 hours
* Hyperfractionation: 1 to 1.5 Gy multiple times in a day
* Accelerated hyperfractionation: 1 to 1.5 Gy three times a day for one week
* Adjust the parameters until you find a treatment with the maximum number of surviving healthy tissue. Consider the plot you made in the last activity. Where does there seem to be the largest potential for keeping healthy tissue alive? Look at the gap between the two equations.
* Run a fractionated treatment a few times and determine the average number of treatments applied before the program stops. Run the model again with `Fractions` set to be one less than this number. What happens? How long after treatment does the tumour population overtake the number of healthy cells?
* The lifetime of a cell varies greatly between different types of tissues. This model uses a lifetime of 1 month for the cancer cells and 3 months for the healthy tissue. Try adjusting these values by changing the values of `lifeT` and `lifeH` within the `setup` command procedure in the code.
* Have the model also output the biologically effective dose (BED) in the Output box. BED is given by:
(numdoses * Dose * ( 1 + Dose / (alpha / beta) ))
The above is properly formatted syntax. Look at the code for printing the output at the beginning of the `go` command procedure and add this in. Note: `numdoses` is the actual number of treatments applied, NOT the maximum number you set with the `Fractions` variable.
* Select the dose slider and adjust the range of allowed values and experiment with doses even higher than 6 Gray. You might get an error. Why? Try and fix this.
* Adjust the `alpha` and `beta` values for the tumour cells to correspond to different types of cancer. Warning: you should first plot the survival curve for these new values and the values used for the healthy cells (0.1, 0.1) to check that they are reasonable.
## TROUBLE SHOOTING
#### The program takes too long to run
The program can take up to 10 minutes to run, especially when there is a long time between fractions. To help speed it up, deselect "view updates" at the top of the interface tab.
#### Runtime Error: "Can't take logarithm of 0"
This error occurs when high doses are used; the population decreases too rapidly for the program to end before reaching an error. Click "Dismiss" and run the simulation again. You may need to use a smaller dose, or adjust the cut-off point in the code.
#### Slider Stops Working
Select the dose slider by right clicking it, move it around the interface, and deselect it by clicking elsewhere on the screen. Repeat until it works.
## EXTENDING THE MODEL
* Develop treatment schedules other than evenly spaced fractionated treatments. Often patients will only receive treatment 5 days a week. Adjust the code to have radiation applied in fractions which are not equally spaced.
* Hypoxic cells are significantly less sensitive to radiation than well-oxygenated (oxic) cells (Steel, 2010). After irradiation, most of the oxic cells will be killed, leaving a tumour consisting of nearly entirely hypoxic cells. It has been found that after irradiation the tumour undergoes reoxygenation, which restores the ratio of hypoxic to oxic cells. It can take anywhere from minutes to days for a tumour to undergo reoxygenation. If the next fraction of radiation is applied while most of the tumour is still hypoxic, the radiation will be less effective. This sets a lower limit on the time between fractions and a treatment planner should be aware of balancing regrowth with reoxygenation. Expand the model to include reoxygenation by using the variable `hypoxic?`.
* Hypoxic cells are also more likely to undergo metastasis. Allow hypoxic cells to spread into the healthy tissue on the left side of the tissue sample.
## CREDITS AND REFERENCES
For a good overview of alpha-beta ratios and the LQ model, see:
Eye Physics, 2014. _Biological Models._ [online] Available at:
For a more in-depth explanation of the rationale behind the LQ model, and its validity compared to other models, see:
Brenner, D., 2009. Point: The linear-quadratic model is an appropriate methodology for determining iso-effective doses at large doses per fraction. _National Institutes of Health_, 18(4), pp.234–239.
For more information about the effects of hypoxia on radiosensitivy in fractionated treatment, see chapters 15 and 16 in:
Steel, G. ed., 2002. _Basic Clinical Radiobiology_. 3rd ed. London: Arnold.
This model was developed by Alexandra Kasper as part of ISCI 3A12 at McMaster University during the winter term of 2014. If you have questions about the model, e-mail alexandrakskasper@gmail.com.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250
airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15
arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150
box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75
bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30
butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60
car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58
circle
false
0
Circle -7500403 true true 0 0 300
circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123
cylinder
false
0
Circle -7500403 true true 0 0 300
dot
false
0
Circle -7500403 true true 90 90 120
face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240
face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225
face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183
fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30
flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45
flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240
house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120
leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195
line
true
0
Line -7500403 true 150 0 150 300
line half
true
0
Line -7500403 true 150 0 150 150
monster
false
0
Polygon -7500403 true true 75 150 90 195 210 195 225 150 255 120 255 45 180 0 120 0 45 45 45 120
Circle -16777216 true false 165 60 60
Circle -16777216 true false 75 60 60
Polygon -7500403 true true 225 150 285 195 285 285 255 300 255 210 180 165
Polygon -7500403 true true 75 150 15 195 15 285 45 300 45 210 120 165
Polygon -7500403 true true 210 210 225 285 195 285 165 165
Polygon -7500403 true true 90 210 75 285 105 285 135 165
Rectangle -7500403 true true 135 165 165 270
pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120
person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105
petals
false
0
Circle -7500403 true true 117 12 66
Circle -7500403 true true 116 221 67
Circle -7500403 true true 41 41 67
Circle -7500403 true true 11 116 67
Circle -7500403 true true 41 191 67
Circle -7500403 true true 191 191 67
Circle -7500403 true true 221 116 67
Circle -7500403 true true 191 41 67
Circle -7500403 true true 60 60 180
plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90
sheep
false
15
Circle -1 true true 203 65 88
Circle -1 true true 70 65 162
Circle -1 true true 150 105 120
Polygon -7500403 true false 218 120 240 165 255 165 278 120
Circle -7500403 true false 214 72 67
Rectangle -1 true true 164 223 179 298
Polygon -1 true true 45 285 30 285 30 240 15 195 45 210
Circle -1 true true 3 83 150
Rectangle -1 true true 65 221 80 296
Polygon -1 true true 195 285 210 285 210 240 240 210 195 210
Polygon -7500403 true false 276 85 285 105 302 99 294 83
Polygon -7500403 true false 219 85 210 105 193 99 201 83
square
false
0
Rectangle -7500403 true true 30 30 270 270
square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240
star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108
target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60
tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152
triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255
triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224
truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42
turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99
wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269
wolf
false
0
Polygon -16777216 true false 253 133 245 131 245 133
Polygon -7500403 true true 2 194 13 197 30 191 38 193 38 205 20 226 20 257 27 265 38 266 40 260 31 253 31 230 60 206 68 198 75 209 66 228 65 243 82 261 84 268 100 267 103 261 77 239 79 231 100 207 98 196 119 201 143 202 160 195 166 210 172 213 173 238 167 251 160 248 154 265 169 264 178 247 186 240 198 260 200 271 217 271 219 262 207 258 195 230 192 198 210 184 227 164 242 144 259 145 284 151 277 141 293 140 299 134 297 127 273 119 270 105
Polygon -7500403 true true -1 195 14 180 36 166 40 153 53 140 82 131 134 133 159 126 188 115 227 108 236 102 238 98 268 86 269 92 281 87 269 103 269 113
x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270
@#$#@#$#@
NetLogo 6.0.2
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180
@#$#@#$#@
0
@#$#@#$#@