;;; ISING MODEL WITH THE BA NETWORK ;;;

turtles-own [
  spin
]

globals [
  sum-of-spins
  moving-turtle
  moving-turtles
]

;;;;;;;;;;;;;;;;;;;;;
;; SETUP PROCEDURE ;;
;;;;;;;;;;;;;;;;;;;;;

to setup 
  ;; (for this model to work with NetLogo's new plotting features,
  ;; __clear-all-and-reset-ticks should be replaced with clear-all at
  ;; the beginning of your setup procedure and reset-ticks at the end
  ;; of the procedure.)
  clear-all
  set-default-shape turtles "circle"
  set moving-turtle nobody
  set moving-turtles turtle-set nobody
  
  ;; depending on which type of network the user chooses
  ;; we can create different types of networks
  if network-type = "Preferential Attachment" 
  [ create-initial-nodes
    repeat N - m0 [ make-node-with preferential-group ] ]
  
  if network-type = "Fully Connected" 
  [ make-node N
    ask turtles 
    [ create-links-with other turtles 
      set size 3 ]
    layout-circle turtles 0.9 * max-pxcor ]
  
  if network-type = "Random Network" 
  [ make-node N
    ask turtles 
    [ repeat m 
      [ create-link-with one-of other turtles 
        set size 3 ] ]
    layout-circle turtles 0.9 * max-pxcor ]
  set sum-of-spins sum [spin] of turtles
  setup-plot
  plotxy 0 magnetization
  plot-degree
  reset-ticks
end

;; Creating a Preferential Attachment Network ;;

;; create m0 initial nodes so that every node is connected to 
to create-initial-nodes
  repeat m0 
  [ make-node-with one-of other turtles ]; with [not link-neighbor? self] ] ;;do we need this part?
end
    
;; Idea: first create a function that takes two turtles as inputs and when executed, links the two
;; Next, repeat N times the following: create new node, link to m separate lottery winners
to make-node [arg]
  crt arg
  [ ifelse random-float 2 < initial-magnetization + 1
    [ set spin 1 ]
    [ set spin -1 ]
    recolor ]
end
    
;; used for creating a new node.
;; if TARGET is a single agent, link with that agent
;; if TARGET is a set of agents, link with all agents.
to make-node-with [target]
  make-node 1
  ask max-one-of turtles [who] ;; the last turtle added
  [ if target != nobody
      [ if is-agent? target 
        [ create-link-with target [ set color gray ] 
          move-to target ]
        if is-agentset? target 
        [ create-links-with target[ set color gray ] 
          move-to one-of target ]
        ;; position the new node near its partner
        fd 20 ] ]
end

to-report preferential-group
  ;; connect the turtle to m number of partners
  ;; start by creating one target
  let targets (turtle-set find-partner)
  repeat (m - 1) 
  [ let next-node find-partner
    
    ;; add a target that is not already a target
    while [member? next-node targets]
      [set next-node find-partner ]
    
    set targets (turtle-set targets next-node) ]
  report targets
end
  

;; This code is borrowed from Lottery Example (in the Code Examples
;; section of the Models Library).
;; The idea behind the code is a bit tricky to understand.
;; Basically we take the sum of the degrees (number of connections)
;; of the turtles, and that's how many "tickets" we have in our lottery.
;; Then we pick a random "ticket" (a random number).  Then we step
;; through the turtles to figure out which node holds the winning ticket.
to-report find-partner
  let total random-float sum [count link-neighbors] of turtles
  let partner nobody
  ask turtles
  [ let nc count link-neighbors
    ;; if there's no winner yet...
    if partner = nobody
    [ ifelse nc > total
        [ set partner self ]
        [ set total total - nc ] ] ]
  report partner
end

;; This is the coloring procedure for an individual turtle
to recolor
  ifelse spin = 1
    [ set color blue + 2 ]
    [ set color blue - 2 ]
end  

;;;;;;;;;;;;;;
;;; Layout ;;;
;;;;;;;;;;;;;;

;; resize-nodes, change back and forth from size based on degree to a size of 1
to resize-nodes
  ifelse all? turtles [size <= 1]
  [ ;; a node is a circle with diameter determined by
    ;; the SIZE variable; using SQRT makes the circle's
    ;; area proportional to its degree
    ask turtles [ set size sqrt count link-neighbors ] ]
  [ ask turtles [ set size 1 ] ]
end

to layout
  ;; the number 3 here is arbitrary; more repetitions slows down the
  ;; model, but too few gives poor layouts
  repeat 3  [
    ;; the more turtles we have to fit into the same amount of space,
    ;; the smaller the inputs to layout-spring we'll need to use
    let factor sqrt count turtles
    ;; numbers here are arbitrarily chosen for pleasing appearance
    ifelse manual-layout?
    [ layout-spring turtles links spring-constant spring-length repulsion-constant ]
    [ layout-spring turtles links (1 / (factor)) (7 / factor) (7 / factor) ]
    display  ;; for smooth animation
  ]
  ;; don't bump the edges of the world
  let x-offset max [xcor] of turtles + min [xcor] of turtles
  let y-offset max [ycor] of turtles + min [ycor] of turtles
  ;; big jumps look funny, so only adjust a little each time
  set x-offset limit-magnitude x-offset 0.1
  set y-offset limit-magnitude y-offset 0.1
  ask turtles [ setxy (xcor - x-offset / 2) (ycor - y-offset / 2) ]
end

to-report limit-magnitude [number limit]
  if number > limit [ report limit ]
  if number < (- limit) [ report (- limit) ]
  report number
end

;;;;;;;;;;;;;;
;;;;  GO  ;;;;
;;;;;;;;;;;;;;


to go
  ask one-of turtles [ update ]
  tick
  if ticks mod plotting-interval = 0
    [ set-current-plot "Magnetization"
      plotxy ticks magnetization ]
  plot-degree
end

to update  ;; turtle procedure, update is for ising, update-metropolis is for potts
  ;; flipping changes the sign on our energy, so the difference in energy
  ;; if we flip is -2 times our current energy
  let Ediff 2 * spin * sum [spin] of link-neighbors
  if (Ediff <= 0) or
     (temperature > 0 and (random-float 1.0 < exp ((- Ediff) / temperature)))
    [ set spin (- spin)
      set sum-of-spins sum-of-spins + 2 * spin
      recolor ]
end

;;;;;;;;;;;;;;;;;;;;;;;;;
;;; PLOTTING PROCEDURE ;; 
;;;;;;;;;;;;;;;;;;;;;;;;;

to-report magnetization
  report sum-of-spins / count turtles
end

to setup-plot
  set-current-plot "Magnetization"
  ;; draw a horizontal line to show the x axis
  set-current-plot-pen "axis"
  auto-plot-off
  plotxy 0 0
  plotxy 1000000000000000 0
  auto-plot-on
  set-current-plot-pen "average spin"
  
  let max-degree max [count link-neighbors] of turtles
  set-current-plot "Degree Distribution"
  plot-pen-reset 
  set-plot-x-range 1 (max-degree + 1)
  histogram [count link-neighbors] of turtles
end

to plot-degree
    let max-degree max [count link-neighbors] of turtles
  set-current-plot "Degree Distribution"
  plot-pen-reset 
  set-plot-x-range 1 (max-degree + 1)
  histogram [count link-neighbors] of turtles
end

;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ADJUSTING PROCEDURES ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;

;; The user has the option of changing the nodes
;; in order to make it easier to visualize, or test stuff.

to move-node
  if style = "click and drag" 
  [ if mouse-inside? 
    [ do-highlight
      if mouse-down? [while [mouse-down?] [move display] ] 
    ] 
  ]
  
  if style = "radial layout" 
  [ if mouse-inside? [ do-highlight 
    if mouse-down? [
      if moving-turtle != nobody 
      [ layout-radial turtles links moving-turtle display] ]]
    ]
  
  if style = "set spin" 
  [ if mouse-inside? [ do-highlight ]
    if mouse-down? 
    [ if move-type = "turtle" [ ask moving-turtle [ifelse set-spin-1 [set spin 1] [set spin -1]]]
      if move-type = "turtle and neighbors" [ ask (turtle-set moving-turtles moving-turtle) [ifelse set-spin-1 [set spin 1] [set spin -1]]]
      if move-type = "turtle and subordinates" [ask (turtle-set moving-turtles moving-turtle) [ifelse set-spin-1 [set spin 1] [set spin -1]]] ] ]
  
  
  if style = "circle" 
  [ if mouse-inside? [ do-highlight 
    if mouse-down? [
      if moving-turtle != nobody 
      [ layout-circle turtles 0.9 * max-pxcor] ]]
    ]
  
  
  if mouse-inside? != true
  [ reset-perspective
    ask turtles [recolor]
    ask links [set color gray] ]
  display
end


to do-highlight
  ;; getting the node closest to the mouse
  let min-d min [distancexy mouse-xcor mouse-ycor] of turtles
  let node one-of turtles with [count link-neighbors > 0 and distancexy mouse-xcor mouse-ycor = min-d]
  if node != moving-turtle [
    ask links [set color gray]
    ask turtles [recolor]
  ]
  set moving-turtle node
  
  if node != nobody
  [
    ;; highlight the chosen node
    ask node
    [ set color pink - 1
      watch-me ]
    
    let neighbor-nodes [ link-neighbors ] of node
    set moving-turtles neighbor-nodes
    let direct-links [ my-links ] of node
    ;; highlight neighbors
    ask neighbor-nodes
    [ set color orange + 2

      ;; highlight edges connecting the chosen node to its neighbors
      ask my-links 
      [ ifelse (end1 = node or end2 = node)
        [ set color blue - 1 ]
        [ if (member? end1 neighbor-nodes and member? end2 neighbor-nodes)
            [ set color yellow ] ]
      ]
    ]
  ]
end

to move
  let factor sqrt count turtles 
  if moving-turtle != nobody 
  [ let number count moving-turtles

    
    if move-type = "agent and neighbors"
    [ set moving-turtles [link-neighbors] of moving-turtle
      ask moving-turtle [setxy mouse-xcor mouse-ycor]
;      ask moving-turtles [set heading towards moving-turtle - 180]
;      ask (turtle-set moving-turtle moving-turtles) [setxy mouse-xcor mouse-ycor]
      layout-spring moving-turtles [my-links] of moving-turtle (1 / (factor)) (70 / (factor)) (70 / (factor))
    ]
    if move-type = "agent"
    [ ask moving-turtle [setxy mouse-xcor mouse-ycor ] 
    ] 
    if move-type = "agent and subordinates"
    [ set moving-turtles ([link-neighbors] of moving-turtle) with [count link-neighbors < [count link-neighbors] of moving-turtle]
      ask moving-turtle [setxy mouse-xcor mouse-ycor]
;      ask moving-turtles [set heading towards moving-turtle - 180]
;      ask (turtle-set moving-turtle moving-turtles) [setxy mouse-xcor mouse-ycor]
      layout-spring moving-turtles [my-links] of moving-turtle (1 / (factor)) (70 / (factor)) (70 / (factor))
    ]
  ]
end
@#$#@#$#@
GRAPHICS-WINDOW
280
15
773
529
80
80
3.0
1
10
1
1
1
0
0
0
1
-80
80
-80
80
0
0
1
ticks
30.0

SLIDER
25
345
197
378
N
N
0
1000
459
1
1
NIL
HORIZONTAL

SLIDER
25
380
197
413
m0
m0
2
10
3
1
1
NIL
HORIZONTAL

BUTTON
25
35
87
68
Setup
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
100
225
167
258
Layout
layout
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
880
225
1052
258
plotting-interval
plotting-interval
1
1000
224
1
1
NIL
HORIZONTAL

SLIDER
25
125
197
158
temperature
temperature
0
10
0.83
0.01
1
NIL
HORIZONTAL

PLOT
780
15
1050
215
Magnetization
time
average spin 
0.0
20.0
-1.0
1.0
true
false
"" ""
PENS
"average spin" 1.0 0 -13345367 true "" ""
"axis" 1.0 0 -16777216 true "" ""

BUTTON
25
225
88
258
Go
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

MONITOR
780
225
870
270
NIL
magnetization
3
1
11

SLIDER
25
415
197
448
m
m
1
10
1
1
1
NIL
HORIZONTAL

SLIDER
25
510
197
543
spring-length
spring-length
0
100
5.7
0.1
1
NIL
HORIZONTAL

SLIDER
25
545
197
578
repulsion-constant
repulsion-constant
0
10
0.83
0.01
1
NIL
HORIZONTAL

SLIDER
25
580
197
613
spring-constant
spring-constant
0
10
1.27
0.01
1
NIL
HORIZONTAL

SWITCH
25
475
145
508
manual-layout?
manual-layout?
1
1
-1000

CHOOSER
25
75
206
120
network-type
network-type
"Preferential Attachment" "Fully Connected" "Random Network"
0

PLOT
1060
15
1325
215
Degree Distribution
degree
# of nodes
1.0
10.0
0.0
10.0
true
false
"" ""
PENS
"default" 1.0 1 -16777216 true "" ""

BUTTON
785
400
879
433
NIL
move-node
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

CHOOSER
785
450
960
495
style
style
"click and drag" "radial layout" "circle" "set spin"
0

CHOOSER
965
450
1142
495
move-type
move-type
"agent" "agent and neighbors" "agent and subordinates"
1

BUTTON
25
265
95
298
Resize
resize-nodes
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SWITCH
785
500
896
533
set-spin-1
set-spin-1
1
1
-1000

SLIDER
25
160
197
193
initial-magnetization
initial-magnetization
-1
1
0
0.01
1
NIL
HORIZONTAL

MONITOR
965
385
1042
430
#neighbors
[count link-neighbors ] of moving-turtle
17
1
11

BUTTON
880
400
943
433
calib
set sum-of-spins sum [spin] of turtles
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

MONITOR
1050
385
1137
430
moving-turtle
[who] of moving-turtle
17
1
11

TEXTBOX
25
20
175
38
Setup
12
0.0
1

TEXTBOX
25
210
175
228
Running the model
12
0.0
1

TEXTBOX
785
385
935
403
Moving nodes
12
0.0
1

TEXTBOX
25
330
175
348
Variables
12
0.0
1

TEXTBOX
25
460
175
478
Layout options
12
0.0
1

@#$#@#$#@
## WHAT IS IT?

This model studies how social decision, known as magnetization, changes over time. Social decision is modeled as the average opinion of all agents. Agents have one of two opinions. They adjust their opinion over time based on their current opinion, the opinions of their related agents, and the global ease of opinion change. As agent opinion changes, so does social decision.

## HOW IT WORKS

The two possible opinions are modeled as +1 and -1 and are also called the spin of the agent. When the model is initially setup, each agent is randomly assigned an opinion. As the simulation runs, agents adjust their opinion. This adjustment depends on two factors; the difference between an agent's opinion and the opinions of their neighbors, and the global temperature variable. If the sum of all the spins of an agent's neighbors has an opposite sign than the agent's spin, then then the agent changes its opinion. If the signs are the same, then there is still the possibility that the agent will switch spins. This depends on the temperature variable and a random component; the full details are described in the code under the GO section. As the simulation runs and agents change their opinion, the user can track the magnetization over time.

## HOW TO USE IT

There are three different options in the setup of the simulation: Preferential Attachment, Fully Connected, and Random Network.

-Preferential Attachment: Arranges N agents into preferential groups determined by the m0 and m variables.
-Fully Connected: Arranges N agents into a circle and connects each agent with every other agent.
-Random Network: Arranges N agents into a circle. Then each agent creates links with m random other agents. Though each agent may only select m targets, it is possible for one agent to be the target of more than m other agents. 

After selecting the setup procedure, the agents will appear on the screen. Agents are colored two different shades of blue. Darker blue represents spin -1, and lighter blue represents spin +1. To get a better look at the colors of the agents, press the resize button to increase their size. Press it again to change the agent size back to normal.

When using the Preferential Attachment setup, the Layout button may be pushed to give a better view of the structure. Press the Layout button again to stop the movement. By selecting On from the manual-layout? switcher, you can use the spring-length, repulsion-constant, and spring-constant sliders to adjust the layout options.

You may now start the simulation by pressing the Go button. Agent's will adjust their opinion and change their color. In addition, the change in magnetization will be tracked on the plot on the right side of the interface. Adjusting the plotting-interval slider will change the update frequency of the plot. When you have finished, press the Go button again to stop the simulation. The magnetization will be recorded in the monitor box labeled magnetization. This is the average spin of all the agents, and it represents the social decision of the agents.

If you wish to move the agents around, press the move-nodes button. This will allow you to move the various agents. There are four options under the style chooser. These will allow you to adjust the layout of the agents, and also the set spin option will allow you to change the spin of selected agents. In conjunction with the set spin option, the set-spin-1? chooser decides what spin the agents are changed too; +1 if it is On, and -1 if it is Off. The calib button will then recalculate the magnetization after the spins are adjusted. Furthermore, the move-type chooser will allow you to adjust which agents move, if it is just the agent you select, or if additional agents will move as well. The agent being moved and the number of other agents being moved with it are tracked by the two corresponding monitor boxes.


## THINGS TO NOTICE

Notice how magnetization changes over time, and how this differs how models of the three setup types.

## THINGS TO TRY

Adjust the initial magnetization to see how this affects magnetization over time. Adjust the sliders under the Variables header to see how they affect the various setups, and therefore the magnetization. Adjust the temperature variable to alter the likelihood of opinion changing, which in turn will affect the magnetization and social decision of the simulation.

## EXTENDING THE MODEL

Given that it is still possible for an agent to change its opinion despite complete magnetization given a high enough temperature variable, it may be interesting to see what happens when one adjusts the procedure that determines if an agent changes its opinion due to change. This function depends on the temperature, the agent's own spin, the sum of spins from the agent's linked neighbors, and a random uniform draw. By changing this function, one may change the outcome of the magnetization in this simulation. The function is found in the GO section of the code.

## RELATED MODELS

Axelrod
Confident Voter
Heterogeneous Voter
Social Consensus
Potts
Turnout

@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
0
Rectangle -7500403 true true 151 225 180 285
Rectangle -7500403 true true 47 225 75 285
Rectangle -7500403 true true 15 75 210 225
Circle -7500403 true true 135 75 150
Circle -16777216 true false 165 76 116

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.1.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
1
@#$#@#$#@