; Experiment with first setup of an integrated Learning Network Simulator
; (c) Rob Koper, March/April 2004 (small revisions: June 2004)
; This version is the one described in the article for JASSS
;                                                   
; TURLLE COLORS
; Red = new learners; green = learners that succeeded with at least one course
; White = dropout (on black patches always hided) Yellow = learners with pheromone influenced target
; Grey = learners that sit on ANs after being send by pheromones Other colors on patches = learners studying
;
; Some code included are for future extensions and not visible in the user-interface


globals     [ANs diploma AN-objectives-range tel number competence-levels new-learners-total last-learners
             max-a max-b max-c diplomas-provided time-unit studytimefactor
             regular-diploma-list regular-search-AN search-repetitions mean-motivation k m W1 W2 W3 MfactorWeight SfactorWeight
             succeed-motivation-bonus fail-motivation-malus proportion-of-courses follow name
             tot-restarters
             pheromones first-doel competence-match error-factor dist std-motivation std-weekly-studytime max-attempts
             to-do-list consistency monthly-input-distribution month-dist month-count month fixed-number-d-ANs number-diploma-ANs
             replications 
             pheromone-type AN-selection-principle input-dist diploma-type n-learners]
patches-own [AN-type AN-objective AN-level AN-studytime AN-quality 
             AN-student-contribution AN-number-started AN-number-succeeded AN-avg-studytime]  
turtles-own [goal target to-do search-AN current motivation cl-A cl-B cl-C studytime 
             studytime-current-AN total-studytime total-planned-studytime 
             attempts-current-AN attempts Portfolio-ANs portfolio-competence 
             numb-pher-choices numb-restarted no-pher] ; cl is competence-level

to setup
  random-seed 14031957 ; use the seed when controlled experiments are needed
  ca
  ;---------------------VARIABLES TO SET DURING EXPERIMENTATION---------------------------------------------
  set name "LIZZ" 
  set fixed-number-d-ANs true ; BOOLEAN/(only for regular diploma) if true number-diploma-ANs will be selected/if false proportion-of-courses
  set number-diploma-ANs 52 ; number of diploma ANs that will be prepared when fixed-number-d-ANs = true
  set proportion-of-courses 1 ; defines the proportion of ANs that are diploma ANs when fixed-number... = false  
  set search-repetitions 50 ; number of steps needed for searching an AN, before time-unit proceeds. Must be higher when number of ANs is lower
  set max-attempts 5 ; max number of tentaminations per AN allowed before dropout
  set k 0.5 ; influence on avg-studytime for a mismatch on the core competence (the competence the AN is defined on). Default 0.5
  set m 0.1 ; influence on avg-studytime for a mismatch on other competences than the core competence. Default 0.1
  set std-weekly-studytime mean-weekly-study-time / 1 ; std studytime as distributed among students
  set mean-motivation 2 ; initial motivation of turtles. Can range from 1 .. 10. When motivation < 0 => dropout
  set std-motivation 0.5 ; (eg 0.5 or 1).
  set succeed-motivation-bonus 1.5  ; motivation points extra when succeed to pass tentamination for an AN
  set fail-motivation-malus 0.3  ; motivation points less when failed for an tentamination attempt. 
  set MfactorWeight 0.5 ; adjustable weight to define the influence of the error-factors on the motivation
  set SfactorWeight 1 ; adjustable weight to define the influence of the error-factors on the studytime  
  set W1 1 ; adjustable motivation & studytime weights: influence of disturbance on motivation & studytime  
  set W2 1   ; adjustable motivation & studytime weights: influence of competence (mis)match on motivation & studytime
  set W3 1 ; adjustable motivation & studytime weights: influence of quality on motivation & studytime
  set month ["January" "February" "March" "April" "May" "June" "July" "August" "September" "October" "November" "December"] ; used for display purposes
  set competence-levels 5 ; number of levels per competence A, B or C. Default 5 levels. ANs and learners indicate this level.
  set AN-objectives-range ["A" "B" "C"] ; don't change this without changing cl-A .. cl-C and other references.
  set follow false ; initial status for the follow-me button
;  -----future extension code-----------
  set pheromone-type "converge:random"
  set AN-selection-principle "intelligent"
  set input-dist false
  set diploma-type "no"
;  -------------------------------------
  set n-learners false
  set tel 1
  create-ANs  
  set month-count 0 ; month 0 is january and 11 is december
  new-learners
end

to go
 locals [error repetition]
  ifelse month-count >= 12 [set month-count 0] 
                           [set month-count ((time-unit + 1) mod 52) / 4.3333]
  if ((count turtles with [target = "attained objective" or color = white] = new-learners-total) or time-unit = weeks) and
                           input-dist = false                          
                          [user-message "simulation finished"]
   ask turtles with [motivation <= 0] [set target "dropout" set color white] ; this is the only dropout rule! More rules could be
   ask turtles with [color = white and pcolor = black] [set hidden? true]    ; related to number of tentamination attempts or time at AN
   ifelse dropout = true [ask turtles with [color = white and pcolor != black] [set hidden? false]] 
                         [ask turtles with [color = white and pcolor != black] [set hidden? true]]
   if follow-me = true and follow = false [ask random-one-of turtles with [color != white and hidden? = false] 
                                          [set follow true set label name + ">" inspect self]]
   if follow-me = false and follow = true [ask turtles with [label = name + ">"] [set label "" set follow false]]                         
   set repetition search-repetitions ; number of steps for learners to search ANs between time-units
   set time-unit time-unit + 1
   repeat repetition [                    ; this is the time for learners to search an adequate AN. It happens within 1 time-unit
       ifelse random 100 < matching-error [set error random-normal 5 2.5] [set error 0] ; set change for a matching error
              ; matching error doesn't occur in a regular diploma, but only when a learner matches competences during selection of ANs
       ask turtles with [hidden? = false and search-AN != "studying" and target != "dropout"] ; deleted: and pcolor = black
                        [ifelse search-AN = "searching" [set-search-AN] ; set search AN for all cases that are not yet set
                                 [if AN-selection-principle = "intelligent" [select-ANs-intelligent search-AN error]
                                  ]  ]]
   update-studytime-current-AN
   do-plots
   if learners-once = false 
         [new-learners] 
end

to select-ANs-intelligent [doel marge] ; this will select ANs intelligent given certain error, 
  ifelse no-pher = true [select-AN doel marge] ; ANs are inspected on suitability for the competence levels
    [ifelse (random 100) + 1 > pheromone-strength [set no-pher true select-AN doel marge]
        [determine-pheromones doel
         ifelse count pheromones > 0
           [select-AN-pheromone first-doel stop] ; when more than one target, select the first
           [select-AN doel marge] ; when no pheromone, select the normal ('intelligent') way.
    ]   ]     
end

to determine-pheromones [doel] ; determine whether there are pheromones available given current position AN and target AN
 locals [temp temp2 nextAN positie] ; different positioning experiments need a different routine here
  ; search learners with same goal in portfolio AN, but who have completed one AN more. 
  ; if present, report true, anders false
  ; set pheromone to learner agentset
 set first-doel sentence first doel item 1 doel ; this selects the first pair e.g. ["A" 1] when the search target contains more competences.
 ifelse length portfolio-competence > 0 ; distiguish between starters and learners with a position (min. one AN studied)
   [set positie last portfolio-ANs ; determine position of learner (ONLY last AN studied!!)
    without-interruption [ ; needed to prevent side-effects
    set pheromones turtles with [self != myself and 
                                       member? (last goal-of myself) goal and length portfolio-ANs > 1 and 
                                       member? first-doel but-first portfolio-competence and 
                                       member? positie portfolio-ANs and 
                                       position first-doel portfolio-competence = (position positie portfolio-ANs) + 1] ; turtles except from myself with a portfolio of at least 2 items
    ]]
    [without-interruption [ ; needed to prevent side-effects/ this sets the pheromones for new learners with unknown position
          set pheromones turtles with [self != myself and member? (last goal-of myself) goal and 
                                       length portfolio-competence > 0 and first portfolio-competence = first-doel] ; turtles except from myself with a portfolio of at least 2 items
    ]]   
end 

to select-AN-pheromone [doel] ; here you can find the policies for the different pheromone types.
   if pheromone-type = "converge:modes" [convergence-pheromone-policy "modes" doel] ; most frequent next AN
   if pheromone-type = "converge:random" [convergence-pheromone-policy "random" doel] ; random one of next ANs (higher frequency => more chance)
   if pheromone-type = "converge:<drpout" [convergence-pheromone-policy "best" doel] ; the next AN with least dropout
   if pheromone-type = "converge:<time" [convergence-pheromone-policy "lesstime" doel] ; the next AN with the least avg studytime spent by learners
end

to convergence-pheromone-policy [sel-type doel]
locals [translate plaats nextAN walk-to temp temp2 verh1 verh2 patchset ANtarget]
  without-interruption [ ; needed to prevent side-effects
      set nextAN []
      ask pheromones [ 
         set plaats position doel portfolio-competence ; determine position in portfolio competence
         set translate item plaats portfolio-ANs ; determine AN in portfolio AN
         set nextAN lput translate nextAN] ; make a list of all next AN
         set walk-to random-one-of nextAN ; random just one of the possible ANs in the list (not the most frequent!)
                       ]                          
     if not (member? walk-to portfolio-ANs) [walktarget walk-to] ; check whether AN is not already studied.
     stop   
end

to walktarget [ANaddress]
locals [arrived]
   set color yellow
   set numb-pher-choices numb-pher-choices + 1 ; number of time a turtle has made a selection based on pheromone
   set arrived 0
   while [arrived != "arrived"] 
      [set heading towardsxy-nowrap first ANaddress last ANaddress
       if demo = true [wait 0.05]
       ifelse pcolor-of patch-ahead 1 = black 
             [fd 1]
             [ifelse (pxcor-of patch-ahead 1 = first ANaddress and pycor-of patch-ahead 1 = last ANaddress)
                     [set arrived "arrived"
                      set-studying]
                     [set heading (random 360)
                      if pcolor-of patch-ahead 1 = black [fd 1]]
              ]]     
end

to set-search-AN ; for every run the search-AN is determined for the learners at a black patch (not studying)
   set-competence-search-AN
end

to stop-studying
  set target "attained objective"
  hideturtle
end

to set-competence-search-AN ; sets the next AN to search for turtles on black patches (not studying at the moment)
   ask turtles with [pcolor = black and first target = "A" and cl-A < last target]
      [set search-AN sentence "A" (cl-A + 1)]
   ask turtles with [pcolor = black and first target = "A" and cl-A >= last target]
      [stop-studying]  
   ask turtles with [pcolor = black and first target = "B" and cl-B < last target]
      [set search-AN sentence "B" (cl-B + 1)]
   ask turtles with [pcolor = black and first target = "B" and cl-B >= last target]
      [stop-studying]
   ask turtles with [pcolor = black and first target = "C" and cl-C < last target]
      [set search-AN sentence "C" (cl-C + 1)]
   ask turtles with [pcolor = black and first target = "C" and cl-C >= last target]
      [stop-studying]
end

to new-learners ; learners komen uit (0 -17 = screen-edge-y - (2 * screen-edge-y)) en de dichtsbijzijnde cursussen zijn degenen die in het curriculum de meeste kans op selectie maken 
                ; als er geen andere informatie beschikbaar is. Daardoor beginnen learners altijd onderaan en werken naar boven.
      locals [distribution-factor]          
      ifelse input-dist = true [set distribution-factor month-dist] [set distribution-factor 1]          
      ifelse n-learners = false [set number int (random-poisson (mean-new-learners * distribution-factor))] 
                                [set number int (mean-new-learners * distribution-factor)] ; fixed number or random number per time-unit
      set new-learners-total new-learners-total + number
      show item int month-count month + " week " + ((time-unit mod 52) + 1) + ", year " + int ((time-unit / 52) + 1) + ", new learners: " + number ; to view the number of new students per week + the month we are in
      ask random-n-of number (patches with [pcolor = black]) 
                        [sprout 1      [set color red
                                        set shape "person"  
                                        set heading random 360
                                        set portfolio-ANs []
                                        set search-AN []
                                        set target "new learner"
                                        set current "searching"
                                        set portfolio-competence []
                                        ]]
      set last-learners turtles with [target = "new learner"]
      ask last-learners [set goal []]
      ask last-learners [
        specify-target "new"  ; set competence levels and for non-diploma students set target
        set-studytime    ; set the number of study hours a student has available per time-unit (week)
        set-motivation   ; set the motivation
        set-search-AN]   ; set the AN search target                                   
end

to set-studytime
      ask last-learners [set studytime round random-gamma (mean-weekly-study-time ^ 2 / std-weekly-studytime ^ 2) 
                                                              (1 / (std-weekly-studytime ^ 2 / mean-weekly-study-time))]
      ; gamma distribution with alfa = (mean * mean / variance) lamda = 1 / (variance / mean) see netlogo manual
      ; gamma distributions are used to estimated task duration (see arena manual blz 591)                                       
end

to set-motivation
      ; research: 30% of the starters stops (non-starters)
       ask last-learners [set motivation random-gamma (mean-motivation ^ 2 / std-motivation ^ 2) 
                                                      (1 / (std-motivation ^ 2 / mean-motivation))]      
end

to specify-target [restart] ; target + competence levels, e.g. cl-A is competence-level for competence A
  ; depending on the proportion of diploma learners set in user-interface the target is set.
  ; diploma students have to study ALL the diploma ANs. A diploma is only setup when there are more than 70 ANs
  ; number of 
  if restart =  "new" ; new learners get their initial comp.levels; restarters keep their competence levels; 
    [ask last-learners [set target random-one-of AN-objectives-range] ; want to increase the competence level of A, B or C.
     ask last-learners [set cl-A round random-exponential 0.5]  ; set competence levels (change with another distribution when needed)
     ask last-learners [set cl-B round random-exponential 0.5]  ; when experimenting, change these values
     ask last-learners [set cl-C round random-exponential 0.5]] ; now: exponential (highest change of a low value)   
  ask last-learners with [target = "A"] 
     [set target sentence "A" (cl-A + 1 + (random (5 - cl-A)))] ; set target with level.
  ask last-learners with [target = "B"] 
     [set target sentence "B" (cl-B + 1 + (random (3 - cl-B)))] ; level A is always available until level 5  
  ask last-learners with [target = "C"] 
     [set target sentence "C" (cl-C + 1 + (random (3 - cl-C)))] ; B and C until 3          
  ifelse goal = [] [set goal (list target)] [set goal lput target goal] ; set goal, restarters have more than one goal.   
end

to create-ANs
  locals [AN-type-range] 
    crt 1 ; the patches created using a temporary turtle
    while [(count patches with [pcolor = green]) != units-of-learning] 
          [ask turtles 
             [lt (random 361) ; position head of turtle in random direction
              fd (random screen-size-x) ; position turtle a random number of steps
              ask patch-here [set pcolor green
                              set AN-studytime set-study-load-uol ; restriction every AN has the same study-time (studielast)
                              set AN-quality min-quality + random ((max-quality + 1) - min-quality) ; avarage quality of ANs is between lowest % (bad) and 100% (good)
                              set AN-objective (random-one-of AN-objectives-range)] ; set random learning objective for AN
              ask neighbors [set pcolor black
                             set AN-type "empty" ; to prevent two patches connected to eachother
                             set AN-objective "empty"] ; to prevent two patches connected to eachother
              set pcolor-of (patch 0 (screen-edge-y - (2 * screen-edge-y))) black ; prevent that the turtle source is black               
                  set tel tel + 1
             ]
           ]                  
     set ANs patches with [pcolor != black] ; define variable ANs with all the ANs      
     ask turtles [die] ; delete temporary turtle
     ask patches [if AN-objective = "A" [set pcolor red set AN-level (random competence-levels) + 1] ; give different ANs a different color
                  if AN-objective = "B" [set pcolor green set AN-level (random competence-levels) + 1]
                  if AN-objective = "C" [set pcolor blue set AN-level (random competence-levels) + 1]]
 end


to select-random-AN [doel marge] ; random doesn't look at any match with objectives, etc. It is completely stupid!
    ifelse pcolor-of patch-ahead 1 != black 
            [set-studying stop]
            [ifelse pcolor-of patch-right-and-ahead 90 1 != black  ; look at the right
              [rt 90 set-studying stop]
                  [ifelse pcolor-of patch-left-and-ahead 90 1 != black  ; look at the left
                  [lt 90 set-studying stop]
              [walk 1]]]
end

to select-AN [doel marge] ; the learners in-search selects an adequate AN
    ifelse pcolor-of patch-ahead 1 != black and ; NO DIPLOMA and if AN ahead
            an-objective-of patch-ahead 1 = first doel and ; and the AN has the needed objective
            (an-level-of patch-ahead 1 <= (last doel + marge) and ; and the AN has the needed level then study
             an-level-of patch-ahead 1 >= (last doel - marge)) and ; the mismatch is expressed here
             not (member? (list pxcor-of patch-ahead 1 pycor-of patch-ahead 1) portfolio-ANs) ; The AN is not already studied 
            [set-studying stop]
            [ifelse pcolor-of patch-right-and-ahead 90 1 != black and ; look at the right
                    an-objective-of patch-right-and-ahead 90 1 = first doel and 
                    an-level-of patch-right-and-ahead 90 1 = (last doel + marge) and
                    not (member? (list pxcor-of patch-right-and-ahead 90 1 pycor-of patch-right-and-ahead 90 1) portfolio-ANs) ; The AN is not already studied                      
              [rt 90
               set-studying stop]
              [ifelse pcolor-of patch-left-and-ahead 90 1 != black and ; look at the left
                    an-objective-of patch-left-and-ahead 90 1 = first doel and 
                    an-level-of patch-left-and-ahead 90 1 = (last doel + marge) and
                    not (member? (list pxcor-of patch-left-and-ahead 90 1 pycor-of patch-left-and-ahead 90 1) portfolio-ANs) ; The AN is not already studied  
              [lt 90
               set-studying stop]
              [walk 1]
    ]]  
end

to set-studying
    ifelse motivation > 0
       [fd 1
        ifelse color = yellow [set color grey] [set color pcolor + 30]
        set search-AN "studying"
        set AN-number-started AN-number-started + 1
        set current (list pxcor pycor an-objective an-level)]
       [walk 1] 
end

to walk [step] 
  repeat step [
    if random 20 = 0 [set heading (random 360)] ; change direction sometimes to avoid endless repeated search path
    ifelse pcolor-of patch-ahead 1 = black
      [fd 1]
      [set heading (random 360)]
      if demo = true [wait 0.1]]
end

to update-studytime-current-AN
  ask turtles with [color != white and search-AN = "studying" and studytime-current-AN >= AN-studytime] 
      [without-interruption [tentamination-attempt]]
  ask turtles with [color != white and search-AN = "studying" and studytime-current-AN < AN-studytime]  
      [without-interruption [calculate-studytime-motivation]] ; netto study progression in hours per time unit
end

to calculate-studytime-motivation
locals [time-learner-spends]
    ; purpose: calculate the number of actual study hours a student studies per time unit based on:
    ; disturbance-factor, average match to competence level (A+B+C), AN-quality and studytime
    ; whith a better match a student delivers more time (in fact can spent less time with more effect!)
  determine-dropout-factors
  set time-learner-spends studytime * error-factor * SfactorWeight ; corrects effectively spend studytime depending on errorfactor 
  set studytime-current-AN studytime-current-AN + time-learner-spends
  set total-studytime total-studytime + time-learner-spends
  set total-planned-studytime total-planned-studytime + studytime
  set motivation motivation + ((error-factor - 1) * mean-motivation * MfactorWeight); ALTERNATIVE SIMPLE FORMULA
end

to determine-dropout-factors ; set disturbance, competence-match and error-factor (based on dist, competence and AN-quality)
  ifelse random 100 < disturbance-chance [set dist ((random 100) / 100)] [set dist 1]
    ; if disturbance occurs (with % chance = disturbance factor) then the level of disturbance is a factor between 0 and 1 (0 = high disturbance)
  set-competence-match
  set error-factor (((dist * W1) + ((1 / competence-match) * W2) + ((AN-quality / 100) * W3)) / (W1 + W2 + W3)) 
end

to set-competence-match
  ; when a person has a higher avg level of competence than needed for the course, he studies faster and vise versa
  if AN-objective = "A" [set competence-match (AN-level / (cl-A + 1)) ^ k * (AN-level / ((0.5 * (cl-B + cl-C)) + 1)) ^ m] ; see <information> tab for explanation
  if AN-objective = "B" [set competence-match (AN-level / (cl-B + 1)) ^ k * (AN-level / ((0.5 * (cl-A + cl-C)) + 1)) ^ m]
  if AN-objective = "C" [set competence-match (AN-level / (cl-C + 1)) ^ k * (AN-level / ((0.5 * (cl-A + cl-B)) + 1)) ^ m]
end  

to tentamination-attempt
  ifelse attempts-current-AN >= max-attempts [set motivation -10] ; this will force dropout
   [determine-dropout-factors
    set attempts attempts + 1
    ifelse random 101 < (error-factor * 100) 
         [set attempts-current-AN 0
          succeed]
         [set attempts-current-AN attempts-current-AN + 1
          set motivation motivation - fail-motivation-malus ; minus motivation must be between 0 and 1
          set studytime-current-AN round studytime-current-AN - (0.2 * studytime-current-AN) ; need 20% extra studytime every new tentamination attempt  
         ]]; fail
end

to succeed 
     ifelse motivation > 0 
           [set motivation motivation + succeed-motivation-bonus ; extra motivation 
            set AN-avg-studytime ((an-number-succeeded * AN-avg-studytime) + studytime-current-AN) / (an-number-succeeded + 1) ; calculate avg studytime learners needed
            set studytime-current-AN 0
            set no-pher false ; learner can be influenced again by pheromones
            set AN-number-succeeded AN-number-succeeded + 1
            set portfolio-ANs lput (list pxcor pycor) portfolio-ANs ; build the list of ANs that are completed [[1 10] [1 3]] etc.
            set portfolio-competence lput (list AN-objective AN-level) portfolio-competence ; build the list of completed ANs by levels [[C 1][A 3]] etc.            
            ifelse AN-objective = "A"
              [if AN-level > cl-a [set cl-a AN-level]] ; competence level is set to the AN level when AN-level is higher
               [ifelse AN-objective = "B"
                 [if AN-level > cl-b [set cl-b AN-level]]
                 [if AN-objective = "C"
                    [if AN-level > cl-c [set cl-c AN-level]]]]
                   set current "searching"
                   set search-AN "searching"
                   set-search-AN
                   set color green ; green are turtles that have studied at least one AN
                   walk 3]        
           [set color white]
end


to do-plots
  if mean-new-learners > 0 and count turtles with [color != white] > 1 and sum values-from turtles [total-planned-studytime] > 0 
  [ ; otherwise devide by 0 possible
    set-current-plot "dropout & attained"   
          set-current-plot-pen "Dropout"
          plot count turtles with [color = white] / new-learners-total
          set-current-plot-pen "Attained"
          plot count turtles with [target = "attained objective"] / new-learners-total
    ]
end

@#$#@#$#@
GRAPHICS-WINDOW
216
10
650
468
23
23
9.0213
1
10
1
1
1

CC-WINDOW
216
466
649
615
Command Center

BUTTON
133
10
217
43
NIL
setup
NIL
1
T
OBSERVER
T

SLIDER
649
10
864
43
units-of-learning
units-of-learning
0
180
100
1
1
NIL

SLIDER
648
73
863
106
mean-new-learners
mean-new-learners
0
1000
6
1
1
NIL

BUTTON
133
43
217
76
NIL
go
T
1
T
OBSERVER
T

MONITOR
133
123
215
172
new learners
new-learners-total
3
1

MONITOR
132
172
215
221
searching
count (turtles with [pcolor = black and hidden? = false and color != white])  + " (" + round ((count (turtles with [pcolor = black and hidden? = false and color != white]) / new-learners-total) * 100) + "%)"
3
1

SLIDER
651
138
862
171
matching-error
matching-error
0
100
0
1
1
NIL

SLIDER
649
201
861
234
mean-weekly-study-time
mean-weekly-study-time
0
40
6
1
1
NIL

SLIDER
649
233
861
266
set-study-load-uol
set-study-load-uol
0
200
25
1
1
NIL

SLIDER
649
105
863
138
disturbance-chance
disturbance-chance
0
100
0
1
1
NIL

SWITCH
964
110
1087
143
dropout
dropout
1
1
-1000

SLIDER
649
170
752
203
min-quality
min-quality
0
100
100
1
1
NIL

SLIDER
751
170
861
203
max-quality
max-quality
0
100
100
1
1
NIL

SWITCH
964
77
1093
110
learners-once
learners-once
1
1
-1000

SLIDER
648
264
861
297
pheromone-strength
pheromone-strength
0
100
0
1
1
NIL

SWITCH
964
44
1087
77
follow-me
follow-me
1
1
-1000

SLIDER
648
42
863
75
weeks
weeks
0
1040
1040
26
1
NIL

MONITOR
133
76
216
125
weeks
time-unit
3
1

SWITCH
963
11
1053
44
demo
demo
1
1
-1000

PLOT
649
297
861
467
dropout & attained
time
dropout
0.0
100.0
0.0
1.0
true
false
PENS
"Dropout" 1.0 0 -65536 true
"Attained" 1.0 0 -16776961 true

MONITOR
826
297
921
346
Attained (blue)
count turtles with [target = "attained objective"] + " (" + round ((count turtles with [target = "attained objective"] / new-learners-total) * 100) + "%)"
3
1

MONITOR
826
345
920
394
Dropout (red)
count turtles with [color = white] + " (" + round ((count turtles with [color = white] / new-learners-total) * 100) + "%)"
3
1

@#$#@#$#@
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@