breed [ microglia a-microglia ]
breed [ hNeurons hNeuron ]       ; hNeuron = healthy neuron
breed [ dNeurons dNeuron ]       ; dNeuron = damaged neuron
undirected-link-breed [ synapses synapse ]

microglia-own [
  wait-ticks     ; number of ticks a microglia will wait during surveillance/phagocytosis
]

patches-own [
  ; inflam-val is the actual inflammation value a current patch has, and is used for
  ; the direction microglia move towards. inflam-change is a separate variable used
  ; to calculate the diffusal and dismantling of inflammation for patches other than
  ; the current one.
  inflam-val
  inflam-change
  curr-spread  ; current radius that inflammation is spreading.
  residence?   ; is there a dNeuron on patch?
  dismantling? ; is the patch dismantling (a dNeuron just got eaten)?
]

; =========================
; setup and go procedures
; =========================

to setup
  clear-all
  set-default-shape dNeurons "circle"
  set-default-shape hNeurons "circle"
  ; microglia are the default arrow shape

  create-microglia init-microglia [
    set color green
    set size 2
    set wait-ticks 0
    setxy random-xcor random-ycor
    while [any? other turtles-here]      ; all turtles spawn in a random location, and will
      [ setxy random-xcor random-ycor ]  ; re-randomize if the patch already contains a turtle
  ]

  create-hNeurons init-hNeuron [
    set color pink
    set size 1.5
    setxy random-xcor random-ycor
    while [any? other turtles-here]
      [ setxy random-xcor random-ycor ]
  ]

  create-dNeurons init-dNeuron
  [
    set color red
    set size 1.5
    setxy random-xcor random-ycor
    while [any? other turtles-here]
      [ setxy random-xcor random-ycor ]
  ]

  ask patches [
    set residence? false    ; boolean value for if inflammation is present
    set dismantling? false  ; boolean value for if inflammation is in the process of dismantling
  ]

  ask dNeurons [
    ask patch-here [
      set inflam-val 1     ; initial inflammation value for patches with damaged neurons
      set curr-spread 1    ; current radius of the inflammation spread
      set residence? true
    ]
  ]

  ; Creating synapses between nearby neurons of either type. If there's multiple
  ; neurons in the synapse radius, the neuron will create only one synapse with
  ; one other neuron.
  ask (turtle-set dNeurons hNeurons) [
    ; create agentset of nearby neurons for the current neuron
    let nearby-neurons other (turtle-set dNeurons hNeurons) in-radius neuron-distance
    if any? nearby-neurons [ create-synapse-with one-of nearby-neurons ]
  ]

  reset-ticks
end

to go
  if not any? dNeurons [ stop ]

  ask microglia [
    ; If wait-ticks is 0, take some action. Else, "wait" one tick and reduce wait-ticks by 1
    ifelse wait-ticks = 0
      [ set color green                                 ; microglia currently moving are green
        move
        if any? dNeurons-on patch-here [ eat-attempt ]  ; tries to eat if damaged neuron is on current patch
        if any? hNeurons-on patch-here [ survey ] ]     ; surveys if healthy neuron is on current patch
      [ set color yellow                                ; microglia currently waiting are yellow
        set wait-ticks wait-ticks - 1 ]
  ]

  ; If ticks is a multiple of 5, do following actions
  if (ticks mod 5 = 0)
  [
    ask dNeurons
    [
      ask patch-here
      [
        ; if curr-spread of inflammation is less than the set inflam-radius, diffuse inflammation
        if curr-spread < inflam-radius [ diffuse-inflam ]
      ]
    ]
    ask patches with [ dismantling? and (curr-spread <= inflam-radius) ] [ dismantle-inflam ]  ; dismantles inflammation over time
  ]

  ask hNeurons with [damage-link] [
    get-damaged
  ]

  tick
end

; ======================
; turtle procedures
; ======================

; microglia procedure
to move
  rt random 50
  lt random 50
  ; only goes uphill with a % chance determined by sensing-efficiency. If all neighboring patches have the same
  ; inflammation, move normally instead
  ifelse (random 100 < sensing-efficiency) and (max [inflam-val] of neighbors) != (min [inflam-val] of neighbors)
    [ uphill inflam-val ]
    [ fd 1 + 0.05 * (temperature - 37) ]
    ; if not moving towards inflammation, 5% increased speed per degree temp > 37C (and vice versa)
end

; microglia procedure: stops movement to attempt phagocytosis on damaged neuron on current patch
to eat-attempt
  set color yellow
  set wait-ticks 5  ; microglia waits 5 ticks after an eat attempt, regardless of success
  let prey one-of dNeurons-here
  if random 100 < eat-probability [
    ask prey [ die ]
    ask patch-here [
      set residence? false    ; since patch no longer has a damaged neuron on it
      set dismantling? true   ; patch starts dismantling the inflammation it spread
    ]
  ]
end

; microglia procedure: stops movement to survey healthy neuron on current patch
to survey
  set wait-ticks 2
end

; hNeuron procedure: causes a healthy neuron to become damaged if it there is a
; synapse between it and a damaged neuron, with some fixed percent chance.
to get-damaged
  if precision (random-float 100) 2 < (damage-chance) [
    set breed dNeurons ; changes breed from healthy to damaged
    set color red
    ask patch-here [   ; update patch neuron is on to a resident with inflammation
      diffuse-inflam
      ask patches in-radius inflam-radius [ update-colors ]
    ]
  ]
end

; ==================
; patch procedures
; ==================

; diffuses inflammation over time until the max radius (inflam-radius)
; has been reached.
to diffuse-inflam
  ask patches in-radius curr-spread [
    set inflam-val inflam-val + 1  ; gives inflammation to patches within the current spreading radius
    update-colors
  ]
  set curr-spread curr-spread + 1  ; increases curr-spread to inflame farther on next diffusion cycle
end

; dismantles inflammation over time until all inflammation
; diffused from the eaten dNeuron is dismantled
to dismantle-inflam
  set curr-spread curr-spread - 1
  ask patches in-radius curr-spread [
    set inflam-val inflam-val - 1 ; remove inflammation
    update-colors
  ]
  if (curr-spread = 0) [  ; curr-spread will be zero when the area is at the origin of inflammation
    set dismantling? false
  ]
  update-colors
end

; updates patch colors after inflammation value changes, with a gradient
; illustrating different inflammation levels.
to update-colors
    set pcolor scale-color violet inflam-val 0 20
end


; =======================
; reporters and utility
; =======================

; checks if a link to a damaged neuron exists
to-report damage-link
  report any? link-neighbors with [breed = dNeurons]
end

; button that infects a random hNeuron in the current world
to infect
  let victim one-of hNeurons ; choose a random healthy neuron
  if victim != nobody [      ; only infect if there exists at least one healthy neuron
    ask victim [
      set breed dNeurons
      set color red
      ask patch-here [
        set inflam-val 1
      ]
    ]
  ]
end
@#$#@#$#@
GRAPHICS-WINDOW
210
10
647
448
-1
-1
13.0
1
10
1
1
1
0
1
1
1
-16
16
-16
16
0
0
1
ticks
30.0

BUTTON
9
15
72
48
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
75
15
138
48
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
10
55
186
88
init-microglia
init-microglia
0
50
3.0
1
1
NIL
HORIZONTAL

SLIDER
10
92
186
125
init-hNeuron
init-hNeuron
0
50
10.0
1
1
NIL
HORIZONTAL

SLIDER
11
129
187
162
init-dNeuron
init-dNeuron
0
50
10.0
1
1
NIL
HORIZONTAL

PLOT
4
394
204
545
populations
time
agent amounts
0.0
100.0
0.0
10.0
true
false
"" ""
PENS
"microglia" 1.0 0 -13840069 true "" "plot count microglia"
"h-neurons" 1.0 0 -1264960 true "" "plot count hNeurons"
"d-neurons" 1.0 0 -5298144 true "" "plot count dNeurons"

BUTTON
141
15
204
48
NIL
infect
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
11
166
187
199
temperature
temperature
33
40
37.0
1
1
C
HORIZONTAL

SLIDER
11
203
187
236
inflam-radius
inflam-radius
0
33
5.0
1
1
patches
HORIZONTAL

SLIDER
11
240
188
273
eat-probability
eat-probability
0
100
70.0
1
1
%
HORIZONTAL

SLIDER
11
277
188
310
sensing-efficiency
sensing-efficiency
0
100
50.0
1
1
%
HORIZONTAL

SLIDER
11
314
188
347
neuron-distance
neuron-distance
0
20
5.0
1
1
patches
HORIZONTAL

SLIDER
11
352
189
385
damage-chance
damage-chance
0
100
0.5
.01
1
%
HORIZONTAL

@#$#@#$#@
## WHAT IS IT?

This is an agent-based model simulating a 2-dimensional slice of the hippocampus, intending to analyze the relationship between microglia (resident immune cells) and the factors that contribute to the progression of Alzheimer’s Disease, as guided by available research. 

This version of the model includes three agent breeds, representing mobile microglial cells and stationary neuronal cells, either healthy or damaged. The microglia are initialized with a generalized goal of phagocytosing (clearing out) all damaged neurons in any given iteration of the simulation. They accomplish this task through pseudo-random movement in the patch space until they encounter a chemokine (a kind of signaling protein) being secreted from a damaged neuron, which signals the microglia to follow the source of the chemokine until reaching the damaged neuron, and phagocytosing it with some variable probability. 

This model utilizes solely agent-dependent patch characteristics. In this version of the model, only a damaged neuron has the ability to affect the patches that surround it in the model world. Patches do not spawn with any patch characteristics innately, unless there are damaged neurons present which, by design, will follow a procedure that provides nearby patches with user-created patch characteristics. The specifics of this process will be elaborated on in greater detail later on.

This model sheds light on the impacts of microglial activity as they relate to damaged neurons. Rather than highlighting and examining damaged neurons' role in the proliferation and progression of Alzheimer’s Disease, which is well researched, this model seeks to explore which spatial and temporal microglial factors can influence creation of response to damaged neurons. 

## HOW IT WORKS

The model is intended to have many variables that can be chosen by the user. Initialization involves setting the number of microglia agents, healthy (pink) neuron agents and damaged (red) neuron agents. The user also has the option to adjust the temperature, inflammation radius, the probability of successful phagocytosis, the efficiency of the microglia sensing, the distance of the neuron links, and the chance of a neuron becoming damaged. The turtles representing neurons are stationary. They can be healthy or damaged. In the damaged state they secrete inflammation. In both states, neuron turtles can connect to one another via links. These links communicate the current state of the neurons with those they connected to, infecting with a chosen probability. The microglia turtles move randomly about the world. Their task is to seek out damaged neurons and clear them from the world. The simulation ends once the microglia have cleared all the damaged neurons.

### Inflammation

The turtles representing damaged neurons secrete inflammation, a patch characteristic dependent on a user-created procedure that mimics the diffusal of chemicals secreted by cells in the body (specifically IFN-&gamma;, a cytokine that signals microglia to activate). Inflammation signals nearby microglia turtles to attempt phagocytosis. The radius of this inflammation can be adjusted by the user with the INFLAM-RADIUS slider. The inflammation spreads from the damaged neurons until it reaches the chosen radius.

### Phagocytosis

The microglia turtles’ main function is to seek the world for damaged neurons and phagocytose them. Phagocytosis is the process of ridding the hippocampus of the damaged neurons. The probability of successful phagocytosis can be modified by the user with the EAT-PROBABILITY slider.  

### Sensing

The microglia turtles have a sensing radius that allows them to sense the damaged neurons that they are hunting for. The effectiveness of these turtles accurately sensing a damaged neuron can be altered by the user using the SENSING-EFFICIENCY slider.

### Neurons

The number of healthy and damaged neuron turtles in each run is determined by the user using the INIT-HNEURON and INIT-DNEURON sliders, respectively.  If the neuron is damaged, they diffuse inflammation (described above). The neurons are stationary, and their main purpose is to be consumed by the microglia. The neurons can connect to one another via links.

### Links

The turtles representing neurons (both healthy and damaged) can connect to one another via links. These links communicate the status of the neuron turtles to one another. If there is a damaged neuron connected to a healthy neuron, the damaged neuron can “infect” the healthy neuron by a set probability. The chance that this happens is once per healthy neuron per tick.

## HOW TO USE IT

In the interface tab, the user is presented with a variety of sliders to adjust the simulation. Here is a brief description of each of these sliders.


* INIT-MICROGLIA: sets the number of microglia turtles that the simulation starts with. 

* INIT-HNEURON and INIT-DNEURON: sets the number of healthy and damaged neurons, respectively. 

* TEMPERATURE: adjusts the temperature of the microglia turtles, which affects their speed of movement.

* INFLAM-RADIUS: changes the radius of the inflammation secreted by the damaged neurons.

* EAT-PROBABILITY: adjusts the probability that a microglia turtle will successfully perform phagocytosis. 

* SENSING-EFFICIENCY: changes the probability of a microglia turtle to successfully sense the inflammation secreted by the damaged neuron turtles. 

* NEURON-DISTANCE: affects the radius that a neuron turtle can connect to another neuron turtle through synapses (links).

* DAMAGE-CHANCE: adjusts probability that a healthy neuron with a link to a damaged neuron will become damaged.

The SETUP button resets the graphics and plots and places the turtles in random locations. The INFECT button causes a random healthy neuron turtle to become a damaged neuron turtle. This button can be used throughout the simulation. The GO button starts the simulation and the plotting function. 

As the simulation runs the microglia turtles survey the world and clear it of any damaged neurons present. Once the microglia clear all the damaged neurons, the simulation ends. 

The plot shows the population of each turtle with respect to time. The green line represents microglia turtles, and the red and pink lines represent the damaged and healthy neurons, respectively. 

## THINGS TO NOTICE

When the simulation starts, notice:

* Healthy neurons that are linked to damaged ones might become damaged.

* Inflammation spreads from the damaged neurons.

* Microglia move toward damaged neurons if they encounter a patch with inflammation.

* Microglia change from green to yellow when surveying or attempting to eat.

## THINGS TO TRY

The user can run a number of experiments with many different variables to adjust.

The model includes an INFECT button. Try running a simulation and infect healthy neurons as the simulation runs. Observe how long it takes for the microglia turtles to clear the world of the damaged neuron turtles. How could this relate to real world diseases? If the infection is rampant, the microglia struggle to clear the damage. Try the same parameter values, but reduce the number of microglia. How does a lower number of microglia affect the recovery of a disease?

The model includes the slider INFLAM-RADIUS. Try adjusting the radius of the inflammation. If the radius is large, does this affect the efficiency of the microglia in clearing the damaged neurons? Or, is the efficiency of microglia clearing the damaged neurons entirely dependent on the SENSING-EFFICIENCY slider? Is there a threshold of when SENSING-EFFICIENCY is so high that microglia become overwhelmed by the inflammatory signals and stop properly functioning, or so low that they fail to have an appropriate response altogether?

Try experimenting with different values on each slider. For example, to have a good chance at seeing every facet of the model working together, try the starting values:

INIT-MICROGLIA: 3

INIT-HNEURON: 10

INIT-DNEURON: 10

TEMPERATURE: 37 C

INFLAM-RADIUS: 5 patches

EAT-PROBABILITY: 70%

SENSING-EFFICIENCY: 50%

NEURON-DISTANCE: 5 patches

DAMAGE-CHANCE: 0.50%

## EXTENDING THE MODEL

Like all computer simulations of biological systems, this model has simplified many aspects of the Central Nervous System. The model, therefore, provides numerous opportunities for expansion: 

* Of chief priority in future models is to establish an effective phenotype breed switch for the microglia turtles. Microglia continually sense and respond to their environment, and in responding to certain signals, enter activated states described as the expression of a specific phenotype. These activated phenotype switching states would be an ideal biological phenomena to model and explore in later models. 

* The model uses inflammation to depict neurons secreting cytokines, particularly Interferon-gamma (IFN-&gamma;). A future model could implement other factors related to the progression of Alzheimer’s Disease, such as A&beta; plaques. 

* This model makes the simplifying assumption that IFN-&gamma; is the only cytokine present in the hippocampal slice being simulated. In reality, there are many other cytokines in a human hippocampus, and future models could explore implementation of many different cytokines all interacting at once

* Microglia also emit their own cytokines that allow them to communicate with each other; future models could add a feature where microglia secret their own cytokines similar to the inflammation secreted by the damaged neurons.

## CREDITS AND REFERENCES

This project was supported by NSF grant 2245839 from the Mathematical Biology program. We are deeply grateful for this support.

We would also like to thank the users on Stack Overflow who replied to [this](https://stackoverflow.com/questions/77467956/how-to-create-a-diffuse-function-without-the-diffuse-primitive) thread.

## HOW TO CITE

If you mention this model or the NetLogo software in a publication, we ask that you include the citations below.

For the model itself:

Case, A., Mezzulo, E., Penland, A., Ty, C., & Larripa, K. (2024). NetLogo Microglia Model. Cal Poly Humboldt, Arcata, CA.

Please cite the NetLogo software as:

Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
15
Circle -1 true true 203 65 88
Circle -1 true true 70 65 162
Circle -1 true true 150 105 120
Polygon -7500403 true false 218 120 240 165 255 165 278 120
Circle -7500403 true false 214 72 67
Rectangle -1 true true 164 223 179 298
Polygon -1 true true 45 285 30 285 30 240 15 195 45 210
Circle -1 true true 3 83 150
Rectangle -1 true true 65 221 80 296
Polygon -1 true true 195 285 210 285 210 240 240 210 195 210
Polygon -7500403 true false 276 85 285 105 302 99 294 83
Polygon -7500403 true false 219 85 210 105 193 99 201 83

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

wolf
false
0
Polygon -16777216 true false 253 133 245 131 245 133
Polygon -7500403 true true 2 194 13 197 30 191 38 193 38 205 20 226 20 257 27 265 38 266 40 260 31 253 31 230 60 206 68 198 75 209 66 228 65 243 82 261 84 268 100 267 103 261 77 239 79 231 100 207 98 196 119 201 143 202 160 195 166 210 172 213 173 238 167 251 160 248 154 265 169 264 178 247 186 240 198 260 200 271 217 271 219 262 207 258 195 230 192 198 210 184 227 164 242 144 259 145 284 151 277 141 293 140 299 134 297 127 273 119 270 105
Polygon -7500403 true true -1 195 14 180 36 166 40 153 53 140 82 131 134 133 159 126 188 115 227 108 236 102 238 98 268 86 269 92 281 87 269 103 269 113

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270
@#$#@#$#@
NetLogo 6.4.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180
@#$#@#$#@
0
@#$#@#$#@