; Marcus D. Gabriel
; Copyright(c) 2010
; marcus@gabriel.name
;
; See "Thinking in Systems, A primer" by Donella H. Meadows,
; ISBN 978-1-84407-726-7, chapter 2.
;
; This model captures the essential design and behaviour of a
; Viessmann gas furnance being used in the Bas-Rhin of Alsace in
; France during winter.

; All of these globals are constants set by set-globals.
globals [
  initial-room-temperature

  minimum-outside-temperature
  outside-temperature-increment
  maximum-outside-temperature
  initial-outside-temperature
  ; Logically maximum-outside-temperature > sized-for-mininum-outside-temperature.
  ; Also sized-for-mininum-outside-temperature > minimum-outside-temperature,
  ; that is, the furnance can be overwhelmed.
  sized-for-mininum-outside-temperature

  minimum-thermostat-setting
  thermostat-setting-increment
  maximum-thermostat-setting
  initial-thermostat-setting

  ; The room-furnance-size is a unitless quantity in this model.  It
  ; is proportional to the size of the room and inversely propotional
  ; to the strength of the furnace, that is, increasing the
  ; room-furnance-size means the room is larger relative to the size
  ; (strength) of the furnance and decreasing it means the room is
  ; smaller relative to the size (strength) of the furnance.  The name
  ; was chosen to emphasize the size of the room over the size
  ; (strength) of the furnance.  One can think of the
  ; room-furnance-size as the heat capacity of the room.
  minimum-room-furnance-size
  room-furnance-size-increment
  maximum-room-furnance-size
  initial-room-furnance-size

  minimum-room-leakage-factor
  room-leakage-factor-increment
  maximum-room-leakage-factor
  initial-room-leakage-factor
  ; The furnance should be sized for a leaky room and not for a very
  ; leaky room nor for a good room, for example, 30% is for a leaky
  ; room, 10% is for a good room, and 50% is for a very leaky room.
  sized-for-room-leakage-factor
]

; Temperatures are in centigrade and have been choosen for a typical
; winter day in the Bas-Rhin of Alsace in France.
to set-globals
  ; Save the values of all of the sliders
  let saved-outside-temperature outside-temperature-slider
  let saved-thermostat-setting thermostat-setting-slider
  let saved-leakage-factor-slider room-leakage-factor-slider
  let saved-room-furnance-size room-furnance-size-slider
  
  set initial-room-temperature 5

  set minimum-outside-temperature (- 25)
  set outside-temperature-increment 1
  set maximum-outside-temperature 45
  set sized-for-mininum-outside-temperature (-10)
  set initial-outside-temperature 0
  
  set minimum-thermostat-setting 5
  set thermostat-setting-increment 1
  set maximum-thermostat-setting 25
  set initial-thermostat-setting 21

  set minimum-room-furnance-size 100
  set room-furnance-size-increment 50
  set maximum-room-furnance-size 1000
  set initial-room-furnance-size 550
  
  ; The room-leakage-factor-slider uses %, the rest are fractions.
  set minimum-room-leakage-factor 5 / 100
  set room-leakage-factor-increment 2.5 / 100
  set maximum-room-leakage-factor 95 / 100
  set sized-for-room-leakage-factor 30 / 100
  set initial-room-leakage-factor 30 / 100
  
  ; Restore the values of all of the sliders
  set outside-temperature-slider saved-outside-temperature
  set thermostat-setting-slider saved-thermostat-setting
  set room-leakage-factor-slider saved-leakage-factor-slider
  set room-furnance-size-slider saved-room-furnance-size
end

to reset-sliders
  set outside-temperature-slider initial-outside-temperature
  set thermostat-setting-slider initial-thermostat-setting
  ; Convert to %, for example, 30%.
  set room-leakage-factor-slider sized-for-room-leakage-factor * 100
  set room-furnance-size-slider initial-room-furnance-size
end

to setup
  clear-all
  set-globals
  system-dynamics-setup
  do-plots
end

to initialise
  setup
  reset-sliders
end

to go
  system-dynamics-go
  do-plots
end

to do-plots
  set-current-plot "Inside Temperature"
  set-current-plot-pen "room-temperature"
  plotxy ticks room-temperature
  set-current-plot-pen "thermostat-setting"
  plotxy ticks thermostat-setting
  set-current-plot-pen "outside-temperature"
  plotxy ticks outside-temperature
  
  set-current-plot "Rate of heat consumption"
  set-current-plot-pen "rate-of-consumption"
  plotxy ticks rate-of-heat-consumption
end

to-report minimum-value [a b]
  ifelse a < b
    [report a]
    [report b]
end

to-report maximum-value [a b]
  ifelse a < b
    [report b]
    [report a]
end

to-report safe-room-furnance-size
  report maximum-value room-furnance-size minimum-room-furnance-size
end

to-report maximum-delta-temperature-to-room
  ; The furnance/thermostat/room system has been sized to handle at
  ; most a given maximum temperature difference between the inside
  ; room temperature and the outside temperature, for a given efficiency
  ; of insolation of the room, and for a given size of the room relative
  ; to the size (strength) of the furnance.
  report ((maximum-thermostat-setting - sized-for-mininum-outside-temperature) / safe-room-furnance-size) * sized-for-room-leakage-factor
end

to-report delta-temperature
  ; The furnace/thermostat system monitors the discrepancy between
  ; theromostat setting and room temperatures and adds heat accordingly.
  report (thermostat-setting - room-temperature) / safe-room-furnance-size
end

to-report delta-temperature-to-room
  ; The furnace/thermostat system monitors heat loss so as to add heat to
  ; delta-temperature to compensate for heat lost to the outside.
  let actual-delta minimum-value maximum-delta-temperature-to-room (delta-temperature + (- delta-temperature-from-room))
  ifelse (room-temperature > outside-temperature) and (thermostat-setting > room-temperature)
    [report actual-delta]
    [report 0]
end

to-report delta-temperature-from-room
  ; The room-leakage-factor inversely models the insolation of the
  ; room, the R factor.  The lower the room-leakage-factor, the
  ; smaller the loss of heat to the outside for any given dt.  The
  ; greater the room-leakage-factor, the greater the loss of heat
  ; to the outside for any given dt.
  report ((outside-temperature - room-temperature) / safe-room-furnance-size) * room-leakage-factor
end

to-report rate-of-heat-consumption
  ; A unitless scale is used from 0 to 100.
  report delta-temperature-to-room * 100 / maximum-delta-temperature-to-room
end

; Alias for plotting, an alignment trick because
;   outside-temperature
;   rate-of-consumption
; align.
to-report rate-of-consumption
  report rate-of-heat-consumption
end
@#$#@#$#@
GRAPHICS-WINDOW
359
11
549
222
0
0
180.0
1
0
1
1
1
0
1
1
1
0
0
0
0
1
1
1
ticks

SLIDER
8
277
233
310
thermostat-setting-slider
thermostat-setting-slider
minimum-thermostat-setting
maximum-thermostat-setting
21
thermostat-setting-increment
1
NIL
HORIZONTAL

SLIDER
8
239
233
272
outside-temperature-slider
outside-temperature-slider
minimum-outside-temperature
maximum-outside-temperature
0
outside-temperature-increment
1
NIL
HORIZONTAL

SLIDER
8
317
234
350
room-leakage-factor-slider
room-leakage-factor-slider
minimum-room-leakage-factor * 100
maximum-room-leakage-factor * 100
52.5
room-leakage-factor-increment * 100
1
%
HORIZONTAL

SLIDER
8
356
234
389
room-furnance-size-slider
room-furnance-size-slider
minimum-room-furnance-size
maximum-room-furnance-size
550
room-furnance-size-increment
1
NIL
HORIZONTAL

PLOT
237
11
656
256
Inside Temperature
Time
Room Temp.
0.0
10.0
-25.0
45.0
true
true
PENS
"thermostat-setting" 1.0 0 -2674135 true
"room-temperature" 1.0 0 -16777216 true
"outside-temperature" 1.0 0 -13345367 true

BUTTON
9
69
107
103
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
113
69
232
103
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

MONITOR
9
150
233
191
Inside Temperature
room-temperature
1
1
10

MONITOR
663
154
863
195
delta-temperature-to-room
delta-temperature-to-room
5
1
10

MONITOR
662
105
862
146
delta-temperature-from-room
delta-temperature-from-room
5
1
10

BUTTON
9
109
233
142
NIL
reset-sliders
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

MONITOR
661
12
862
53
NIL
maximum-delta-temperature-to-room
5
1
10

PLOT
237
260
656
436
Rate of heat consumption
Time
Consumption
0.0
10.0
0.0
110.0
true
true
PENS
"rate-of-consumption" 1.0 0 -10899396 true

TEXTBOX
285
280
491
306
(Rate of energy or monitary consumption)
9
95.0
1

MONITOR
661
58
861
99
delta-temperature
delta-temperature
5
1
10

BUTTON
10
12
232
45
NIL
initialise
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

TEXTBOX
34
46
224
72
(Equivalent to setup and reset-sliders)
9
105.0
1

MONITOR
9
194
233
235
Time
ticks
0
1
10

@#$#@#$#@
WHAT IS IT?
-----------
A one-stock model of a thermostat/furnance/room system.  Using the System Dynamics Modeler, this model captures the essential design and behaviour of a Viessmann gas furnance being used in the Bas-Rhin of Alsace in France during winter.  All temperatures are in centigrade and initial values and ranges have been choosen for a typical winter season in this region of the world.

HOW IT WORKS
------------
Open the System Dynamics Model from the menu item

-  Tools -> System Dynamics Model

and note that there are one stock, one inflow, one outflow, four variables, and eight links:

-  Stocks: ROOM-TEMPERATURE;

-  Inflows: HEAT-TO-ROOM;

-  Outflow: HEAT-FROM-ROOM;

-  Variables: THERMOSTAT-SETTING, OUTSIDE-TEMPERATURE, ROOM-LEAKAGE-FACTOR, and ROOM-FURNACE-SIZE;

-  Links to HEAT-TO-ROOM from: THERMOSTAT-SETTING, ROOM-TEMPERATURE, ROOM-FURNACE-SIZE, and HEAT-FROM-ROOM; and

-  Links to HEAT-FROM-ROOM from: OUTSIDE-TEMPERATURE, ROOM-TEMPERATURE, ROOM-FURNACE-SIZE, and ROOM-LEAKAGE-FACTOR.

The outflow HEAT-FROM-ROOM is proportional to the descrpency between the OUTSIDE-TEMPERATURE and the ROOM-TEMPERATURE, is proportional to the ROOM-LEAKAGE-FACTOR, and is inversely proportional to the ROOM-FURNACE-SIZE (that is, the heat capacity of the room).

The ROOM-LEAKAGE-FACTOR inversely models the insolation of the room, the R factor.  The lower the ROOM-LEAKAGE-FACTOR, the smaller the loss of heat to the outside per unit time.  The greater the ROOM-LEAKAGE-FACTOR, the greater the loss of heat to the outside per unit time.  The ROOM-LEAKAGE-FACTOR is a percentage where 0% means no leakage and 100% means complete leakage, that is, at 100% leakage the furnance must add as much heat to the room as is leaving the room per unit time so as to maintain the current room temperature.  

The ROOM-FURNACE-SIZE is a unitless quantity in this model.  It is proportional to the size of the room and inversely propotional to the strength (size) of the furnace, that is, increasing the ROOM-FURNACE-SIZE means the room is larger relative to the size (strength) of the furnance and decreasing it means the room is smaller relative to the size (strength) of the furnance.

The thermostat/furnance/room system monitors the descrepency between the THERMOSTAT-SETTING and the ROOM-TEMPERATURE and also monitors the HEAT-FROM-ROOM outflow, which is dependent on the OUTSIDE-TEMPERATURE, so as to bring the ROOM-TEMPERATURE to or above the THERMOSTAT-SETTING if required.

Pay particular attention to DELTA-TEMPERATURE-TO-ROOM since this is where all the feedback logic of the thermostat/furnance/room system resides, this is where the action is.

Finally, in this model, MAXIMUM-DELTA-TEMPERATURE-TO-ROOM varies as the ROOM-FURNACE-SIZE-SLIDER varies.  The larger the room, the smaller MAXIMUM-DELTA-TEMPERATURE-TO-ROOM a given furnance can supply, and the smaller the room, the larger MAXIMUM-DELTA-TEMPERATURE-TO-ROOM the given furnance can supply.

HOW TO USE IT
-------------
To start the model for the first time, click on INITIALISE, and then GO to start the model, and then once again GO to stop the model.

The Interface tab consists of the following elements:

- INTIALISE: Equivalent to SETUP and RESET-SLIDERS.

- SETUP: Clears all plots and sets the ROOM-TEMPERATURE to the INITIAL-ROOM-TEMPERATURE (5).

- GO: Starts and stops the model.

- RESET-SLIDERS: Resets all sliders to their default values:
-- Set OUTSIDE-TEMPERATURE-SLIDER to INTIIAL-OUTSIDE-TEMPERATURE (0);
-- Set THERMOSTAT-SETTING-SLIDER to INTIIAL-THERMOSTAT-SETTING (21);
-- Set ROOM-LEAKAGE-FACTOR-SLIDER to INTIIAL-ROOM-LEAKAGE-FACTOR (30%, that is, 30% is a leaky room, 10% is good, and 50% is a very leaky room).
-- Set ROOM-FURNACE-SIZE-SLIDER to INITIAL-ROOM-FURNACE-SIZE (550, i.e., 100 is a small room relative to the furnance, 1000 is a larger room relative to the furnance, and 550 is in the middle).

- INSIDE TEMPERATURE MONITOR: Display the inside ROOM-TEMPERATURE.

- TIME MONITOR: Number of ticks so far.

- OUTSIDE-TEMPERATURE-SLIDER: Adjusts the OUTSIDE-TEMPERATURE from MINIMUM-OUTSIDE-TEMPERATURE (-25) to MAXIMUM-OUTSIDE-TEMPERATURE (45).

- THERMOSTAT-SETTING-SLIDER: Adjusts the THERMOSTAT-SETTING from MINIMUM-THERMOSTAT-SETTING (5) to MAXIMUM-THERMOSTAT-SETTING (25).

- ROOM-LEAKAGE-FACTOR-SLIDER: Adjusts the ROOM-LEAKAGE-FACTOR from MINIMUM-ROOM-LEAKAGE-FACTOR (5%) to MAXIMUM-ROOM-LEAKAGE-FACTOR (95%).

- ROOM-FURNACE-SIZE-SLIDER: Adjusts the ROOM-FURNACE-SIZE from MINIMUM-ROOM-FURNACE-SIZE (100) to MAXIMUM-ROOM-FURNACE-SIZE (1000).

- INSIDE TEMPERATURE PLOT: A plot of the inside room temperature versus time.

- RATE OF HEAT CONSUMPTION PLOT: A plot of heat, that is, energy or monetary consumption versus time.  It is scaled from 0 to 100.  0 means the furnance is not supplying heat to the room in order to maintain the rooms temperature, and 100 means the furmance is working at 100% of its maximum capacity.

- MAXIMUM-DELTA-TEMPERATURE-TO-ROOM MONITOR: The furnance/thermostat/room system has been sized to handle at most a given maximum temperature difference between the inside room temperature and the outside temperature, for a given efficiency of insolation of the room, and for a given size of the room relative to the size (strength) of the furnance.

- DELTA-TEMPERATURE MONITOR: The temperature change needed for the room only due to the discrepancy between theromostat setting and room temperatures.

- DELTA-TEMPERATURE-FROM-ROOM MONITOR: The temperature change of the room due to heat leaking from the room to the outside.  It can be negative, positive, or zero.

- DELTA-TEMPERATURE-TO-ROOM MONITOR: The temperature of the room from the furance adding heat to the room.  This takes into account the discrepancy between theromostat setting and room temperatures, DELTA-TEMPERATURE, and the heat lost to the outside, DELTA-TEMPERATURE-FROM-ROOM.  If this delta is to large for the furnance, then MAXIMUM-DELTA-TEMPERATURE-TO-ROOM is used instead.

THINGS TO NOTICE
----------------
To return to a known, default starting point, one must click on INITIALISE, otherwise clicking on SETUP allows one to keep the current slider settings and observe the model once again or adjust one of the sliders to observe how this variable affects the run of the model.  One can click on RESET-SLIDERS in the middle of a run of the model to return to a know point after adjusting several sliders at once.

THINGS TO TRY
-------------
Run the model serveral times and only adjust the ROOM-FURNACE-SIZE-SLIDER.  Do different values of the ROOM-FURNACE-SIZE change the shape of the two plots of this model?  Does it change the rate at which the room reaches dynamic equilibrium?  Adjust the ROOM-FURNACE-SIZE-SLIDER while the model is running.  Is the ROOM-FURNACE-SIZE variable interesting?

During a run of the model, try raising and lowering the THERMOSTAT-SETTING-SLIDER to observe the result.  During another run of the model, try raising and lowering the OUTSIDE-TEMPERATURE-SLIDER to observe the result.  Place the OUTSIDE-TEMPERATURE above the THERMOSTAT-SETTING.

Try a high THERMOSTAT-SETTING and a low OUTSIDE-TEMPERATURE so as to overwhelm the furnance and to force the ROOM-TEMPERATURE below the THERMOSTAT-SETTING.  Now try adjusting the ROOM-LEAKAGE-FACTOR-SLIDER and observe changes in the plots.

Run the model serveral times while only adjusting the ROOM-LEAKAGE-FACTOR-SLIDER before and during the run of the model.  What is the affect on the rate of heat consumption?

Does your intuition agree with the plots during runs of the model?  If not, is your intuition wrong or incomplete, does the model have a defect in one of the procedures, or is the model wrong or incomplete?

EXTENDING THE MODEL
-------------------
If outside conditions are dry and with little wind, many individuals will open many windows so as to air out the room.  Add a switch WINDOWS-OPEN such that ON means that they are open and OFF means that they are closed. (Hint: think about the ROOM-LEAKAGE-FACTOR.)

Extend the model so that ROOM-FURNACE-SIZE is replaced by the independent concepts of
ROOM-SIZE (heat capacity of the room) and FURNANCE-SIZE (strength of the furnance).  Of these two new variables, which one or ones affect the inflow and which one or ones affect the outflow?  How many links would one have given this change above?

Instead of the previous suggestion for extending the model, what about extending the model to include a sunny day warming the room via its windows?

NETLOGO FEATURES
----------------
All parameters can be changed in the SET-GLOBALS procedure, nothing is hard-coded outside of this procedure.

The procedure DO-PLOTS was needed to coordinate the two plots, MINIMUM-VALUE and MAXIMUM-VALUE were added for convenience, SAFE-ROOM-FURNANCE-SIZE was added to avoid dividing by zero, and RATE-OF-CONSUMPTION is an alias.

Version 1.19 of this model was tested under Netlogo 4.1.0, Java 1.6.0_18-b07, and Ubuntu 8.04.

RELATED MODELS
--------------
Other one stock models:

File -> Models Library -> Exponential Growth

File -> Models Library -> Logistic Growth

CREDITS AND REFERENCES
----------------------
Author Marcus D. Gabriel at marcus@gabriel.name.
Copyright (c) 2010.  All rights reserved.

See "Thinking in Systems, A primer" by Donella H. Meadows, ISBN 978-1-84407-726-7, chapter 2.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.1
@#$#@#$#@
@#$#@#$#@
1.0
    org.nlogo.sdm.gui.AggregateDrawing 17
        org.nlogo.sdm.gui.StockFigure "attributes" "attributes" 1 "FillColor" "Color" 225 225 182 261 119 60 40
            org.nlogo.sdm.gui.WrappedStock "room-temperature" "initial-room-temperature" 0
        org.nlogo.sdm.gui.ReservoirFigure "attributes" "attributes" 1 "FillColor" "Color" 192 192 192 59 249 30 30
        org.nlogo.sdm.gui.RateConnection 3 87 258 168 210 249 163 NULL NULL 0 0 0
            org.jhotdraw.figures.ChopEllipseConnector REF 3
            org.jhotdraw.standard.ChopBoxConnector REF 1
            org.nlogo.sdm.gui.WrappedRate "delta-temperature-to-room" "heat-to-room"
                org.nlogo.sdm.gui.WrappedReservoir  REF 2 0
        org.nlogo.sdm.gui.RateConnection 3 333 165 409 213 485 261 NULL NULL 0 0 0
            org.jhotdraw.standard.ChopBoxConnector REF 1
            org.jhotdraw.figures.ChopEllipseConnector
                org.nlogo.sdm.gui.ReservoirFigure "attributes" "attributes" 1 "FillColor" "Color" 192 192 192 482 253 30 30
            org.nlogo.sdm.gui.WrappedRate "(- delta-temperature-from-room)" "heat-from-room" REF 2
                org.nlogo.sdm.gui.WrappedReservoir  0   REF 12
        org.nlogo.sdm.gui.ConverterFigure "attributes" "attributes" 1 "FillColor" "Color" 130 188 183 35 324 50 50
            org.nlogo.sdm.gui.WrappedConverter "thermostat-setting-slider" "thermostat-setting"
        org.nlogo.sdm.gui.BindingConnection 2 70 334 168 210 NULL NULL 0 0 0
            org.jhotdraw.contrib.ChopDiamondConnector REF 15
            org.nlogo.sdm.gui.ChopRateConnector REF 4
        org.nlogo.sdm.gui.ConverterFigure "attributes" "attributes" 1 "FillColor" "Color" 130 188 183 481 321 50 50
            org.nlogo.sdm.gui.WrappedConverter "outside-temperature-slider" "outside-temperature"
        org.nlogo.sdm.gui.BindingConnection 2 495 331 409 213 NULL NULL 0 0 0
            org.jhotdraw.contrib.ChopDiamondConnector REF 20
            org.nlogo.sdm.gui.ChopRateConnector REF 9
        org.nlogo.sdm.gui.BindingConnection 2 249 163 168 210 NULL NULL 0 0 0
            org.jhotdraw.standard.ChopBoxConnector REF 1
            org.nlogo.sdm.gui.ChopRateConnector REF 4
        org.nlogo.sdm.gui.BindingConnection 2 333 165 409 213 NULL NULL 0 0 0
            org.jhotdraw.standard.ChopBoxConnector REF 1
            org.nlogo.sdm.gui.ChopRateConnector REF 9
        org.nlogo.sdm.gui.ConverterFigure "attributes" "attributes" 1 "FillColor" "Color" 130 188 183 296 322 50 50
            org.nlogo.sdm.gui.WrappedConverter "room-leakage-factor-slider / 100" "room-leakage-factor"
        org.nlogo.sdm.gui.BindingConnection 2 330 331 409 213 NULL NULL 0 0 0
            org.jhotdraw.contrib.ChopDiamondConnector REF 31
            org.nlogo.sdm.gui.ChopRateConnector REF 9
        org.nlogo.sdm.gui.BindingConnection 2 409 213 168 210 NULL NULL 0 0 0
            org.nlogo.sdm.gui.ChopRateConnector REF 9
            org.nlogo.sdm.gui.ChopRateConnector REF 4
        org.nlogo.sdm.gui.ConverterFigure "attributes" "attributes" 1 "FillColor" "Color" 130 188 183 268 10 50 50
            org.nlogo.sdm.gui.WrappedConverter "room-furnance-size-slider" "room-furnance-size"
        org.nlogo.sdm.gui.BindingConnection 2 282 49 168 210 NULL NULL 0 0 0
            org.jhotdraw.contrib.ChopDiamondConnector REF 39
            org.nlogo.sdm.gui.ChopRateConnector REF 4
        org.nlogo.sdm.gui.BindingConnection 2 302 50 409 213 NULL NULL 0 0 0
            org.jhotdraw.contrib.ChopDiamondConnector REF 39
            org.nlogo.sdm.gui.ChopRateConnector REF 9
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@