turtles-own 
[
  turtle-state   ;; turtle-state of this turtle, taking value of +/-1
  mean-received  ;; the mean of all the turtle-states from all connected turtles (including itself)
]

globals 
[ 
  min-noise-level-4-agreement  ;; the minimum level of noise that can guarantee the entire network to reach agreement/consensus
  max-noise-level-4-agreement  ;; the maximum level of noise that can guarantee the entire network to reach agreement, above which the network generates symmetric behavior / disagreement
  prediction-msg  ;; the message displayed to predict agreement or disagreement
  instant-sum-states  ;; for statistics, the sum of all turtle states at a time instant
  accumulated-sum-states  ;; for statistics, the sum of all turtle-states over all the time instants
]  

to setup
  clear-all
  crt population
  [ 
    set size 5  ;; easier to see
    set shape "dot"
    ;; set label who  ;; if uncommented, this will put labels by the turtles
    setxy random-xcor random-ycor 
    set turtle-state ( random 2 ) * 2 - 1  ;; uniformly distributed over +/-1
    recolor ;; color the turtles in red or blue
  ]
  reset-ticks
  update-links  ;; establish and show links among the turtles
  ifelse noise-level <= max-noise-level-4-agreement and noise-level > min-noise-level-4-agreement
  [
    ifelse random-connection?
    [ set prediction-msg "Network will reach consensus (agreement/symmetry)!" ]
    [ set prediction-msg "All connected sub-graphs will reach symmetry (disagreement)!" ]
  ]
  [ 
    ifelse noise-level > min-noise-level-4-agreement
    [ set prediction-msg "Network will reach symmetry (disagreement)!" ]
    [ set prediction-msg "Network behavior cannot be predicted!" ]
  ]
end

to go
  update-links  ; re-establish and show links among the turtles
  ask turtles
  [ 
    receive-states
  ]
  ask turtles
  [ 
    update-state
  ]  
  set instant-sum-states ( sum [ turtle-state ] of turtles )
  set accumulated-sum-states ( accumulated-sum-states + instant-sum-states )
  tick
end

to update-links  ;; to initialize links or update links
  ifelse random-connection? = true
  [ 
    update-random-graph
	  set min-noise-level-4-agreement 0
	  set max-noise-level-4-agreement 1	
  ]  
  [ 
    initial-fixed-graph
	  let max-degree max [count link-neighbors] of turtles
	  set min-noise-level-4-agreement 1 - 2 / max-degree
	  set max-noise-level-4-agreement 1
  ]    
end

to update-random-graph  ;; to initialize or update the random graph according to random graph process
  let n count turtles
  let n-total-links n * ( n - 1 ) / 2
  let n-links n-total-links * p-for-random-connection
  clear-links  ;; remove all existing links and will create completely new links for each tick
  repeat n-links 
  [ 
    ask one-of turtles
    [
      create-link-with one-of other turtles
    ]
  ]
end


to initial-fixed-graph  ;; to initialize the fixed graph based on nearest neighbors
  if ticks = 0
  [
	  ask turtles 
	  [ 
	    create-links-with ( other turtles in-radius vision )  ;; one way to create a fixed graph is to connect to nearest neighbors only
	  ]
  ]
end

to receive-states  ;; turtle procedure
  if any? link-neighbors
  [ 
    set mean-received average-turtle-state-link-neighbors  ;; a turtle receives the turtle-states from all neighbors (inclusive) 
  ]
end

to-report average-turtle-state-link-neighbors  ;; turtle procedure
  let neighbor-states [ turtle-state ] of  ( turtle-set ( link-neighbors ) ( turtles-here ) )
  let mean-value mean neighbor-states  ;; find the average of the turtle-states from all neighbors (inclusive) 
  report mean-value
end

  
to update-state  ;; turtle procedure
  if any? link-neighbors
  [ 
    perturb  ;; the received information is perturbed by a random noise and determine the next state of this turtle
    recolor  ;; update the color according to new state
  ]
end

to perturb  ;; turtle procedure. The received information is perturbed by a random noise and determine the next state of this turtle
  set turtle-state sign ( mean-received + ( ( random-float 1 ) * 2 - 1 ) * noise-level )
end

to recolor
  ifelse turtle-state = -1
  [ 
    set color blue 
  ]
  [ 
    set color red 
  ]  
end

to-report sign [number]
  ifelse number >= 0
  [ 
    report 1
  ]
  [ 
    report -1
  ]
end

;;Copyright 2013 J. Liu.
@#$#@#$#@
GRAPHICS-WINDOW
289
15
783
530
60
60
4.0
1
10
1
1
1
0
0
0
1
-60
60
-60
60
1
1
1
ticks
30.0

BUTTON
10
95
87
128
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
103
95
184
128
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
9
51
274
84
population
population
1.0
100.0
100
1.0
1
NIL
HORIZONTAL

SLIDER
27
230
268
263
vision
vision
0.0
30.0
16.5
0.5
1
patches
HORIZONTAL

SLIDER
11
135
272
168
noise-level
noise-level
0.0
2.0
1.01
0.01
1
NIL
HORIZONTAL

PLOT
803
52
1003
202
sum sequence
ticks
NIL
0.0
500.0
0.0
10.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" "plot instant-sum-states"

PLOT
805
216
1005
366
sum of sum sequence
ticks
values
0.0
10.0
0.0
10.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" "plot accumulated-sum-states"

PLOT
807
379
1007
529
average of sum sequence
NIL
NIL
0.0
10.0
0.0
10.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" "plot accumulated-sum-states / ( 1 + ticks )"

SWITCH
11
184
160
217
random-connection?
random-connection?
0
1
-1000

SLIDER
28
285
268
318
p-for-random-connection
p-for-random-connection
0
.5
0.04
0.001
1
NIL
HORIZONTAL

BUTTON
199
95
274
128
go once
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

MONITOR
6
342
272
387
min/max noise levels guaranteeing agreement
list precision min-noise-level-4-agreement 3 \nprecision max-noise-level-4-agreement 3
2
1
11

MONITOR
27
400
84
445
#red
count turtles with [ color = red ]
2
1
11

MONITOR
161
399
218
444
#blue
count turtles with [ color = blue ]
2
1
11

MONITOR
7
458
274
503
Prediction
prediction-msg
17
1
11

@#$#@#$#@
## WHAT IS IT?

This simple model demonstrates a phase transition behavior emerging from the interactions among multiple agents in the presence of noise. 

At a noise level higher than a certain threshold, the system generates symmetric behavior (e.g. vapor or melt of magnetization) or disagreement; whereas at a noise level lower than the threshold, the system exhibits spontaneous symmetry breaking (solid or magnetization) or consensus. 

This provides some simple intuitions for understanding the impact of noise in communication networks on network behavior and the impact of noise (temperature) in phase transitions.

NOTE: For this simulator, the following terms are used interchangeably: 
Consensus, agreement, asymmetry, and all agents taking the same value.
Disagreement, asymmetry, and approximately half of the agents taking +1 (colored as red) and the other half taking -1 (colored as blue).


## HOW IT WORKS

A group of non-mobile agents form a network, and each agent, taking bipolar value either +1 or -1, updates its value according to its previous value and the noisy measurements of the values of the agents connected to it. 

Update rule: At each moment, each turtle receives all values from all turtles connected to it (including the turtle itself); these values are then averaged at the turtle and perturbed by a noise. The noise is uniformly distributed in interval [-z, z], where z is called the noise level. If the perturbed average value is positive, then the turtle will take value +1, otherwise it will take value -1.

In other words, each turtle first aggregates the opinions of all its connections and itself (subject to communication/observation noise perturbation), and then follows the aggregated opinion. 



## HOW TO USE IT

To simulate, press SETUP to create the turtles and links, and then press GO to see the network evoluation or GO ONCE to go one step. 

The following may be set before SETUP:

POPULATION: Use the slider to set the value for the number of turtles in the simulation.  A very high POPULATION may slow down the simulation. 

NOISE-LEVEL: Use the slider to set the noise level.

RANDOM-CONNECTIONS?: If ON is chosen, then the network forms a random graph process, with probability p (set by P-FOR-RANDOM-CONNECTIONS slider) to form a link between any two turtles. If OFF is chosen, then the network is over a fixed graph formed by connecting the nearest turtles within a distance set by VISION slider.

VISION: For the fixed graph case (RANDOM-CONNECTIONS?=OFF) only. Two turtles are connected by a link if they are within the distance set by VISION sider.

P-FOR-RANDOM-CONNECTIONS: For the random graph case (RANDOM-CONNECTIONS?=ON) only. For any turtle pair, the probablity of forming a connection (i.e. a link) is given by P-FOR-RANDOM-CONNECTIONS slider.

MIN/MAX NOISE LEVEL GUARANTEEING AGREEMENT: This displays, for a network after SETUP button is pressed, a pair of numbers such that if NOISE-LEVEL slider chooses any value between the min and max, then agreement is guaranteed. 

The following are output:

\#RED, #BLUE: These display the number of red turtles (with state value +1) and the number of blue turtles (with state value -1) at the current time instant.

PREDCTION: This displays the prediction message. After SETUP button is preseed, the simulator makes a prediction of the behavior based on some analytic results. The prediction message may be: 
"Network will reach consensus (agreement/symmetry)!"
"Network will reach symmetry (disagreement)!"
"All connected sub-graphs will reach symmetry (disagreement)!"
"Network behavior cannot be predicted!"

SUM SEQUENCE: Each data point of the sequence corresponds to a tick in time and the sum of all turtles' state values at that time.

SUM OF SUM SEQUENCE: Each data point of the sequence corresponds to a tick in time and the accumulated sum of the SUM SEQUENCE by that time.

AVERAGE OF SUM SEQUENCE: Each data point of the sequence corresponds to a tick in time and the mean value of the SUM SEQUENCE by that time.


## THINGS TO NOTICE

If the noise level set by NOISE-LEVEL slider is higher than the displayed MAX NOISE LEVEL GUARANTEEING AGREEMENT, the system generates symmetric behavior (e.g. vapor or melt of magnetization) or disagreement; whereas at a noise level lower than MAX NOISE LEVEL GUARANTEEING AGREEMENT but above MIN NOISE LEVEL GUARANTEEING AGREEMENT, the system exhibits symmetry breaking (solid or magnetization) or consensus.  This holds for both the fixed graph (RANDOM-CONNECTIONS?=OFF) and random graph process (RANDOM-CONNECTIONS?=ON).

If agreement is predicted, #RED, #BLUE, SUM SEQUENCE, SUM OF SUM SEQUENCE, and AVERAGE OF SUM SEQUENCE will reach/converge to some constants.

If disagreement is predicted, #RED, #BLUE, and SUM SEQUENCE will oscillate, SUM OF SUM SEQUENCE will exhibit a random walk behavior, and AVERAGE OF SUM SEQUENCE will tend to zero.

## THINGS TO TRY

For the random graph case, sweep the noise level (NOISE-LEVEL) and connection probability (P-FOR-RANDOM-CONNECTIONS), and observe network behavior.

For the fixed graph case, sweep the noise level (NOISE-LEVEL) and vision (VISION), and observe network behavior.


## EXTENDING THE MODEL

This model assumes no leader yet. What if there is one or more leaders of a same color? What if there are several leaders with different colors?

What if there are more than two states or more than two colors for each turtle?

What if other noise distributions are used?


## NETLOGO FEATURES


## RELATED MODELS

* Flocking
* Flocking Vee Formation
* Ising 
* Boiling

## CREDITS AND REFERENCES

This model is based on:

* J. Liu, V. Yadav, H. Sehgal, J. M. Olson, H. Liu, N. Elia: Phase Transitions on Fixed Connected Graphs and Random Graphs in the Presence of Noise. IEEE Trans. Automat. Contr. 53(8): 1817-1825 (2008)


* J. Liu, V. Yadav, H. Sehgal, J. M. Olson, H. Liu, N. Elia: Phase Transitions on Fixed Connected Graphs and Random Graphs in the Presence of Noise. Proc. 44th IEEE Conference on Decision and Control (CDC) and 2005 European Control Conference (ECC): 734-739 (2005)


## HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

* J. Liu, V. Yadav, H. Sehgal, J. M. Olson, H. Liu, N. Elia: Phase Transitions on Fixed Connected Graphs and Random Graphs in the Presence of Noise. IEEE Trans. Automat. Contr. 53(8): 1817-1825 (2008)

* Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

## COPYRIGHT AND LICENSE

Copyright 2013 J. Liu.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.0.3
@#$#@#$#@
set population 200
setup
repeat 200 [ go ]
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 1.0 0.0
0.0 1 1.0 0.0
0.2 0 1.0 0.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@