; Genereate habitat and dist data at the beginning
; species data is the only thing that changes throughout the runs.

extensions[table]

globals
[ 
  species-counts 
  species-numbers
 
  log-normal-distribution
 
  species-sample-data
  plot-data 
]

turtles-own [ species ]
patches-own [ environment ]


to calculate-plots
  
  let counter 0
  let x 0
  let y 0
  let num-cols ceiling(sqrt(sample-plot-number))
  let num-rows ceiling(sample-plot-number / num-cols)
  let hspace floor(world-width / num-cols - sample-plot-size / 2)
  let vspace floor(world-height / num-rows - sample-plot-size / 2)
  
  let row-count 0
  let col-count 0
  
  if sample-method = "by-number"
  [ 
    while [row-count < num-rows and counter < sample-plot-number]
    [
      while [col-count < num-cols and counter < sample-plot-number]
      [
        set counter (counter + 1)
        
        let data (list)
        set data lput counter data
        set data lput x data
        set data lput y data
        
        set plot-data lput data plot-data
        
        set x (x + hspace)
        set col-count (col-count + 1)
      ]
      
      set x 0
      set y (y + vspace)
      set row-count (row-count + 1) 
      set col-count 0
    ]
  ]
  
  output-print plot-data  
end

to choose-export-directory
  let dir user-directory  
  if not (dir = false) [ set export-directory dir ]
end

to decrement-species-count [value]  
   
  let index position value species-numbers
  
  if (index != false) [ set species-counts (replace-item index species-counts ((item index species-counts) - 1)) ]
  
end

to-report determine-color [spec-num]
  ;-------------------------------------------------------------------
  ; Determines the color corresponding to the given species number
  ;------------------------------------------------------------------- 
  let prefix floor (spec-num / 10)
  
  if prefix = 2 [ report "Red" ]
  if prefix = 4 [ report "Yel" ]
  if prefix = 6 [ report "Grn" ]
  if prefix = 8 [ report "Blu" ]
  if prefix = 10 [ report "Pur" ]
  if prefix = 12 [ report "Sky" ]
  
end

to-report determine-log-normal
  ;-------------------------------------------------------------------
  ; Determines the log-normal distribution to use for immigraiton
  ;-------------------------------------------------------------------
  ; These distributions were calculated beforehand by averaging over
  ;  1000 generated distributions
  ;-------------------------------------------------------------------
  let log-norm (list)
  
  if number-of-species = 2 [ set log-norm (list 0.7183367 0.2816633) ]  
  if number-of-species = 3 [ set log-norm (list 0.5975081 0.2708414 0.1316505) ]  
  if number-of-species = 4  [ set log-norm (list 0.51702986 0.25482877 0.14737724 0.08076413) ]  
  if number-of-species = 5 [ set log-norm (list 0.45835715 0.24265518 0.15096362 0.09550529 0.05251876) ]  
  if number-of-species = 6 [ set log-norm (list 0.41507604 0.22785213 0.14891503 0.10189594 0.06733728 0.03892358) ]
  
  print word "Log Normal - " log-norm
  foreach species-numbers [ write determine-color ? ]
  print ""
  report log-norm
    
end

to export-sample-data
   
  let species-file word word "species-" ticks ".csv"
  
  if file-exists? species-file [ file-delete species-file ]
  
  ; Generates the header portion of the species data file
  let header "species"  
  foreach plot-data [ set header word word header "," (item 0 ?) ]  
  
  file-open species-file
  file-print header
  foreach species-sample-data [ file-print ? ]

  print word word ">>> Sample Successfully Taken at " ticks " ticks"
  
end

to generate-continuous
  
  ; Seed each of the regions
  foreach species-numbers
  [
    ask patch random-pxcor random-pycor 
    [ 
      set environment ? 
      set pcolor (? - 3)
    ]
  ]
  
  ; Keep expanding each region by one patch at a time until the board is full
  while [not (one-of patches with [environment = 0] = nobody)]
  [
    foreach species-numbers
    [
      let next-patch one-of patches with [(environment = 0) and (one-of neighbors4 with [environment = ?]) != nobody]
      if next-patch != nobody
      [
        ask next-patch
        [
          set environment ? 
          set pcolor (? - 3)
        ]
      ]
    ]
  ]

end

to generate-local
  
  ; Calculate total size of each region
  let regional-plot-count (regional-radius ^ 2)
  
  while [not (one-of patches with [environment = 0] = nobody)]
  [
    foreach species-numbers
    [
      ; Seed the new region
      let next-patch one-of patches with [environment = 0]
      let counter 0
      
      ; Populate the new region
      while [counter < regional-plot-count]
      [
        if next-patch != nobody
        [
          ask next-patch
          [
            set environment ? 
            set pcolor (? - 3)
            set next-patch one-of neighbors4 with [environment = 0]
          ]
        ]
        
        set counter (counter + 1)
      ]
    ]
  ]
  
end

to generate-neopolitan
  
  ; Calculate the width of each stripe
  let stripe-width world-width / number-of-species
  
  ; Paint the stripes
  let stripe-index 0
  foreach species-numbers
  [
    let curr-spec ?
    let start-x stripe-width * stripe-index      
    let x start-x
    
    while [x <= min list (start-x + stripe-width) (world-width - 1)]
    [
      let y-vals n-values world-height [?]
      foreach y-vals
      [
        ask patch x ?
        [
          set environment curr-spec
          set pcolor (curr-spec  - 3)
        ]        
      ]
      
      set x (x + 1)        
    ]
    
    set stripe-index (stripe-index + 1)
  ]
end

to generate-habitat-patches
  
  if habitat-generation-method = "Continuous Patches" [ generate-continuous ]  
  if habitat-generation-method = "Local Patches" [ generate-local ]  
  if habitat-generation-method = "Neopolitan"[ generate-neopolitan ]
  
end

to-report generate-habitat-data
  
  let header "habitat"  
  foreach plot-data [ set header word word header "," (item 0 ?) ]
  
  let habitat-data (list)
  
  let counter 1
  foreach species-numbers
  [
    set counter 0  
    let data-string determine-color ?
    let curr-spec ?
    
    foreach plot-data
    [
      let habitat-counter 0
      set data-string word data-string ","
      
      let x item 1 ?
      let y item 2 ?
      
      let hor-vals n-values sample-plot-size [x + ?]
        
      foreach hor-vals
      [ 
        let hor ?
        
        let ver-vals n-values sample-plot-size [y + ?]
        
        foreach ver-vals
        [
          let ver ?
          if [environment] of patch hor ver = curr-spec
          [
            set habitat-counter habitat-counter + 1 
          ]
        ]
      ]
      
      set data-string word data-string habitat-counter
    ]
    
    set habitat-data lput data-string habitat-data
  ]
  
  set habitat-data fput header habitat-data
  
  report habitat-data
  
end

to-report generate-plot-data
  
  let header "plotid,x,y"
  
  let plot-data-list (list)
  set plot-data-list lput header plot-data-list
  
  foreach plot-data
  [
    let current-plot item 0 ?
    set current-plot word current-plot ","
    set current-plot word current-plot item 1 ?
    set current-plot word current-plot ","
    set current-plot word current-plot item 2 ?
    
    set plot-data-list lput current-plot plot-data-list
  ]
  
  report plot-data-list
  
end

to go
   
  move-random-walk random-pxcor random-pycor
  
  tick
  
  if sample-number = "Automatic" and ticks mod sample-timing = 0 [ sample-grid ]
  if ticks mod plot-interval = 0 [ plot-current-data ]

end

to increment-species-count [value]  
  
  let index position value species-numbers  
  if (index != false) [ set species-counts (replace-item index species-counts ((item index species-counts) + 1)) ]
  
end

to move-random-walk [x-cor y-cor]
  
  let continue true
  
  while [continue = true] 
  [
    let global-max-steps sqrt world-width ^ 2 + world-height ^ 2
    let max-steps floor global-max-steps * (local-global-dispersal / 100)
    
    let start-patch patch x-cor y-cor
    ask start-patch 
    [
      let turt one-of turtles-here
      if turt != nobody
      [
        ask turt
        [
          decrement-species-count species
          die
        ] 
      ]  
    ]
    
    let seed-patch start-patch
    let seed-turtle nobody
    let immigrant-species 0
    
    ;; Immigration
    let imm-chance (random 100)
    
    ifelse (imm-chance < immigration-chance)
    [
      let immigrant-selector (random 100)
      
      let prob-sum 0
      let counter 0
      let flag 0
      while [counter < number-of-species]
      [
        set prob-sum (prob-sum + (100 * item counter log-normal-distribution))
        
        if immigrant-selector < prob-sum and flag = 0
        [            
          set immigrant-species item counter species-numbers
          set flag 1
        ]
        
        set counter (counter + 1)
      ]
    ]
    [
      while [max-steps > 0]
      [
        ; For each step, set the seed-patch to a neighbor of the current seed-patch
        let temp seed-patch
        
        ask seed-patch [set temp one-of neighbors ]
        
        set seed-patch temp
        
        ask seed-patch[set seed-turtle one-of turtles-here]
        
        set max-steps (max-steps - 1)
      ]
    ]
    
    ;; Generate a number between 0 and 99
    let habitat-chance (random 100)
    
    ifelse (not (seed-turtle = nobody) and ([species] of seed-turtle = [environment] of start-patch or habitat-chance > habitat-dependency))
    [   
      ask start-patch 
      [
        sprout 1
        
        let new-turt one-of turtles-here
        ask new-turt
        [
          increment-species-count [species] of seed-turtle
          set species [species] of seed-turtle
          set color [species] of seed-turtle
        ]
      ]
        
      set continue false
    ]
    [
      if (immigrant-species != 0 and (immigrant-species = [environment] of start-patch or habitat-chance > habitat-dependency))
      [
        ask start-patch 
        [
          sprout 1
          
          let new-turt one-of turtles-here
          ask new-turt
          [
            increment-species-count immigrant-species
            set species immigrant-species
            set color immigrant-species
            set label "I"
          ]
        ]
        
        set continue false
      ]    
    ]
  ]
end

to plot-current-data
  
  set-current-plot "Species"
  
  let curr-index 0
  
  while [curr-index < number-of-species]
  [
    set-current-plot-pen determine-color item curr-index species-numbers
    plotxy ticks item curr-index species-counts
    
    set curr-index (curr-index + 1)
  ]  
  
end

to sample-grid
  
  set species-sample-data (list)
  
  if sample-method != "none"
  [
      let sample-data table:make
      
      foreach species-numbers
      [
        table:put sample-data ? determine-color ? 
      ]
           
      foreach plot-data
      [
        let plot-x item 1 ?
        let plot-y item 2 ? 
        
        foreach species-numbers
        [
          table:put sample-data ? word word table:get sample-data ? "," sample-plot plot-x plot-y ?
        ]
      ]   
      
      foreach species-numbers
      [
        set species-sample-data lput table:get sample-data ? species-sample-data
      ]
  ]
  
  export-sample-data
end

to-report sample-plot [x-cor y-cor species-number]
    
  let hor x-cor
  let counter 0 
  
  while [hor < x-cor + sample-plot-size]
  [   
    let ver y-cor  
      
    while [ver < y-cor + sample-plot-size]
    [        
        ask patch hor ver
        [          
          if [species] of one-of turtles-here = species-number
          [
            set counter counter + 1
          ]
        ]  
              
      set ver ver + 1
    ]
          
    set hor hor + 1
  ]
  
  report counter
end

to setup

  clear-all
  
  if sample-timing = 0 
  [
    user-message "Sample Timing must be greater than 0.\nFor your convenience we will set it to 1000 now, but please, do try to remember in the future."
    set sample-timing 1000
  ]
  
  set plot-data (list)
  set species-counts (list)
  set species-numbers (list)  
  set species-sample-data (list)
  
  calculate-plots
  set-default-shape turtles "leaf"  
  
  ;------------------------------------------------------------------
  ; Fill the global lists species-counts and species-numbers
  ;------------------------------------------------------------------
  ; species-counts will hold the number of each species that exists
  ; species-numbers will hold the integer value representing each 
  ;    species
  ;------------------------------------------------------------------
  let currIndex 1
  while [currIndex <= number-of-species]
  [
   set species-counts lput 0 species-counts
   set species-numbers lput (currIndex * 20 + 6) species-numbers 
   set currIndex currIndex + 1
  ]  
  
  ; Sprout all of the patches
  ask patches 
  [
   sprout 1
   set environment 0 
  ]
  
  ; Intialize all the turtles
  ask turtles 
  [
    let value ((random number-of-species + 1) * 20 + 6)    
    set species value
    set color value    
    increment-species-count(value)
  ]
    
  ; Setup the habitat regions
  generate-habitat-patches
  
  ; Setup log-normal distribution for immigration
  set log-normal-distribution determine-log-normal
  
  ; Force the user to select an export directory if the currently
  ; selected on does not exists
  if not file-exists? export-directory or length export-directory = 0 [ choose-export-directory ]
  
  ; Export the habitat, plot, and world information
  set-current-directory export-directory
  
  let habitat-file "habitat.csv"
  let plots-file "plots.csv"
  
  if file-exists? habitat-file [ file-delete habitat-file ]
  if file-exists? plots-file [ file-delete plots-file ]
  
  file-open habitat-file  
  foreach generate-habitat-data [ file-print ? ]
  
  file-open plots-file  
  foreach generate-plot-data [ file-print ? ]
  
  file-close-all
  
  export-world word export-directory "world.csv"
  
  reset-ticks
end
@#$#@#$#@
GRAPHICS-WINDOW
934
66
1322
475
-1
-1
18.0
1
10
1
1
1
0
1
1
1
0
20
0
20
1
1
1
ticks
30.0

BUTTON
93
10
156
43
Go
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
16
10
90
43
Setup
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
177
10
329
43
number-of-species
number-of-species
2
6
3
1
1
NIL
HORIZONTAL

SLIDER
339
10
507
43
habitat-dependency
habitat-dependency
0
100
0
1
1
NIL
HORIZONTAL

SLIDER
513
10
709
43
local-global-dispersal
local-global-dispersal
1
100
10
1
1
NIL
HORIZONTAL

SLIDER
13
157
156
190
sample-plot-size
sample-plot-size
2
20
3
1
1
NIL
HORIZONTAL

CHOOSER
13
103
151
148
sample-method
sample-method
"none" "by-number"
0

INPUTBOX
14
202
117
262
sample-timing
100
1
0
Number

CHOOSER
155
103
309
148
sample-number
sample-number
"Manual" "Automatic"
0

INPUTBOX
163
158
283
218
sample-plot-number
2
1
0
Number

BUTTON
126
228
313
261
Take Sample
sample-grid
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
716
10
914
43
immigration-chance
immigration-chance
0
100
1
1
1
NIL
HORIZONTAL

PLOT
435
180
911
468
Species
NIL
NIL
0.0
10.0
0.0
10.0
true
false
"" ""
PENS
"Red" 1.0 0 -2674135 true "" ""
"Grn" 1.0 0 -10899396 true "" ""
"Yel" 1.0 0 -1184463 true "" ""
"Blu" 1.0 0 -13345367 true "" ""
"Pur" 1.0 0 -5825686 true "" ""
"Sky" 1.0 0 -13791810 true "" ""

CHOOSER
942
10
1131
55
habitat-generation-method
habitat-generation-method
"Continuous Patches" "Local Patches" "Neopolitan"
0

SLIDER
1142
10
1314
43
regional-radius
regional-radius
1
10
3
1
1
NIL
HORIZONTAL

SLIDER
434
134
722
167
plot-interval
plot-interval
1
50
1
1
1
NIL
HORIZONTAL

BUTTON
14
365
210
398
Select Export Directory
choose-export-directory
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

INPUTBOX
12
404
394
464
export-directory
NIL
1
0
String

@#$#@#$#@
## WHAT IS IT 
The goal of this model is to simulate the dynamics of a local plant community to explore the effects of niche and neutral factors in community dynamics.  Users can vary the number of species present, the dependency of a given species on a given habitat (a niche factor), the dispersal distance (a neutral factor), and the possibility of immigration from a metacommunity..  Users may also sample from the world, to see how easy or difficult it is to detect the signature of niche versus neutral factors in communities.

## BASIC WORLD SIMULATION 
The basic variables for every world are as follows: 

number-of-species: The number of different plant species that will exist. 

habitat-dependency: The dependency of a plant species on the habitat in order to be seeded (by percentage) 

global-local-dispersal: The percentage distance around the world from which a patch can be seeded (100 signifies being able to choose a “parent” from the entire world, 1 signifies only being able to choose immediate neighbors as possible seed donors. 

immigration-chance: The percentage chance of a random species immigrating into the world (not a new one, but from the same roster of species in the local simulation; species are log-normally distributed in the meta-community). 

## SAMPLING 
Upon clicking “Setup”, you will automatically be prompted to select and export direcotry if one has not already been selected. Alternatively, you may manually select a directory to use for exporting data by clicking “Select Export Directory”. The currently selected directory for exporting will be shown in the text box. 

The value of “sample-number” determines the way that samples will be taken. “manual” means that samples will only be taken by clicking the “Take Sample” button. “with-frequency” will take a sample each “sample-frequency” number of ticks. 
The following parameters can be controlled in order to customize world sampling: 

sample-plot-size: Each sample plot will be a square with this side length. 

sample-method: Based on which option is selected the sampling is controlled by different parameters.

Select “none” to disable sampling.
Select “by-percentage” to sample a certain percentage of the world.
Select “by-number” to sample the world with a certain number of plots.
Select “even-spacing” to sample the entire world with an even spacing of sample plots. 

sample-plot-distance: The number of spaces separating  sample plots. 

sample-plot-number: The total number of sample plots to take on each sampling if the “by-number” sampling method was selected. 

sample-percentage: The total percentage of the world to sample if the “by-percentage” sampling method was selected. 

## IMMIGRATION 
There is the possibility of immigration in the world. The “immigration-chance” variable is the percentage chance of an immigrant attempting to seed. These immigrants are subject to the same habitat-dependency that has already been selected, and the species of the immigrant is chosen off of the log-normal distribution in a source community which is reported at the beginning of the simulation. 

## ABOUT 
Model created by Lucas Kushner, Kalamazoo College Class of 2014 (B.A., Computer Science), with conceptual background provided by Dr. Binney Girdler, Associate Professor of Biology, Kalamazoo College, Kalamazoo, Michigan 
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
0
Rectangle -7500403 true true 151 225 180 285
Rectangle -7500403 true true 47 225 75 285
Rectangle -7500403 true true 15 75 210 225
Circle -7500403 true true 135 75 150
Circle -16777216 true false 165 76 116

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.0.5
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@