globals [
  food-amount         ;; The number of pieces of food in the trail
  steps               ;; The number of steps the ant performed
  food-eaten          ;; The number of pieces of food found and eaten by the ant 
  init-actions        ;; Actions have been initialised (checked and modified in the first loop of "go"
  actions             ;; The Ant-actions to be executed in "go"
]

patches-own [
  food?                ;; true if the patch is a food part of the trail
  gap?                 ;; true if the patch is a gap part of the trail
]


;;;;;;;;;;;;;;;;;;;;;;;;
;;; Setup procedures ;;;
;;;;;;;;;;;;;;;;;;;;;;;;

to setup

  clear-all  
  setup-global-settings
  setup-santa-fe-trail
  koza-solution
  
  crt 1 [
    set size 1
    set color red
    setxy 0 0
    facexy 1 0  
  ]
  
end

to setup-global-settings

  set-default-shape turtles "bug"
  set food-amount 89
  set steps 0
  set food-eaten 0 
  set Ant-Actions " "
  set init-actions false
  set actions ""

end


to setup-santa-fe-trail

  ask patches [
    set food? false
    set gap? false
    set pcolor 32
  ] 

  let char ""
  let x 0
  let y 0  
  let sft ""
  
  set sft word sft ".111............................"
  set sft word sft "...1............................"
  set sft word sft "...1....................011100.."
  set sft word sft "...1....................1....1.."
  set sft word sft "...1....................1....1.."
  set sft word sft "...1111011111.......01100....0.."
  set sft word sft "............1.......0........1.."
  set sft word sft "............1.......1........0.."
  set sft word sft "............1.......1........0.."
  set sft word sft "............1.......1........1.."
  set sft word sft "............0.......1........0.."
  set sft word sft "............1.......0........0.."
  set sft word sft "............1.......0........1.."
  set sft word sft "............1.......1........0.."
  set sft word sft "............1.......1..0001110.."
  set sft word sft "............0...01000..1........"
  set sft word sft "............0...0......0........"
  set sft word sft "............1...0......0........"
  set sft word sft "............1...1......01000...."
  set sft word sft "............1...1..........1...."
  set sft word sft "............1...1..........0...."
  set sft word sft "............1...1..........0...."
  set sft word sft "............1...0......00010...."
  set sft word sft "............1...0......1........"
  set sft word sft ".001100111110...1..............."
  set sft word sft ".1..............1..............."
  set sft word sft ".1..............1..............."
  set sft word sft ".1.....0111111100..............."
  set sft word sft ".1.....1........................"
  set sft word sft ".0.....1........................"
  set sft word sft ".0111100........................"
  set sft word sft "................................"
  
  while [x < 1024] [
    
    set y int (x / 32)   
    set char item x sft      
    if char = "1" [ask patch x (y * -1) [add-food]] 
    if char = "0" [ask patch x (y * -1) [add-gap]]    
    set x x + 1
    
  ]
 
end

to add-food
  set food? true
  set pcolor 54
end

to add-gap
  set gap? true
  set pcolor 34
end

to koza-solution

  let act ""
  set Ant-Actions ""  
 
  set act word act "ifelse food-ahead\n"
  set act word act "  [move]\n"
  set act word act "  [\n"
  set act word act "    turn-left\n"
  set act word act "    ifelse food-ahead\n"
  set act word act "      [move]\n"
  set act word act "      [turn-right]\n"
  set act word act "    turn-right\n"
  set act word act "    turn-left\n"
  set act word act "    turn-right\n"
  set act word act "    ifelse food-ahead\n"
  set act word act "      [move]\n"
  set act word act "      [turn-left]\n"
  set act word act "     move\n"
  set act word act "  ]"
 
  set Ant-Actions act

end


;;;;;;;;;;;;;;;;;;;;;
;;; Go procedures ;;;
;;;;;;;;;;;;;;;;;;;;;

to go

  if Trail [ask Turtle 0 [set pcolor 13]]

  if steps >= max-steps [stop]
  if food-eaten >= food-amount [stop]
  
  if not init-actions [
    let act Ant-Actions
    set act remove " " act
    if empty? act [stop]
    set actions (word "ask turtle 0 [\n " Ant-Actions " \n]") 
  ]
  
  set init-actions true
    
  run actions 

end



;;;;;;;;;;;;;;;;;;;;;
;;; ANT'S OPERATIONS ;;;
;;;;;;;;;;;;;;;;;;;;;

to move
  if steps < max-steps and food-eaten < food-amount [
    fd 1
    if food? [
      set pcolor 52
      set food? false
      set food-eaten food-eaten + 1
    ]
    set steps steps + 1   
    if Trail [set pcolor 13]
  ]
end

to turn-left
  if steps < max-steps and food-eaten < food-amount [
    lt 90
    set steps steps + 1
  ]
end

to turn-right
  if steps < max-steps and food-eaten < food-amount [
    rt 90
    set steps steps + 1
  ]
end

;ask turtle 0 [show food-ahead]
;ask turtle 0 [ifelse food-ahead [show "Food found!"] [show "No food"]] 
to-report food-ahead
  report [food?] of patch-ahead 1
end



@#$#@#$#@
GRAPHICS-WINDOW
341
10
767
457
-1
-1
13.0
1
10
1
1
1
0
1
1
1
0
31
-31
0
0
0
1
ticks

BUTTON
10
10
74
53
Setup
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

MONITOR
245
10
322
55
Food Eaten
food-eaten
17
1
11

MONITOR
170
10
227
55
Steps
steps
17
1
11

BUTTON
90
10
153
54
Go
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

INPUTBOX
10
110
325
455
Ant-Actions
ifelse food-ahead\n  [move]\n  [\n    turn-left\n    ifelse food-ahead\n      [move]\n      [turn-right]\n    turn-right\n    turn-left\n    turn-right\n    ifelse food-ahead\n      [move]\n      [turn-left]\n     move\n  ]
1
1
String

SLIDER
10
65
152
98
Max-Steps
Max-Steps
10
1000
650
10
1
NIL
HORIZONTAL

SWITCH
170
65
260
98
Trail
Trail
1
1
-1000

@#$#@#$#@
WHAT IS IT?
-----------
This application is a simulation of the "Santa Fe Ant Trail" which is a standard problem in the areas of Genetic Programming and Grammatical Evolution. The objective of this problem is to find a computer program to control an Artificial Ant, so that it can find all 89 pieces of food located on the grid.

With this model, the user can do the following things:
a. Write a set of actions (in the NetLogo programming language) and run them to observe the behaviour of the Artificial Ant.
b. Simulate, verify, and investigate the Santa Fe Ant Trail solutions of other related programs (for example, some Genetic Programming and Grammatical Evolution software packages).


HOW IT WORKS
------------
The Artificial Ant operates in a square 32x32 toroidal grid in the plane. The Ant starts in the upper left cell of the grid (0, 0) facing east. The Santa Fe Trail consists of 144 squares with 21 turns, and the 89 units of food are distributed non-uniformly along it. 

The Artificial Ant can use three operations: move, turn-right, turn-left. Each of these takes one time unit. Indeed, the Artificial Ant can use one sensing function: food-ahead. It looks into the square the Ant is currently facing and returns true or false depending upon whether that square contains food or is empty respectively.


HOW TO USE IT
-------------
Here are a few guidelines of how to use the simulation:

1. Set the model’s speed to normal (adjust the speed slider in the toolbar). This will let the setup procedure to redraw the path very quickly.

2. Press the “Setup” button to initialise the world. After that the Santa Fe Trail will appear in the 2D view. Indeed, the multi-line input box “Ant-Actions” is initialised with one of the Koza’s solutions (1992) of the Santa Fe Trail problem, written in the NetLogo programming language. These NetLogo commands are editable by you (the user) and will be executed by the Ant when you press “Go”. 

3. Set the “Max-Steps” slider to the limit of steps (time units) which are allowed to be executed by the Ant during the simulation. Don’t confuse these steps with the NetLogo’s discrete steps called “ticks”.

4. Turn-on the switch “Trail” if you want to colour the path of the Ant.

5. Set the model’s speed to very slow (adjust the speed slider in the toolbar) in order you can view the Ant’s movements. Otherwise, the Ant will run so fast you only see the results of the simulation.

6. The monitors “Steps” and “Food Eaten” display the current number of the executed actions and the pieces of food eaten by the Ant so far respectively. 

7. Press the button “Go” to start the simulation.


THINGS TO TRY
-------------
Many GP and GE packages provide implementations of the Artificial Ant (Santa Fe Trail) problem. Run them and get the solutions they found in order to verify them by simulating them in this model. Indeed, you can investigate the behaviour of the Ant during the simulation. 

Also, you can write manually your own possible solution to the Santa Fe Trail problem (using the NetLogo programming language) and test it in this model / simulation.


EXTENDING THE MODEL
-------------------
Try to change the code in order to load the Santa Fe Trail from an external text file. Then create different text files with other trails as well (e.g. John Muir trail) and let the user of the model to select the trail to be used in the simulation.


NETLOGO FEATURES
----------------
The built-in RUN primitive is used to execute the NetLogo code (Ant-Actions) which controls the behaviour of the Artificial Ant.


HOW TO CITE
------------
If you mention this model in an academic publication, we ask that you include these citations for the model itself and for the NetLogo software: 
- Georgiou, L. (2009). NetLogo Santa Fe Ant Trail model. http://www.bangor.ac.uk/~eep201/jge. School of Computer Science, Bangor University, Wales, GB. 
- Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use: 
- Georgiou, L. (2009). NetLogo Santa Fe Ant Trail model. http://www.bangor.ac.uk/~eep201/jge. School of Computer Science, Bangor University, Wales, GB. 
- Copyright 1997 Uri Wilensky. All rights reserved. See http://ccl.northwestern.edu/netlogo/models/Ants for terms of use.


CREDITS AND COPYRIGHT NOTICE
--------------------------
All contents (C) 2009 Loukas Georgiou.

Emails: loukas@informatics.bangor.ac.uk, eep201@bangor.ac.uk 
Web Site: http://www.bangor.ac.uk/~eep201

The Santa Fe Ant Trail model is free software: you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation, either version 3 of the License, or (at your option) any later version.

The Santa Fe Ant Trail model is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details.

You should have received a copy of the GNU General Public License along with the Santa Fe Ant Trail model. If not, see www.gnu.org/licenses.


REFERENCES
----------
KOZA, J.R. (1992) Genetic Programming: On the Programming of Computers by the Means of Natural Selection. Cambridge, MA: MIT Press.

WILENSKY, U. (1999) NetLogo. Evanston, IL: Center for Connected Learning and Computer-Based Modeling, Northwestern University. Available from http://ccl.northwestern.edu/netlogo.

@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@