globals
[
  StopYear ; the year when the simulation is stopped
  NoTurtles ; the number of turtles
  NoFemale ; the initial number of females
  NoMale ; the initial number of males
  Women ; the number of female turtles
  Men ;  the number of male turtles
  MaxVision ; maximum possible vision for turtles
  LifeExpectancyMax ; maximum life expectancy
  LifeExpectancyMin ; minimum life expectancy
  AgeSexualActive ; the age when the sexual life starts
  MinWealthToBuy ; the minimum quantity of resources when a turtle start to buy resources
  MinWealthToSell ; the minimum quantity of resources when a turtle start to sell resources
  MeanGlobalWealth ; the mean of global wealth
  AbsoluteGlobalWealth ; the absolute value of global wealth
  MeanGlobalTrade ; the mean global trade
  MeanGlobalPurchase ; the mean global value of purchased resources
  MeanGlobalSold ; the mean global sold resources
  MeanWealthWater ; the average wealth in water
  MeanWealthFood ; the average wealth in food
  MeanWealthEnergy ; the average wealth in energy
  MeanTradeWater ; the average trade in water
  MeanTradeFood ; the average trade in food
  MeanTradeEnergy ; the average trade in energy
  MeanWaterPurchase ; the average value of purchased water
  MeanFoodPurchase ; the average value of purchased food
  MeanEnergyPurchase ; the average value of purchased energy
  MeanWaterSold ; the average value of sold water
  MeanFoodSold ; the average value of sold food
  MeanEnergySold ; the average value of sold energy 
  AvgVisionLow ; the average vision of low class
  AvgVisionMedium ; the average vision of medium class
  AvgVisionHigh ; the average vision of high class
  WealthLow ; the wealth of low class
  WealthMedium ; the wealth of medium class
  WealthHigh ; the wealth of high class
  TradeLow ; the trade of low class
  TradeMedium ; the trade of medium class
  TradeHigh ; the trade of high class
  PurchaseLow ; the purchased energy of low class
  PurchaseMedium ; the purchased energy of medium class
  PurchaseHigh ; the purchased energy of high class
  SoldLow ; the sold energy of low class
  SoldMedium ; the sold energy of medium class
  SoldHigh ; the sold energy of highclass
  Low ; the number of low class people
  Medium ; the number of medium class people
  High ; the number of high class people
]

patches-own
[
  TypePatch ; the type of patch
  ResFood ; keeps the value of food resources
  ResEnergy ; keeps the value of energy resources
  ResWater ; keeps the value of water resources
]  

turtles-own
[
  IdMother ; keeps the identification number of the mother 
  IdFather ; keeps the identification number of the father
  Age ; age in years for every turtle
  LifeExpectancy ; maximum age that a turtle can reach
  Vision ; how many patches ahead a turtle can see
  WomanEngaged? ; used to prevent two males from engaging the same female
  IdHusband ; the identification number of the husband
  ManEngaged? ; used to prevent two females from engaging the same male
  IdWife ; the identification number of the wife
  WealthFood ; the quantity of food owned
  WealthEnergy ; the quantity of energy owned
  WealthWater ; the quantity of water owned
  GlobalWealth ; the global wealth
  WaterTraded ; the amount of traded water
  FoodTraded ; the amount of traded food
  EnergyTraded ; the amount of traded energy
  WaterPurchase ; the amount of purchased water
  FoodPurchase ; the amount of purchased food
  EnergyPurchase ; the amount of purchased energy
  GlobalPurchase ; the global amount of purchased resources
  WaterSold ; the amount of sold water
  FoodSold ; the amount of sold food
  EnergySold ; the amount of sold energy
  GlobalSold ; the global amount of sold resources
  GlobalTrade; the amount of global trade
  Pregnant? ; has two possible values false for non pregnant woman and true otherwise
  PregnancyDuration ; the value of pregnancy duration
  SocialClass       ; the value of social class: low, middle and high
  TurtleMinWealthToBuy ; the minimum wealth when a turtle starts to buy resources
  TurtleMinWealthToSell ; the minimum wealth when a turtle starts to sell resources
]

to Setup
  ca
  set StopYear 1000
  set NoFemale 5
  set NoMale 5
  set MaxVision 15
  set LifeExpectancyMax 80
  set LifeExpectancyMin 30
  set AgeSexualActive 20
  set MinWealthToBuy 10
  set MinWealthToSell 100
  random-seed rs ;; sets the random seed to a certain value in order that computational experiments to be reproductible
  PatchesCreation
  TurtlesCreation
  UpdateSocialClass
  set NoTurtles count turtles
  set Women count turtles with [shape = "woman"]
  set Men count turtles with [shape = "man"]
  set MeanWealthWater mean [WealthWater] of turtles
  set MeanWealthFood mean [WealthFood] of turtles
  set MeanWealthEnergy mean [WealthEnergy] of turtles
  set MeanGlobalWealth mean [GlobalWealth] of turtles
end

to Go
  tick
  if ticks mod (Interval) = 0 
    [if Renewable [GrowResource]]
  if count turtles = 0 [ stop]
  ask turtles
    [FindResources 
     EatDrinkWarmAgeDie]
  ask turtles with [shape = "man"]
    [if (ManEngaged? = false and Age >= AgeSexualActive) [ FindWomen ]]
  ask turtles with [shape = "man" and ManEngaged? = true] [DoSex]
  if Trade
   [ask turtles with [WealthWater <= TurtleMinWealthToBuy] [TradeWater]
    ask turtles with [WealthFood <= TurtleMinWealthToBuy] [TradeFood]
    ask turtles with [WealthEnergy <= TurtleMinWealthToBuy] [TradeEnergy]]
  UpdateSocialClass
  if-else count turtles != 0
   [set NoTurtles count turtles
    set MeanWealthWater mean [WealthWater] of turtles
    set MeanWealthFood mean [WealthFood] of turtles
    set MeanWealthEnergy mean [WealthEnergy] of turtles
    set MeanGlobalWealth mean [GlobalWealth] of turtles
    set MeanTradeWater mean [WaterTraded] of turtles
    set MeanTradeFood mean [FoodTraded] of turtles
    set MeanTradeEnergy mean [EnergyTraded] of turtles
    set MeanGlobalTrade mean [GlobalTrade] of turtles
    set Women count turtles with [shape = "woman"]
    set Men count turtles with [shape = "man"]]
   [stop]
  if ticks = StopYear [stop]
end

to PatchesCreation
     ask patches 
     [let Prob 0
      set Prob random 3 
      if (Prob = 0) 
       [set TypePatch "food" 
        set ResFood (1 + random 10) 
        set ResEnergy 0 
        set ResWater 0]
      if (Prob = 1) 
       [set TypePatch "energy" 
        set ResFood 0 
        set ResEnergy (1 + random 10) 
        set ResWater 0]
      if (Prob = 2) 
       [set TypePatch "water" 
        set ResFood 0 
        set ResEnergy 0 
        set ResWater (1 + random 10)]]
   if (count patches with [TypePatch = "water"] = 0)
     or (count patches with [TypePatch = "food"] = 0)
     or (count patches with [TypePatch = "energy"] = 0) 
       [PatchesCreation] 
  ask patches 
   [RecolorPatch]
end

to TurtlesCreation
  crt NoFemale 
    [set shape "woman"
     set IdMother false
     set IdFather false
     set Age 20
     set WomanEngaged? false
     set IdHusband false
     set WealthFood 10
     set WealthEnergy 10
     set WealthWater 10
     set GlobalWealth WealthFood + WealthEnergy + WealthWater
     set LifeExpectancy 1 + LifeExpectancyMin + random (LifeExpectancyMax - LifeExpectancyMin)
     set Vision 1 + random MaxVision
     set TurtleMinWealthToBuy 1 + random MinWealthToBuy
     set TurtleMinWealthToSell 1 + random MinWealthToSell
     set size 1
     set Pregnant? false
     set PregnancyDuration false
     setxy random-xcor random-ycor ]
  crt NoMale 
    [set IdMother false
     set IdFather false
     set shape "man"
     set Age 20
     set ManEngaged? false
     set IdWife false
     set WealthFood 10
     set WealthEnergy 10
     set WealthWater 10
     set GlobalWealth WealthFood + WealthEnergy + WealthWater
     set LifeExpectancy 1 + LifeExpectancyMin + random (LifeExpectancyMax - LifeExpectancyMin)
     set color red
     set size 1
     set Vision 1 + random MaxVision
     set TurtleMinWealthToBuy 1 + random MinWealthToBuy
     set TurtleMinWealthToSell 1 + random MinWealthToSell
     setxy random-xcor random-ycor]
end

to FindResources
  let Resource 0
  set heading random 360
  repeat Vision 
   [fd 1
    set Resource ResFood / count turtles-here
    set WealthFood WealthFood + Resource
    set ResFood ResFood - Resource
    set Resource ResEnergy / count turtles-here
    set WealthEnergy WealthEnergy + Resource
    set ResEnergy ResEnergy - Resource
    set Resource ResWater / count turtles-here
    set WealthWater WealthWater + Resource
    set ResWater ResWater - Resource
    RecolorPatch]
end

to FindWomen
  let Engage one-of turtles with 
   [shape = "woman" and WomanEngaged? = false and Age >= AgeSexualActive]
  if Engage != nobody                             
   [set [WomanEngaged?] of Engage true
    set ManEngaged? true
    set IdWife [who] of Engage
    set [IdHusband] of Engage who]   
end

to DoSex
  let Sex random 3
  if Sex = 1 or Sex = 2
    [let WhoMale who
     ask turtles with 
      [shape = "woman" 
       and IdHusband = WhoMale 
       and Pregnant? = false] 
      [set Pregnant? Sex 
       set PregnancyDuration 0]]
end

to GrowResource
  ask patches 
    [if (TypePatch = "food")
      [set ResFood (ResFood + 1 + random 10)]
     if (TypePatch = "energy")
      [set ResEnergy (ResEnergy + 1 + random 10)]
     if (TypePatch = "water")
       [set ResWater (ResWater + 1 + random 10)]]
end

to EatDrinkWarmAgeDie
  if-else WealthFood >= 1 
   [set WealthFood WealthFood - 1] 
   [InheritTurtle
    die]
  if-else WealthWater >= 1 
   [set WealthWater WealthWater - 1] 
   [InheritTurtle
    die]
  if-else WealthEnergy >= 1 
   [set WealthEnergy WealthEnergy - 1] 
   [InheritTurtle
    die]
  set Age Age + 1
  if shape = "woman" [if Pregnant? != false [Pregnancy]] 
  if Age >= LifeExpectancy 
   [InheritTurtle 
    die]
end

to InheritTurtle
  let InheritWater 0
  let InheritFood 0
  let InheritEnergy 0
  let NoInheriters CountInheritors who
  if NoInheriters > 0 
   [set InheritWater WealthWater / NoInheriters
    set InheritFood WealthFood / NoInheriters
    set InheritEnergy WealthFood / NoInheriters]
  let InheritAction false
  if NoInheriters > 0 
   [set InheritAction InheritOfTurtle who InheritWater InheritFood InheritEnergy]
  if-else InheritAction = true 
   []
   [let Water WealthWater
   let Food WealthFood
   let Energy WealthEnergy
   ask one-of patches with [TypePatch = "water"]
    [set ResWater ResWater + Water
     RecolorPatch]
   ask one-of patches with [TypePatch = "food"]
    [set ResFood ResFood + Food
     RecolorPatch]
   ask one-of patches with [TypePatch = "energy"]
    [set ResEnergy ResEnergy + Energy
     RecolorPatch]]
end

to-report CountInheritors [a]
  let total 0
  ask turtles with 
   [IdFather = a or IdMother = a]
   [if IdFather = a or IdMother = a 
    [set Total Total + 1
     ]]
  report Total
end

to-report InheritOfTurtle [a b c d]
  let Answer false
  ask turtles with [IdFather = a or IdMother = a] 
     [set WealthWater WealthWater + b
     set WealthFood WealthFood + c
     set WealthEnergy WealthEnergy + d
     set Answer true]
  report Answer
end

to Pregnancy
 set PregnancyDuration PregnancyDuration + 1
 if PregnancyDuration >= 1 
     [let Sex Pregnant?
      set Pregnant? false
      set PregnancyDuration false
      let Mother who
      let WealthFoodMother WealthFood
      let WealthEnergyMother WealthEnergy
      let WealthWaterMother WealthWater
      set WealthFood WealthFood * 9 / 10
      set WealthEnergy WealthEnergy * 9 / 10
      set WealthWater WealthWater * 9 / 10
      let VisionMother Vision
      let Father false
      let WealthFoodFather 0
      let WealthEnergyFather 0
      let WealthWaterFather 0
      let VisionFather 0
      ask turtles with [shape = "man" and IdWife = Mother] 
       [set Father who
        set WealthFoodFather WealthFood
        set WealthEnergyFather WealthEnergy
        set WealthWaterFather WealthWater
        set WealthFood WealthFood * 9 / 10
        set WealthEnergy WealthEnergy * 9 / 10
        set WealthWater WealthWater * 9 / 10
        set VisionFather Vision]
      if Sex = 1 
       [hatch 1 
         [set shape "woman"
         set size 1
         set IdMother Mother
         set IdFather Father
         set Age 0
         set WomanEngaged? false
         set IdHusband false
         set WealthFood (WealthFoodMother + WealthFoodFather) / 10
         set WealthEnergy (WealthEnergyMother + WealthEnergyFather) / 10
         set WealthWater (WealthWaterMother + WealthWaterFather) / 10
         set GlobalWealth WealthFood + WealthEnergy + WealthWater
         set LifeExpectancy 1 + LifeExpectancyMin + random (LifeExpectancyMax - LifeExpectancyMin)
         set TurtleMinWealthToBuy 1 + random MinWealthToBuy
         set TurtleMinWealthToSell 1 + random MinWealthToSell
         set WaterPurchase 0
         set FoodPurchase 0
         set EnergyPurchase 0
         set WaterSold 0
         set FoodSold 0
         set EnergySold 0
         set Vision 1 + random MaxVision
         set Pregnant? false
         set PregnancyDuration false]]
      if sex = 2 
       [hatch 1 
        [set shape "man"
         set size 1
         set IdMother Mother
         set IdFather Father
         set color red
         set Age 0
         set ManEngaged? false
         set IdWife false
         set WealthFood (WealthFoodMother + WealthFoodFather) / 10
         set WealthEnergy (WealthEnergyMother + WealthEnergyFather) / 10
         set WealthWater (WealthWaterMother + WealthWaterFather) / 10
         set GlobalWealth WealthFood + WealthEnergy + WealthWater
         set LifeExpectancy 1 + LifeExpectancyMin + random (LifeExpectancyMax - LifeExpectancyMin)
         set Vision 1 + random MaxVision
         set TurtleMinWealthToBuy 1 + random MinWealthToBuy
         set TurtleMinWealthToSell 1 + random MinWealthToSell
         set WaterPurchase 0
         set FoodPurchase 0
         set EnergyPurchase 0
         set WaterSold 0
         set FoodSold 0
         set EnergySold 0]]]
end

to RecolorPatch
  if (TypePatch = "food") 
   [set pcolor scale-color green ResFood 0 10]
  if (TypePatch = "water") 
   [set pcolor scale-color blue ResWater 0 10]
  if (TypePatch = "energy") 
   [set pcolor scale-color yellow ResEnergy 0 10]
end

to UpdateSocialClass
  if count turtles = 0 [stop]
  ask turtles
   [
    set GlobalWealth WealthFood + WealthEnergy + WealthWater
    set WaterTraded WaterPurchase + WaterSold
    set FoodTraded FoodPurchase + FoodSold
    set EnergyTraded EnergyPurchase + EnergySold
    set GlobalTrade WaterTraded + FoodTraded + EnergyTraded
    set GlobalPurchase WaterPurchase + FoodPurchase + EnergyPurchase
    set GlobalSold WaterSold + FoodSold + EnergySold
    ]
  set AbsoluteGlobalWealth sum [GlobalWealth] of turtles
  let MaxWealth max [GlobalWealth] of turtles
  ask turtles
   [ifelse (GlobalWealth <= MaxWealth / 3)
    [set SocialClass "low" ]
    [ifelse (GlobalWealth <= (MaxWealth * 2 / 3))
     [set SocialClass "medium" ]
     [set SocialClass "high"]]]
  set Low count turtles with [SocialClass = "low"]
  set Medium count turtles with [SocialClass = "medium"]
  set High count turtles with [SocialClass = "high"]
  if Low != 0 
   [set AvgVisionLow mean [vision] of turtles with [SocialClass = "low"]
    set WealthLow mean [GlobalWealth] of turtles with [SocialClass = "low"]
    set TradeLow mean [GlobalTrade] of turtles with [SocialClass = "low"]
    set PurchaseLow mean [GlobalPurchase] of turtles with [SocialClass = "low"]
    set SoldLow mean [GlobalSold] of turtles with [SocialClass = "low"]
    ]
  if Medium != 0
   [set AvgVisionMedium mean [vision] of turtles with [SocialClass = "medium"]
    set WealthMedium mean [GlobalWealth] of turtles with [SocialClass = "medium"]
    set TradeMedium mean [GlobalTrade] of turtles with [SocialClass = "medium"]
    set PurchaseMedium mean [GlobalPurchase] of turtles with [SocialClass = "medium"]
    set SoldMedium mean [GlobalSold] of turtles with [SocialClass = "medium"]]
  if High != 0
   [set AvgVisionHigh mean [vision] of turtles with [SocialClass = "high"]
    set WealthHigh mean [GlobalWealth] of turtles with [SocialClass = "high"]
    set TradeHigh mean [GlobalTrade] of turtles with [SocialClass = "high"]
    set PurchaseHigh mean [GlobalPurchase] of turtles with [SocialClass = "high"]
    set SoldHigh mean [GlobalSold] of turtles with [SocialClass = "high"]]
end

to TradeWater
 let Partner one-of turtles with 
   [WealthWater >= TurtleMinWealthToSell]
  if Partner != nobody                             
     [
      set WealthWater WealthWater + 1
      set WaterPurchase WaterPurchase + 1
      set [WealthWater] of Partner [WealthWater] of Partner - 1
      set [WaterSold] of Partner [WaterSold] of Partner + 1
     ]
end

to TradeFood
 let Partner one-of turtles with 
   [WealthFood >= TurtleMinWealthToSell]
  if Partner != nobody                             
     [
      set WealthFood WealthFood + 1
      set FoodPurchase FoodPurchase + 1
      set [WealthFood] of Partner [WealthFood] of Partner - 1
      set [FoodSold] of Partner [FoodSold] of Partner + 1
     ]
end

to TradeEnergy
 let Partner one-of turtles with 
   [WealthEnergy >= MinWealthToSell]
  if Partner != nobody                             
     [
      set WealthEnergy WealthEnergy + 1
      set EnergyPurchase EnergyPurchase + 1
      set [WealthEnergy] of Partner [WealthEnergy] of Partner - 1
      set [EnergySold] of Partner [EnergySold] of Partner + 1
     ]
end
@#$#@#$#@
GRAPHICS-WINDOW
585
10
931
377
10
10
16.0
1
10
1
1
1
0
1
1
1
-10
10
-10
10
0
0
1
ticks

CC-WINDOW
5
544
1065
639
Command Center
0

BUTTON
5
17
76
50
Setup
Setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
84
17
151
50
Go
Go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

MONITOR
531
478
618
523
Year
ticks
0
1
11

MONITOR
700
479
757
524
Women
Women
3
1
11

MONITOR
765
479
822
524
Men
Men
3
1
11

MONITOR
7
485
128
530
MeanWealthWater
MeanWealthWater
1
1
11

MONITOR
131
484
245
529
NIL
MeanWealthFood
1
1
11

MONITOR
251
481
379
526
NIL
MeanWealthEnergy
1
1
11

MONITOR
15
304
72
349
Low
Low
3
1
11

MONITOR
15
353
65
398
Medium
Medium
3
1
11

MONITOR
15
401
72
446
High
High
3
1
11

SLIDER
6
58
170
91
rs
rs
-2
2
-2
1
1
NIL
HORIZONTAL

SLIDER
4
105
162
138
Interval
Interval
1
10
1
1
1
NIL
HORIZONTAL

SWITCH
7
152
124
185
Renewable
Renewable
0
1
-1000

MONITOR
77
303
165
348
NIL
AvgVisionLow
1
1
11

MONITOR
72
353
180
398
NIL
AvgVisionMedium
1
1
11

MONITOR
75
401
165
446
NIL
AvgVisionHigh
1
1
11

MONITOR
827
479
940
524
NIL
MeanGlobalWealth
1
1
11

MONITOR
171
301
245
346
NIL
WealthLow
1
1
11

MONITOR
183
353
277
398
NIL
WealthMedium
1
1
11

MONITOR
170
401
247
446
NIL
WealthHigh
1
1
11

MONITOR
627
479
693
524
NIL
NoTurtles
0
1
11

MONITOR
947
477
1056
522
NIL
MeanGlobalTrade
1
1
11

MONITOR
260
304
327
349
NIL
TradeLow
1
1
11

MONITOR
288
354
375
399
NIL
TradeMedium
1
1
11

MONITOR
257
402
327
447
NIL
TradeHigh
1
1
11

SWITCH
7
196
110
229
Trade
Trade
0
1
-1000

MONITOR
391
479
525
524
NIL
AbsoluteGlobalWealth
1
1
11

MONITOR
340
304
426
349
NIL
PurchaseLow
1
1
11

MONITOR
381
354
486
399
NIL
PurchaseMedium
1
1
11

MONITOR
335
405
423
450
NIL
PurchaseHigh
1
1
11

MONITOR
440
305
498
350
NIL
SoldLow
1
1
11

MONITOR
491
354
569
399
NIL
SoldMedium
1
1
11

MONITOR
427
405
487
450
NIL
SoldHigh
1
1
11

@#$#@#$#@
WHAT IS IT?
-----------
This model describes a economy using three types of resources: water, food and energy. Inside this economy, there is an artificial society with the following characteristics:
(i) the turtles are of two types: female and male;
(ii) these turtles have a limited life expectancy determined by the parameters LifeExpectancyMax (maximum life expectancy) and LifeExpectancyMin (minimum life expectancy); 
(iii) the patches Pxy are of three types: type 1 that stores a certain amount of water, type 2 that stores a certain amount of food and type 3 that stores a certain amount of energy.
(iv) a male and female turtle can create a couple and a number of children; 
(v) the children can inherit the wealth of their parents;
(vi) the basic needs of every turtle are 1 unit of water, 1 unit of food and 1 unit of energy per one year;
(vii) if these basic needs are not fulfilled then the respective turtle dies;
(viii) if a turtle has an amount of wealth in water, food, and energy that exceeds a certain limit determined by the parameter TurtleMinWealthToBuy then it starts to buy resources from the other turtles that have an amount of resources that exceeds the value of the parameter TurtleMinWealthToSell. 

HOW IT WORKS
------------

The model has two buttons:
- <Setup> - that declare and setup parameters, initial variables, agents and patches
- <Go> - Start the simulation and stop the simulation when 1000 years passed or there are no agents
You can set the next sliders: 
- rs - that set the value of the random seed: -2, -1, 0, 1, 2;
- Interval - that set the value of resources growth interval: 1, 2, ..., 10;
and the next switchers:
- Renewable = {on, off} - has two possible values: off for nonrenewable resources and on for renewable resources;
- Trade = {on, off} - has two possible values: off when trade is not allowed between agents and on when trade is allowed.
In the interface tab, there are the next monitors:
- Low - the number of turtles from low class;
- Medium - the number of turtles from medium class;
- High - the number of turtles from high class;
- AvgVisionLow - the average vision for low class;
- AvgVisionMedium - the average vision for medium class;
- AvgVisionHigh - the average vision for high class;
- WealthLow - mean wealth in water;
- WealthMedium - mean wealth in food;
- WealthHigh - mean wealth in energy;
- TradeLow - the amount of traded resources by low class;
- TradeMedium - the amount of traded resources by medium class;
- TradeHigh - the amount of traded resources by high class;
- PurchaseLow - the amount of purchased resources by low class;
- PurchaseMedium - the amount of purchased resources by medium class;
- PurchaseHigh - the amount of purchased resources by high class;
- SoldLow - the amount of sold resources by low class;
- SoldMedium - the amount of sold resources by medium class;
- SoldHigh - the amount of sold resources by high class;
- MeanWealthWater - mean wealth in water;
- MeanWealthFood - mean wealth in food;
- MeanWealthEnergy - mean wealth in energy;
- AbsoluteGlobalWealth - the absolute value of global wealth (the cumulated value of water, food and energy resources);
- Year - the number of years
- NoTurtles - the number of turtles
- Women - the number of females;
- Men - the number of males;
- MeanGlobalWealth - mean global wealth;
- MeanGlobalTrade - mean global trade.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

factory
false
0
Rectangle -7500403 true true 76 194 285 270
Rectangle -7500403 true true 36 95 59 231
Rectangle -16777216 true false 90 210 270 240
Line -7500403 true 90 195 90 255
Line -7500403 true 120 195 120 255
Line -7500403 true 150 195 150 240
Line -7500403 true 180 195 180 255
Line -7500403 true 210 210 210 240
Line -7500403 true 240 210 240 240
Line -7500403 true 90 225 270 225
Circle -1 true false 37 73 32
Circle -1 true false 55 38 54
Circle -1 true false 96 21 42
Circle -1 true false 105 40 32
Circle -1 true false 129 19 42
Rectangle -7500403 true true 14 228 78 270

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

link
true
0
Line -7500403 true 150 0 150 300

link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

man
false
10
Polygon -7500403 true false 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Polygon -13345367 true true 60 195 90 210 114 154 120 195 180 195 187 157 210 210 240 195 195 90 165 90 150 105 150 150 135 90 105 90
Circle -7500403 true false 110 5 80
Rectangle -7500403 true false 127 79 172 94
Polygon -13345367 true true 120 90 120 180 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 180 90 172 89 165 135 135 135 127 90
Polygon -13345367 true true 116 4 113 21 71 33 71 40 109 48 117 34 144 27 180 26 188 36 224 23 222 14 178 16 167 0
Line -16777216 false 225 90 270 90
Line -16777216 false 225 15 225 90
Line -16777216 false 270 15 270 90
Line -16777216 false 247 15 247 90
Rectangle -6459832 true false 240 90 255 300

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

person business
true
0
Rectangle -1 true false 120 90 180 180
Polygon -16777216 true false 135 90 150 105 135 180 150 195 165 180 150 105 165 90
Polygon -7500403 true true 120 90 105 90 60 195 90 210 116 154 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 183 153 210 210 240 195 195 90 180 90 150 165
Circle -7500403 true true 110 5 80
Rectangle -7500403 true true 127 76 172 91
Line -16777216 false 172 90 161 94
Line -16777216 false 128 90 139 94
Polygon -7500403 true true 195 225 195 300 270 270 270 195
Rectangle -16777216 true false 180 225 195 300
Polygon -16777216 true false 180 226 195 226 270 196 255 196
Polygon -16777216 true false 209 202 209 216 244 202 243 188
Line -16777216 false 180 90 150 165
Line -16777216 false 120 90 150 165

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

woman
false
10
Polygon -7500403 true false 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Polygon -13345367 true true 60 195 90 210 114 154 120 195 180 195 187 157 210 210 240 195 195 90 165 90 165 105 150 165 135 90 105 90
Circle -7500403 true false 105 0 90
Rectangle -7500403 true false 127 79 172 94
Polygon -13345367 true true 120 90 120 180 120 195 90 285 105 300 135 300 150 300 165 300 195 300 210 285 180 195 180 90 172 89 165 165 135 165 127 90
Polygon -1184463 true false 116 4 113 21 75 90 135 90 120 45 135 15 150 15 180 26 180 90 240 90 210 45 195 15 167 0
Line -16777216 false 225 90 270 90
Line -16777216 false 225 15 225 90
Line -16777216 false 270 15 270 90
Line -16777216 false 247 15 247 90

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.0.5
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@