breed [deliverers human] ;one set of deliverers
breed [clients human] ; one set of clients

globals [
  work-days ; the number of "days", but will be represented by the number of times the model loops through the set of procedures.  ticks is represented in weeks.
  delivery-site-locations; an initial set of potential locations where RESPECT will be delivered. (10 total, locations fixed for all runs)
  available-position ; the actual set of locations where RESPECT will be delivered based on the number positions specified in the input

  ;variables to relevant to clients
  client-count ; the number of clients in the simulation
  RESPECT2-count; the number of clients that have received both session of RESPECT
  RESPECT1-count; the number of clients that have received the first session of RESPECT
  total-lost; the number of clients that have been lost to follow up

 ;variables relevant to deliverers
  deliverer-count;cumulative # of individuals hired
  deliverer-trained; cumulative # of individuals that leave
  deliverer-turnover; cumulative # of individuals that leave

  ;;;risk summary output;;
  total-risk-achieved; the number of clients that acheive their risk reduction step
  total-risk-decay; the number of clients that experience behavior decay
  risk-mean ; average risk for the population
  risk-max ; highest risk value in the populations
  risk-min ; lowest risk value in the population
  risk-median ; median risk value in the population
  risk-0 ; number of indiviuals with a risk value <=1
  risk-1 ; number of individuals with a risk value >1 and =2
  risk-2 ; number of individuals with a risk value >2 and =3
  risk-3 ; number of individuals with a risk value >3 and =4
  risk-4 ; number of individuals with a risk value >4 and =5
  risk-5 ; number of individuals with a risk value >5 and =6
  risk-6 ; number of individuals with a risk value >6 and =7
  ]

; variables specific to each individual client in the population
clients-own [ ; eventually these will be variables for each of the clients.  These are outcome variables that were tracked as part of the original RESPECT RCT.
  infected? ; HIV infection
  risk; the level of risk that the individuals have
  session-one? ; receiving the initial session
  session-two? ; if the person will return for the second session of the program
  lost?; if the person is lost to follow up
  risk-achieved?
  risk-decay? ; if the person has experienced risk decay after receiving RESPECT
]

;variables specific to each individual deliverer in the model
deliverers-own [
  age
  trained?]

patches-own [
  available?
  empty-time]; variable that will count the number of delivery sites that do not have capacity

;-----setup procedures-------;

to setup
  clear-all
  setup-globals ; sets up all global variables
  setup-deliverysites ; sets up the locations for RESPECT delivery
  setup-people ; procedure that creates the client population  and "shapes them"
  set client-count (count clients) ; creates a variable that keeps track of the number of potential clients
  set RESPECT2-count (count clients with [session-two? = true]) ; creates a variable that keeps track of the number of clients that have received both session of RESPECT.
  set RESPECT1-count (count clients with [session-one? = true]) ; creates a varible that keeps track of the number of clients that have received the first sesion of RESPECT.
  set total-lost (count clients with [lost? = true])
  setup-clientsown; procedure that randomly assigns infection and risk among the number of clients
  setup-deliverersown; procedure that sets up variables for deliverers
  set total-risk-achieved 0
  set total-risk-decay 0
  set deliverer-count (count deliverers)
  set deliverer-trained 0
  set deliverer-turnover 0
  reset-ticks; sets the time at zero
  if save-output? = true [update-output print-output]
end

to go
  if not any? clients with [session-two? = false] or ticks = 500 [stop]; stops the model from running if every client has received both sessions of RESPECT
  ;if ticks = 50 [stop]

  ifelse work-days = 15 [ ; procedure for moving clients to the RESPECT sites and loops through the procedures 6 times. I did this because the counselors report -->
    set work-days 0 ; that they see on average 6 clients a week.
    update-deliverer-capacity
    behavior-decay
    tick
    if save-output? = true and remainder ticks 50 = 0 [
    update-output
    print-output]]; represents a week
  [recruit
  deliver-RESPECT ; procedure for receiving the intervention and tracking deliverer delivery
  returntopop ; procedure for moving clients back into the population
  set work-days (work-days + 1)
  ]; counts the number of work days that have past.
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;all of the set up procedures are listed below;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to setup-globals
    set delivery-site-locations (patch-set
      patch -13 -10 patch -10 -10 patch -7 -10 patch -4 -10 patch -1 -10 patch 2 -10 patch 5 -10 patch 8 -10 patch 11 -10 patch 14 -10
      patch -13 -13 patch -10 -13 patch -7 -13 patch -4 -13 patch -1 -13 patch 2 -13 patch 5 -13 patch 8 -13 patch 11 -13 patch 14 -13); locations where the deliverers and clients will move for RESPECT delivery
    ;ask delivery-site-locations [set pcolor blue]
    set work-days 0

end

to setup-deliverysites ; to set up the delivery site locations.
ask patches ; Set up the paches own variables
[set empty-time 0
  set available? false]
ask n-of positions delivery-site-locations ; ask patches in the patch set defined as delivery-site locations to set available true based on the number of positions specifcied in the input
[set available? true] ;
set available-position (patch-set patches with [available?] ) ; create a new patch set based on the patches with this true variable.
end

to setup-people
  create-clients initial-clients ; set up an initial number of clients based on initial-clients slider in the interface
   ask clients [setxy random-xcor random-float max-pycor ; set all of the population characteristics
    set shape "person"
    set heading 180
    ]
   create-deliverers positions ; set up an initial number of clients based on an initial deliverer-num slider in the interface
   ask deliverers [    ; set all of the deliverer characteristics
    set shape "person service"
    set heading 0
    move-to one-of available-position while [any? other turtles-here] [move-to one-of available-position]] ; move to one of the available positions defined above

end

to setup-clientsown ; set up client characteristics
  ask clients[
    set infected? (who < client-count * infection-rate) ; number of clients are assinged an infection based on the initial infection rate; infection rate is on a slider
    set risk random-poisson initial-risk ; sets a risk level for an individual by randomly selecting a number from a poisson distribution with the mean as a slider in the interface (is infected? unrelated to risk? Shouldn't infection be related to risk?)
    if risk > 7 [set risk 7] ; if by chance the indivdiual has a risk higher than seven, the it is reassigned a 7 to create a cap.
    if risk < 0 [set risk 0]
    ifelse infected? [set color yellow] [set color blue] ; if the person is HIV+, set their color as yellow
    set session-one? false ; all clients start without having the 1st session of RESPECT
    set session-two? false ; all clients start without having the 2nd session of RESPECT
    set lost? false
    set risk-achieved? false ; all clients start without having achieved their risk reduction step
    set risk-decay? false ; no clients start with having experience risk decay
  ]
end

to setup-deliverersown ; set up deliverer characteristics
  ask deliverers[    ; all deliverers start at an age of 0 and without training
    set age 0
    set trained? false
  ]
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;ALL go procedures are listed below;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;to recruit procedure starts by asking clients that have received session 1 to return for their follow up appointment. Then fill the remaining spaces new clients
to recruit
  ask clients with [session-one? = true and session-two? = false and lost? = false] ;recruit session 1 peeps that haven't had the second session yet.
  [if random-number < .90 and available-sites > 0 ;number of clients sites and emptysites based on the number of followup clients that counselors report per week; set so that there is about 89% loss to follow up after a year.
    [move-to one-of available-position while [any? other clients-here] [move-to one-of available-position]] ; move to a delivery site
  ]

ask clients with [session-one? = false] ; recruit new clients
    [if random-number < .001 and available-sites > 0 ; pick however many clients and then move them.
    [move-to one-of available-position while [any? other clients-here] [move-to one-of available-position]]] ; move to a delivery site
end

 to-report random-number ; random number reporter used to select followup and new clients from the population; also used to decrease risk among clients below
   report (random-float 1)
 end

 to-report available-sites ; reported to count the number of client delivery sites that are empty and "available"; used to determine capacity to deliver RESPECT to clients
   report (count available-position with [not any? clients-here and any? deliverers-here with [trained?]])
 end

to-report trained-deliverers
  report (count deliverers with [trained? = true])
end


; to deliver-RESPECT procedure simulates a client "receiving the RESPECT intervention. It starts by changing the RESPECT variables from false to true
; i.e., if session one is false, change to true, if session one is true, the change session one to false)
to deliver-RESPECT
  ask clients-on available-position
  [ifelse session-one? ;
    [set session-two? true] ; if session one is true, set session two true
    [
     set session-one? true ; otherwise, set session one true, and assign .89 lost to follow up
     if random-number > .85
     [set lost? true]
     ]]
  ask clients-on available-position; increases the likelihood that someone will reduce their risk.
  [ifelse session-two? and random-number > .28 [
      set risk (risk - (random-normal 1 .5)) ;
      set risk-achieved? true
      set total-risk-achieved (total-risk-achieved + 1)] []
    if risk > 7 [set risk 7] ; if by chance the indivdiual has a risk higher than seven, the it is reassigned a 7 to create a cap.
    if risk < 0 [set risk 0]] ; This is supposed to simulate the risk reduction step --> 70% of individuals will successfully reduce their risk. (Risk will be reduced by subtracting .5. Could this lead to negative risk, or is there a check elsewhere to prevent values from falling below 0? Multiplying risk by some fraction would be a way to avoid negative values.)
end

to returntopop ;ask clients to move back into the general population
  ask clients-on available-position [
    setxy random-xcor random-float max-pycor]
end

;procedure that simulates deliverer "capacity" by incoporating training for deliverers if they've been at a site for
; a certain amount of time and turnover among deliverers that have been there for at least two years.

to update-deliverer-capacity ; procedure for updating the capacity to deliver RESPECT at the end of the work week
  ask deliverers ; updates variables for deliverers, increases age for every week worked
  [ set age (age + 1)
    if age = training-delay
    [set trained? true
    set deliverer-trained (deliverer-trained + 1)  ] ;  after four weeks the deliverer becomes trained.
    if random-number < turnover-rate [ ; over a period of time the counselor will turnover
      set deliverer-turnover (deliverer-turnover + 1)
      die
      ]  ;set deliverer-turnover (
     ]

  ask available-position ; creates new deliverers after empty spaces have been vacant for a period of time.
  [if not any? deliverers-here [set empty-time (empty-time + 1)]
   if empty-time > 4 [sprout-deliverers 1 [
       set age 0
       set trained? false
       set shape "person service"
       set heading 0]
   set deliverer-count (deliverer-count + 1)]
   if empty-time > 4 [set empty-time 0]]

 end

to behavior-decay ; this procedure randomly selects indivdiuals to loose their risk reduction behavior according RESPECT RCT.
  ask clients with [session-two? = true and risk-achieved? = true and risk-decay? = false]
  [if random-number < risk-decay
    [set risk (risk + (random-normal 1 .5))
     set risk-decay? true
     set total-risk-decay (total-risk-decay + 1)] ; The risk-decay value is high enough in this default that the net result is that people who receive RESPECT are more likely than those who don't to increase their risk.
  if risk > 7 [set risk 7] ; if by chance the indivdiual has a risk higher than seven, the it is reassigned a 7 to create a cap.
  if risk < 0 [set risk 0]] ; (why is this here? risk is going up rather than down - the danger would be of risk > 7, right? Just trying to understand the reasoning.)
end

to update-output
  set RESPECT2-count (count clients with [session-two? = true]) ; creates a variable that keeps track of the number of clients that have received both session of RESPECT.
  set RESPECT1-count (count clients with [session-one? = true]) ; creates a varible that keeps track of the number of clients that have received the first sesion of RESPECT.
  set total-lost (count clients with [lost? = true]); creates a variable that keeps track of the number of clients that have been lost to follow up
  set risk-mean mean [risk] of clients ; average risk for the population
  set risk-max max [risk] of clients; highest risk value in the populations
  set risk-min min [risk] of clients ; lowest risk value in the population
  set risk-median median [risk] of clients ; median risk value in the population
  set risk-0 count clients with [risk <= 1]; number of indiviuals with a risk value <= 1
  set risk-1 count clients with [risk > 1 and risk <= 2]; number of individuals with a risk value >1 and =2
  set risk-2 count clients with [risk > 2 and risk <= 3]; number of individuals with a risk value >2 and =3
  set risk-3 count clients with [risk > 3 and risk <= 4]; number of individuals with a risk value >3 and =4
  set risk-4 count clients with [risk > 4 and risk <= 5]; number of individuals with a risk value >4 and =5
  set risk-5 count clients with [risk > 5 and risk <= 6]; number of individuals with a risk value >5 and =6
  set risk-6 count clients with [risk > 6]; number of individuals with a risk value >6
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;------output procedures------;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to print-map
 set-current-directory directory
 if save-map? [export-view (word "map" filename "(" experiment ")(" run-num ").png")]
end

;to setup-output ; setting up a .csv file
  ;file-open (word directory filename "(" experiment ")(" run-num ").csv") ;
  ;file-type (word "start parameters, run-num, filename, experiment, infection-rate, initial-clients, initial-risk, risk-decay,") ; general parameters
  ;file-type (word "independent variables, time, positions, turnover-rate, training-delay,") ; independent variables
  ;file-type (word "monitors, deliverer-count, deliverer-trained, deliverer-turnover, available-sites,"); variables for monitoring, calibration, and validation purposes
  ;file-type (word "dependent variables, session1, session2, lost-to-followup, total-risk-achieved, total-risk-decay, risk-mean, risk-max, risk-min, risk-median, risk-0, risk-1, risk-2, risk-3, risk-4, risk-5, risk-6, ") ;; dependent variables
  ;file-print ""
 ;file-close
;end

to print-output ; setting up a .csv file
  file-open (word directory filename "(" experiment ")(" run-num ").csv")
  file-type (word "," run-num "," filename "," experiment "," infection-rate "," initial-clients "," initial-risk "," risk-decay ",") ; general parameters
  file-type (word "," ticks "," positions "," turnover-rate "," training-delay "," ); independent variables
  file-type (word "," deliverer-count "," deliverer-trained "," deliverer-turnover "," available-sites ",") ; variables for monitoring, calibration, and validation purposes
  file-type (word "," RESPECT1-count "," RESPECT2-count "," total-lost "," total-risk-achieved "," total-risk-decay "," risk-mean "," risk-max "," risk-min "," risk-median "," risk-0 "," risk-1 "," risk-2 "," risk-3 "," risk-4 "," risk-5 "," risk-6 ", ") ;; dependent variables
  file-print "" ; creates a hard return in the csv file
  file-close
end
@#$#@#$#@
GRAPHICS-WINDOW
698
20
1200
543
15
15
15.9
1
10
1
1
1
0
1
1
1
-15
15
-15
15
1
1
1
ticks
30.0

BUTTON
18
11
84
44
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
103
10
166
43
NIL
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
16
71
188
104
infection-rate
infection-rate
0
.5
0.12
.01
1
NIL
HORIZONTAL

MONITOR
95
186
167
231
Session 1
count clients with [session-one? = true]
17
1
11

MONITOR
19
186
92
231
Time
ticks
17
1
11

BUTTON
201
11
296
44
run model
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

MONITOR
171
185
243
230
Session 2
count clients with [session-two? = true]
17
1
11

PLOT
15
302
277
503
RESPECT Sessions
Time
People
0.0
10.0
0.0
10.0
true
false
"" ""
PENS
"pen-2" 1.0 0 -13345367 true "" "plot count clients with [session-one? = true]"
"pen-3" 1.0 0 -1184463 true "" "plot count clients with [session-two? = true]"

SLIDER
15
116
190
149
initial-clients
initial-clients
5000
25000
5000
1000
1
NIL
HORIZONTAL

MONITOR
482
185
584
230
NIL
available-sites
17
1
11

TEXTBOX
24
158
174
176
Output \n
11
0.0
0

TEXTBOX
22
507
172
525
Saving Output
11
0.0
1

INPUTBOX
17
527
577
601
directory
/Users/virginiamckay/Documents/Dissertation/Analyses/Netlogo models/Output/
1
0
String

INPUTBOX
21
604
150
664
filename
RESPECT.9.15.15
1
0
String

INPUTBOX
158
604
246
664
experiment
incremental conditions10.16.16
1
0
String

SWITCH
330
604
450
637
save-map?
save-map?
1
1
-1000

INPUTBOX
250
604
324
664
run-num
1
1
0
String

SLIDER
197
70
369
103
initial-risk
initial-risk
1
5
2.5
.1
1
NIL
HORIZONTAL

SWITCH
330
639
449
672
save-output?
save-output?
0
1
-1000

TEXTBOX
20
50
170
68
Initial Conditions\n
11
0.0
1

TEXTBOX
390
44
540
62
IVs
11
0.0
1

SLIDER
387
103
559
136
turnover-rate
turnover-rate
0
.025
0.008
.001
1
NIL
HORIZONTAL

SLIDER
387
143
559
176
training-delay
training-delay
2
6
6
1
1
NIL
HORIZONTAL

INPUTBOX
417
39
489
99
positions
10
1
0
Number

SLIDER
198
116
370
149
risk-decay
risk-decay
0
.01
0.0028
.001
1
NIL
HORIZONTAL

PLOT
284
303
578
503
Risk Histogram
NIL
NIL
0.0
10.0
0.0
4000.0
false
false
"set-plot-pen-interval 1" ""
PENS
"default" 1.0 1 -16777216 true "" "histogram [risk] of clients"

MONITOR
402
186
477
231
risk decay
total-risk-decay
17
1
11

MONITOR
18
241
113
286
NIL
deliverer-count
17
1
11

MONITOR
116
240
214
285
NIL
deliverer-trained
17
1
11

MONITOR
222
242
337
287
NIL
deliverer-turnover
17
1
11

MONITOR
246
184
303
229
Lost
count clients with [lost? = true]
17
1
11

MONITOR
304
185
398
230
risk achieved
count clients with [risk-achieved? = true]
17
1
11

PLOT
598
553
798
703
plot 1
NIL
NIL
0.0
500.0
1.0
4.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" "plot mean [risk] of clients"

@#$#@#$#@
## WHAT IS IT?

(a general understanding of what the model is trying to show or explain)

## HOW IT WORKS

(what rules the agents use to create the overall behavior of the model)

## HOW TO USE IT

(how to use the model, including a description of each of the items in the Interface tab)

## THINGS TO NOTICE

(suggested things for the user to notice while running the model)

## THINGS TO TRY

(suggested things for the user to try to do (move sliders, switches, etc.) with the model)

## EXTENDING THE MODEL

(suggested things to add or change in the Code tab to make the model more complicated, detailed, accurate, etc.)

## NETLOGO FEATURES

(interesting or unusual features of NetLogo that the model uses, particularly in the Code tab; or where workarounds were needed for missing features)

## RELATED MODELS

(models in the NetLogo Models Library and elsewhere which are of related interest)

## CREDITS AND REFERENCES

(a reference to the model's URL on the web if it has one, as well as any other necessary credits, citations, and links)
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

person service
false
0
Polygon -7500403 true true 180 195 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285
Polygon -1 true false 120 90 105 90 60 195 90 210 120 150 120 195 180 195 180 150 210 210 240 195 195 90 180 90 165 105 150 165 135 105 120 90
Polygon -1 true false 123 90 149 141 177 90
Rectangle -7500403 true true 123 76 176 92
Circle -7500403 true true 110 5 80
Line -13345367 false 121 90 194 90
Line -16777216 false 148 143 150 196
Rectangle -16777216 true false 116 186 182 198
Circle -1 true false 152 143 9
Circle -1 true false 152 166 9
Rectangle -16777216 true false 179 164 183 186
Polygon -2674135 true false 180 90 195 90 183 160 180 195 150 195 150 135 180 90
Polygon -2674135 true false 120 90 105 90 114 161 120 195 150 195 150 135 120 90
Polygon -2674135 true false 155 91 128 77 128 101
Rectangle -16777216 true false 118 129 141 140
Polygon -2674135 true false 145 91 172 77 172 101

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
15
Circle -1 true true 203 65 88
Circle -1 true true 70 65 162
Circle -1 true true 150 105 120
Polygon -7500403 true false 218 120 240 165 255 165 278 120
Circle -7500403 true false 214 72 67
Rectangle -1 true true 164 223 179 298
Polygon -1 true true 45 285 30 285 30 240 15 195 45 210
Circle -1 true true 3 83 150
Rectangle -1 true true 65 221 80 296
Polygon -1 true true 195 285 210 285 210 240 240 210 195 210
Polygon -7500403 true false 276 85 285 105 302 99 294 83
Polygon -7500403 true false 219 85 210 105 193 99 201 83

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

wolf
false
0
Polygon -16777216 true false 253 133 245 131 245 133
Polygon -7500403 true true 2 194 13 197 30 191 38 193 38 205 20 226 20 257 27 265 38 266 40 260 31 253 31 230 60 206 68 198 75 209 66 228 65 243 82 261 84 268 100 267 103 261 77 239 79 231 100 207 98 196 119 201 143 202 160 195 166 210 172 213 173 238 167 251 160 248 154 265 169 264 178 247 186 240 198 260 200 271 217 271 219 262 207 258 195 230 192 198 210 184 227 164 242 144 259 145 284 151 277 141 293 140 299 134 297 127 273 119 270 105
Polygon -7500403 true true -1 195 14 180 36 166 40 153 53 140 82 131 134 133 159 126 188 115 227 108 236 102 238 98 268 86 269 92 281 87 269 103 269 113

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.3.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
<experiments>
  <experiment name="experiment (average conditions)" repetitions="10" runMetricsEveryStep="false">
    <setup>setup</setup>
    <go>go</go>
    <metric>mean [risk] of clients</metric>
    <metric>ticks</metric>
    <enumeratedValueSet variable="risk-decay">
      <value value="0.0028"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="run-num">
      <value value="&quot;&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="turnover-rate">
      <value value="0.001"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initial-clients">
      <value value="15000"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="save-output?">
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="experiment">
      <value value="&quot;average conditions&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="directory">
      <value value="&quot;/Users/virginiamckay/Documents/Dissertation/Analyses/Netlogo models/Output/Average run/&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="positions">
      <value value="10"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initial-risk">
      <value value="1.5"/>
      <value value="2.5"/>
      <value value="3.5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="infection-rate">
      <value value="0.12"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="training-delay">
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="save-map?">
      <value value="false"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="filename">
      <value value="&quot;RESPECT.9.15.15 &quot;"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="experiment (incremental conditions)" repetitions="10" runMetricsEveryStep="false">
    <setup>setup</setup>
    <go>go</go>
    <metric>mean [risk] of clients</metric>
    <metric>ticks</metric>
    <enumeratedValueSet variable="risk-decay">
      <value value="0.0028"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="run-num">
      <value value="&quot;1&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="turnover-rate">
      <value value="0.001"/>
      <value value="0.002"/>
      <value value="0.004"/>
      <value value="0.005"/>
      <value value="0.008"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initial-clients">
      <value value="15000"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="save-output?">
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="experiment">
      <value value="&quot;incremental conditions&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="directory">
      <value value="&quot;/Users/virginiamckay/Documents/Dissertation/Analyses/Netlogo models/Output/&quot;"/>
    </enumeratedValueSet>
    <steppedValueSet variable="positions" first="5" step="2" last="15"/>
    <steppedValueSet variable="initial-risk" first="1.5" step="0.5" last="3.5"/>
    <enumeratedValueSet variable="infection-rate">
      <value value="0.12"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="training-delay">
      <value value="2"/>
      <value value="4"/>
      <value value="6"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="save-map?">
      <value value="false"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="filename">
      <value value="&quot;RESPECT.9.15.15 &quot;"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="experiment (average conditions10.10.15)" repetitions="10" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <metric>ticks</metric>
    <metric>initial-risk</metric>
    <metric>mean [risk] of clients</metric>
    <enumeratedValueSet variable="risk-decay">
      <value value="0.0028"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="run-num">
      <value value="&quot;&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="turnover-rate">
      <value value="0.001"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initial-clients">
      <value value="10000"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="save-output?">
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="experiment">
      <value value="&quot;average conditions&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="directory">
      <value value="&quot;/Users/virginiamckay/Documents/Dissertation/Analyses/Netlogo models/Output/Average run/&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="positions">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initial-risk">
      <value value="1.5"/>
      <value value="2.5"/>
      <value value="3.5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="infection-rate">
      <value value="0.12"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="training-delay">
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="save-map?">
      <value value="false"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="filename">
      <value value="&quot;RESPECT.10.10.15 &quot;"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="experiment (incremental conditions10.10.15)" repetitions="10" runMetricsEveryStep="false">
    <setup>setup</setup>
    <go>go</go>
    <metric>ticks</metric>
    <metric>mean [risk] of clients</metric>
    <enumeratedValueSet variable="risk-decay">
      <value value="0.0028"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="run-num">
      <value value="&quot;1&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="turnover-rate">
      <value value="0.001"/>
      <value value="0.004"/>
      <value value="0.008"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initial-clients">
      <value value="10000"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="save-output?">
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="experiment">
      <value value="&quot;incremental conditions10.10.15&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="directory">
      <value value="&quot;/Users/virginiamckay/Documents/Dissertation/Analyses/Netlogo models/Output/&quot;"/>
    </enumeratedValueSet>
    <steppedValueSet variable="positions" first="2" step="2" last="10"/>
    <enumeratedValueSet variable="initial-risk">
      <value value="2.5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="infection-rate">
      <value value="0.12"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="training-delay">
      <value value="2"/>
      <value value="4"/>
      <value value="6"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="save-map?">
      <value value="false"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="filename">
      <value value="&quot;RESPECT.9.15.15 &quot;"/>
    </enumeratedValueSet>
  </experiment>
</experiments>
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@