breed [preys prey]
breed [dummies dummy]
breed [neuralians neuralian]

dummies-own [energy]
neuralians-own [energy r]

globals [fixation extinction delta-t prey-cap birth-rate Vrep spike-cost maint-cost capture-cost]

to setup
  
  ;; (for this model to work with NetLogo's new plotting features,
  ;; __clear-all-and-reset-ticks should be replaced with clear-all at
  ;; the beginning of your setup procedure and reset-ticks at the end
  ;; of the procedure.)
  __clear-all-and-reset-ticks
  
  ask patches [set pcolor blue]
  
  set-default-shape turtles "circle"
  
  create-preys 1 [
    set color orange
    set size .5
    setxy random-xcor random-ycor 
  ]
  
  set delta-t 1
  set birth-rate .07
  set Vrep 100
  set fixation 0
  set extinction 0
  
  ifelse high-density
  [set maint-cost .22 set prey-cap 10000]
  [set maint-cost .022 set prey-cap 1000]
  
  ifelse high-s
  [set spike-cost maint-cost]
  [set spike-cost (maint-cost / 100)]
  
  ifelse high-a/m
  [set capture-cost (maint-cost * 10)]
  [set capture-cost (maint-cost * 5)]
  
  
  
end

to go
 
    move-prey
    prey-rep
    move-predators
    feed-predators
    rep-and-die
    tick
  
end

to introduce-idiot
  
  create-dummies 1 [
    set color red
    set size 1
    set energy Vrep / 2
    setxy random-xcor random-ycor
    ifelse show-indigenous-energy? 
    [set label round energy]
    [set label ""]
  ]
  
end

to introduce-decider
  
    create-neuralians 1 [
      set color black
      set size 1
      set energy Vrep / 2
      setxy random-xcor random-ycor
      ifelse show-mutant-energy? 
      [set label round energy]
      [set label ""]
    ]
  
end

to begin-invasion
  
  repeat 1000 [go]
  introduce-idiot
  repeat 15000 [go]
  introduce-decider
  
  while [fixation + extinction < trials] [
   
    repeat 1000 [go]
    
    if count neuralians = 0 [
      set extinction extinction + 1
      repeat 2000 [go]
      introduce-decider
      ]
    
    if count neuralians > 10 [
      set fixation fixation + 1
      ask neuralians [die]
      ;get prey back to max
      repeat 1000 [go]
      introduce-idiot
      ;get dummies to equilibrium
      repeat 15000 [go] 
      introduce-decider
    ]
    
  ]
  
end

to move-prey
  
  ask preys [lt random-float 10 rt random-float 10 fd .05]
  
end

to prey-rep

  let new-preys (sum n-values (prey-cap - count preys) [ifelse-value (birth-rate > random-float 1) [1] [0]])
  
  ask one-of preys [hatch new-preys [setxy random-xcor random-ycor]]
  
end

to move-predators
  
  ask turtles with [(breed = dummies) or (breed = neuralians)] [
    lt random-float 10
    rt random-float 10
    fd 2 ;must be at least 2 * sqrt(2 / pi)
  ]
 
end

to capture
  
  set energy (energy - capture-cost + count preys in-radius (sqrt (2 / pi)))
  
  ask preys in-radius (sqrt (2 / pi)) [die]
  
end

to feed-predators
  
  ask turtles with [(breed = dummies) or (breed = neuralians)] [
    
    set energy (energy - maint-cost)
    
    while [any? preys in-radius (1 / sqrt pi)] [
      ask preys in-radius (1 / sqrt pi) [setxy random-xcor random-ycor]
    ]
    
    ;dummies strike on every time step
    if breed = dummies [
      capture
      ifelse show-indigenous-energy? 
      [set label round energy]
      [set label ""]
      ]
    
    ;neuralians strike depending on the proximity of prey
    if breed = neuralians [
           
      ;get the distance to every prey
      set r [distance myself] of min-n-of 15 preys [distance myself]
      
      ;calculate the signals
      let sigma map [1 / ? ^ 3] r
      
      ifelse excitatory?
      ;expected number of spikes in time step delta-t for excitatory sensors
      [
       let lambda ((gain * (sum sigma) + noise) * delta-t)
       let PrC (1 - e ^ (- lambda))
       ;draw a random number and see if neuralian tries to capture
       if random-float 1 < PrC [capture set energy (energy - spike-cost)]
      ]
      ;expected number of spikes in time step delta-t for inhibitory sensors
      ;this formula is derived from the condition that Pr(C=1|Z) must be the same
      ;for excitatory and inhibitory sensors to have a fair comparison.
      [
       let lambda (- ln (1 - e ^ (-1 * (gain * (sum sigma) + noise) * delta-t)))
       let PrC (e ^ (- lambda))
       ;draw a random number and see if neuralian tries to capture
       ifelse random-float 1 < PrC
        [capture]
        [set energy (energy - spike-cost)]
       ]

      ifelse show-mutant-energy? 
      [set label round energy]
      [set label ""]
    
    ]
    
  ]
  
end

to rep-and-die
  
  ask dummies with [energy >= Vrep] [hatch 1
      [fd 1
       set heading random-float 360
       set energy Vrep / 2
      ]
    set energy (Vrep / 2)
  ]
  ask dummies with [energy <= 0] [die]
  ask neuralians with [energy >= Vrep] [hatch 1 
      [set heading random-float 360
       setxy random-xcor random-ycor
       set energy Vrep / 2 
      ]
    set energy (Vrep / 2)
  ]
  ask neuralians with [energy <= 0] [die]
  
end









@#$#@#$#@
GRAPHICS-WINDOW
741
13
1239
532
30
30
8.0
1
10
1
1
1
0
1
1
1
-30
30
-30
30
1
1
1
ticks
30.0

BUTTON
530
120
596
153
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SWITCH
108
489
279
522
show-mutant-energy?
show-mutant-energy?
0
1
-1000

SLIDER
38
277
169
310
gain
gain
0
.25
0.15
.01
1
NIL
HORIZONTAL

SLIDER
212
277
344
310
noise
noise
3
7
3
1
1
NIL
HORIZONTAL

SLIDER
446
481
571
514
trials
trials
0
100
50
1
1
NIL
HORIZONTAL

BUTTON
444
430
569
463
NIL
begin-invasion
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SWITCH
211
150
347
183
excitatory?
excitatory?
0
1
-1000

MONITOR
619
425
686
470
fixations
fixation
0
1
11

MONITOR
614
477
696
522
extinctions
extinction
0
1
11

TEXTBOX
62
253
322
274
1b)  Decider's sensor parameters
16
0.0
1

TEXTBOX
220
118
352
149
excitatory (on) or inhibitory (off) sensor
11
0.0
1

TEXTBOX
423
376
702
419
to run \"trials\" number of simulations to fixation or extinction, click 'setup' and then 'begin-invasion'.  note:  this simulation could take days to complete.\n
11
0.0
1

SWITCH
211
206
347
239
high-s
high-s
1
1
-1000

SWITCH
40
206
175
239
high-a/m
high-a/m
1
1
-1000

SWITCH
40
150
176
183
high-density
high-density
1
1
-1000

TEXTBOX
201
188
371
206
s = m (on) or s = m / 100 (off)
11
0.0
1

TEXTBOX
23
188
188
206
a = 10*m (on) or a = 5*m (off)
11
0.0
1

BUTTON
396
279
459
312
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
489
279
586
312
NIL
introduce-idiot
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

TEXTBOX
401
92
730
111
2a)  click 'setup' before running anything.
16
0.0
1

TEXTBOX
409
187
725
273
click 'go' to run the model, click again to pause.  click 'introduce-dummy' to put a neurone-less animal in the ecosystem and watch it eat food.  click 'introduce-mutant' to put an animal with a sensor in the ecosystem with parameters \"gain\" and \"noise.\"  see information tab for more info on the details of the model.
11
0.0
1

SWITCH
91
426
283
459
show-indigenous-energy?
show-indigenous-energy?
1
1
-1000

TEXTBOX
62
377
325
421
have idiots show their energy accumulation in real time.  when energy >= 100, animals split into two newborns of energy 50 each.
11
0.0
1

TEXTBOX
60
470
328
488
have deciders show energy as they accumulate it.
11
0.0
1

BUTTON
612
279
723
312
NIL
introduce-decider
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

TEXTBOX
52
118
169
145
high (on) or low (off) food item density
11
0.0
1

TEXTBOX
55
19
342
69
1)  Define parameters (see caption in Figure 4)
20
0.0
1

TEXTBOX
87
88
301
109
1a)  Ecological parameters
16
0.0
1

TEXTBOX
126
349
250
369
Display options
16
0.0
1

TEXTBOX
463
20
648
45
2)  Run the model
20
0.0
1

TEXTBOX
400
161
724
179
2b)  Get a feel for what the model does...
16
0.0
1

TEXTBOX
410
326
706
365
2b) ... or run repeated simulations to obtain data such as that in Figure 4
16
0.0
1

TEXTBOX
457
59
674
90
note:  a speed slider at the top of the screen controls the speed of simulation.
11
0.0
1

@#$#@#$#@
## WHAT IS IT?

This simulation investigates the fixation of neurones in an indigenous, neurone-less population.

Animals (large circles, red and black) eat food in their proximity (small circles) and accumulate energy (1 unit per food eaten).  Animals expend a basal energetic maintenance cost for living on every time step (parameter maint-cost) and lose energy for attempting to consume food (capture-cost).  They split into two identical offspring upon achieving energy Vrep.

Animals come in two breeds:  deciders and idiots.  Deciders have a neurone that acts as rudimentary food proximity detectors; neurones make deciders more likely to capture food when there is food nearby.  Idiots have no such neurone; they simply attempt to consume food on every time step.

A decider is introduced to a stable idiot population.  We are interested in the probability that that decider will drive the idiots to extinction (i.e. fixate).  

To see the code that produces this simulation, click the procedures tab.

Depending on parameter values, 50 trials can take from 5 minutes (for very successful or very unsuccessful deciders) to 72 hours (for deciders that do slightly better than the idiots in a large idiot population).

## HOW IT WORKS

After clicking the 'begin-invasion' button, this is what happens.

1)  Food reproduce until they reach their population cap (fixed at 1000).  They reproduce after every time step with a fixed probability of .07 (the actual number affects population sizes, but not the results).

On a time step, the number of food that are introduced is binomially 			distributed as binom(1000 - (whatever current food population is), .07).  The lower the food population, the faster they are introduced, and vice versa.  This reproduction rule forces animal and food population sizes to a stable equilibrium.

2)  Idiots are introduced.  Assuming they make an expected energetic profit per time step, they reproduce and drive the food density down to the point where the idiots receive an expected energetic return of 0 per time step.

3)  After the ecosystem achieves stable population sizes, a single decider is introduced.  

The decider has an idealised sensor; food send signals out that fall as distance cubed. The decider's sensor multiplies the sum of the signals from the food by the gain, adds uniform noise, and spikes with some probability, given the food's distances from the decider.  If food are far away, their signals are weaker, and the decider is less likely to attempt consumption.  Though the decider saves energy on average (by not attempting food consumption when food isn't close), the neurone incurs a cost (parameter spike-cost) when it spikes.

4)  When the decider population has reached 0 (neurone went extinct) or the idiot population has reached 0 (neurone fixated), we count what happened (fixation or extinction) and reset the simulation.


## HOW TO USE IT

Select the desired parameter settings, and choose the number of times you wish to run the simulation until invasion or extinction.  Click 'setup', and then click 'begin-invasion.'  

## THINGS TO NOTICE

The idiots always drive the food density down to a stable equilibrium value of  
density = (maint-cost + capture-cost) / benefit = maint-cost + capture-cost.  If the food population were not constant, then the fixation probability for the decider becomes intractable.

We can obtain a tractable expression for the fixation probability of the decider given two central assumptions:  
1)  The expected energetic return for the deciders is very close to 0  
2)  The decider attempts food consumption on almost every time step

There are two kinds of neurone:  inhibitory and excitatory.  If a decider's neurone is excitatory, the decider attempts food consumption when its neurone spikes.  If a decider's neurone is inhibitory, the decider does not attempt food consumption when its neurone spikes.  So excitatory neurones are more likely to spike when food is close, whereas inhibitory neurones are more likely to spike when food is distant.  Obviously, if a decider attempts food consumption almost all the time, an inhibitory neurone (which doesn't spike very often) is a much more energetically efficient way of transmitting the same amount of energy as the excitatory neurone (which almost always spikes).

## THINGS TO TRY

Given the two central assumptions above, deciders are more likely to fixate when:  
1)  Capture-cost is large compared to maint-cost  
2)  When the food density is low (alter capture-cost and maint-cost to drive food density down)  
3)  When the neurone is either inhibitory or energetically cheap (spike-cost is low)  
4)  When the noise isn't dominating the the food's signals (when noise = 7 or so, it is very difficult for deciders to fixate)

## CREDITS AND REFERENCES

For a tractable mathematical analysis of this problem, see the manuscript.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
0
Rectangle -7500403 true true 151 225 180 285
Rectangle -7500403 true true 47 225 75 285
Rectangle -7500403 true true 15 75 210 225
Circle -7500403 true true 135 75 150
Circle -16777216 true false 165 76 116

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.0.4
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 1.0 0.0
0.0 1 1.0 0.0
0.2 0 1.0 0.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@