extensions [array bitmap]


;; ----------------------------------------------------------------
breed [helplines helpline]
breed [swarmants swarmant]

globals [
  nrows
  ncols
  posturtle
  steps
  meanvalue
  unfinishedvalue
  vstd
  timeout 
]
patches-own [jumpv]
swarmants-own [antpos]
helplines-own [temp2]

;; ----------------------------------------------------------------

;; startup definition
to startup
  
  __clear-all-and-reset-ticks
  
  set nladders 10
  set nsnakes 10
  set nrows 10
  set ncols 10
  
  ; define world size
  set-patch-size 30
  resize-world 0 (nrows + 1) 0 (ncols + 1)
  bitmap:copy-to-drawing (bitmap:import "board.jpg") 0 0

  set meanvalue 0
  set unfinishedvalue 0

  set vstd 3
  set timeout 1000
  
  ;set showunfinishedgames true
  
  reset-ticks
  
end

;; ----------------------------------------------------------------

;; generate snakes and ladders - on a square grid
to generatesnakesladders
  
  ; pick the heads of snakes and ladders
  let temp shuffle filter [? > 0] n-values (nrows * ncols - 1) [?]
  let lheads sublist temp 0 nladders
  let sheads sublist temp nladders (nladders + nsnakes)

  set-default-shape helplines "dot"
  create-helplines 1
  
  ; compute the falls
  foreach sheads [
    ask patch (1 + getcolfromindex ?) (1 + getrowfromindex ?) [
      
      let adjmean averagelength
      let adjstd vstd
      if (averagelength + 3 * vstd) > ? [
        let k ? / (averagelength + 3 * vstd)
        set adjmean averagelength * k
        set adjstd vstd * k
      ]
      
      let a round random-normal adjmean adjstd
      while [a > ?] [
        set a round random-normal adjmean adjstd  
      ]
      if a <= 0 [set a 1]

      set jumpv ? - 1 * a

      ;; draw the line
      ask helplines [
        move-to myself
        set temp2 [jumpv] of myself
        set color [255 0 0]
        set pen-size 9
        set size 1.3
        stamp
        pen-down
        setxy (1 + getcolfromindex temp2) (1 + getrowfromindex temp2)
        pen-up
      ]
      
      ;; draw the line
      ask helplines [
        move-to myself
        set temp2 [jumpv] of myself
        set color [255 255 255]
        set pen-size 3
        set size 0.8
        stamp
        pen-down
        setxy (1 + getcolfromindex temp2) (1 + getrowfromindex temp2)
        pen-up
      ]
    ]
  ]
  
  
    ; compute the jumps
  foreach lheads [
    ask patch (1 + getcolfromindex ?) (1 + getrowfromindex ?) [
      
      let adjmean averagelength
      let adjstd vstd
      if (averagelength + 3 * vstd + ?) > nrows * ncols [
        let k (nrows * ncols - ?) / (averagelength + 3 * vstd)
        set adjmean averagelength * k
        set adjstd vstd * k
      ]
      
      let a round random-normal adjmean adjstd
      while [( a + ? ) >= (nrows * ncols)] [
        set a round random-normal adjmean adjstd
      ]
      
      ;if ( a + ? ) >= (nrows * ncols) [ set a (nrows * ncols) - ? - 1]
      if a <= 0 [set a 1]
      set jumpv ? + a
      
      ;; draw the line
      ask helplines [
        move-to myself
        set temp2 [jumpv] of myself
        set color [0 0 0]
        set pen-size 10
        pen-down
        setxy (1 + getcolfromindex temp2) (1 + getrowfromindex temp2)
        pen-up
      ]
      
      ask helplines [
        move-to myself
        set temp2 [jumpv] of myself
        set color [255 255 255]
        set pen-size 3
        pen-down
        setxy (1 + getcolfromindex temp2) (1 + getrowfromindex temp2)
        pen-up
       
      ]
    ]
  ]
  
end


;; ----------------------------------------------------------------



;; ----------------------------------------------------------------
;; get the column coordinate from an index
to-report getcolfromindex [index] 
    let row getrowfromindex index
    ifelse (row mod 2) = 0 [
      ;; we are counting from left to right
      report index mod ncols
    ] [
      ;; we are counting from right to left
      report ncols - 1 - (index mod ncols)
    ]
end

;; get the row coordinate from an index
to-report getrowfromindex [index] 
    report floor (index / ncols)
end

;; ----------------------------------------------------------------

to rolldice
  
  set steps steps + 1
  
  ;; roll the dice
  let dice (1 + random 6)
  
  ;; advance the turtle
  set posturtle posturtle + dice
  
  ;; check if we are done
  ifelse posturtle >= (ncols * nrows - 1) [
    show (word "simulation done. number of steps: " steps)
    set posturtle 0
  ] [
    ;; account for ladders and snakes
    set posturtle [jumpv] of patch (1 + getcolfromindex posturtle) (1 + getrowfromindex posturtle)
  ]
  
  ;; update the heading of the turtle
  let row getrowfromindex posturtle
  ifelse (row mod 2) = 0 [
    ask turtles [set heading 90]
  ] [
    ask turtles [set heading 270]
  ]
  if posturtle = (ncols * nrows - 1) [
    ask turtles [set heading 0]
  ]

  ;; update the position of the turtle
  ask turtles [set xcor 1 + getcolfromindex posturtle]
  ask turtles [set ycor 1 + getrowfromindex posturtle]
  
  ;; update the display
  show (word "dice roll: " dice)
  show (word "position: " posturtle)
  show ""
  
end

;; ----------------------------------------------------------------

;; setup button
to setup
  
  __clear-all-and-reset-ticks
  
  let i 0
  
  set nrows 10
  set ncols 10
  ; define world size
  set-patch-size 30
  resize-world 0 (nrows + 1) 0 (ncols + 1)
  bitmap:copy-to-drawing (bitmap:import "board.jpg") 0 0

  set steps 0
  
  ;set showunfinishedgames true
  set vstd 3
  set timeout 1000
  
  clear-patches
  
  ;; fill in the default values
  foreach n-values (nrows * ncols) [?] [
    ask patch (1 + getcolfromindex ?) (1 + getrowfromindex ?) [set jumpv ?]
  ]
    
  clear-output
  
  ;; generate a new setup
  generatesnakesladders
  
  ;; place a turtle at the origin
  set posturtle 0
  
  ask turtles [die]
  create-turtles 1
  ask turtles [
    setxy 1 1
    set heading 90
    set color yellow
  ]
    
end

;; ----------------------------------------------------------------

;; function generates a bunch of ants and runs statistics
to runswarm
  
  let clock 0
  let i 0
  let statexit []
  
  clear-all-plots
  reset-ticks
  
  ; clear additional variables
  set meanvalue 0
  set unfinishedvalue 0
  
  ; disable display
  no-display
  
  create-swarmants ngames
  ask swarmants [
    set antpos 0
  ]
  
  while [clock < timeout] [
    
    ask swarmants [
      
      ;; roll the dice
      let dice (1 + random 6)
  
      ;; advance the ant
      set antpos antpos + dice
  
      ;; check if we are done
      ifelse antpos >= (ncols * nrows - 1) [
        ;; record the statistics
        set statexit lput clock statexit
        die
      ] [
        ;; account for ladders and snakes
        set antpos [jumpv] of patch (1 + getcolfromindex antpos) (1 + getrowfromindex antpos)
      ]
      
    ]
    
    set-current-plot "Number of Finished Games versus Number of Rolls"
    ifelse empty? statexit [
    ] [
      set-plot-x-range 1 last statexit
      histogram statexit
    ]
    
    set clock clock + 1
    tick
  ]
  
  ;; update variables
  ifelse length statexit = 0 [
    set meanvalue 0 
  ] [
    set meanvalue mean statexit
  ]
  
  ; update the unfinished games variable
  set unfinishedvalue unfinishedvalue + count swarmants
  
  set-current-plot "Number of Finished Games versus Number of Rolls"
  set-plot-x-range 1 (timeout + 1)
  histogram statexit
  
  ;; kill all ants
  ask swarmants [die]
  
  ; enable the display again
  display
  
end
@#$#@#$#@
GRAPHICS-WINDOW
210
45
580
436
-1
-1
30.0
1
10
1
1
1
0
0
0
1
0
11
0
11
1
1
1
dice rolls
30.0

BUTTON
18
43
202
76
Set up New Board
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
19
154
202
187
nladders
nladders
1
50
10
1
1
ladders
HORIZONTAL

SLIDER
19
118
202
151
nsnakes
nsnakes
1
50
10
1
1
snakes
HORIZONTAL

SLIDER
18
236
204
269
averagelength
averagelength
1
50
25
1
1
squares
HORIZONTAL

TEXTBOX
39
201
200
230
Select the size of the snakes \n           and ladders
11
0.0
1

BUTTON
19
299
205
332
Roll the dice 
rolldice
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
19
402
206
435
Run all the games
runswarm
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
19
363
204
396
ngames
ngames
100
10000
9900
100
1
games to play
HORIZONTAL

PLOT
583
109
930
385
Number of Finished Games versus Number of Rolls
Number of dice rolls to finish a game
Number of finished games
0.0
10.0
0.0
10.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" ""

TEXTBOX
22
82
207
124
Select the number of snakes (red)\n       and ladders (black)
11
0.0
1

TEXTBOX
39
271
189
299
To move your counter one \n   go at a time press here
11
0.0
1

TEXTBOX
15
438
925
557
The faster a coral reef can grow (dice rolls) and mature (climb the board) then the better the resilience against disasters (snakes).  The more we can provide protection and assistance (ladders) the more we can help coral reefs reach a state of high maturity. However if there too many snakes the coral reef can't reach Nirvana (square 100) but instead oscillate in a poorer condition. Climate change will introduce more 'snakes' and make 'ladders' harder to implement.
14
0.0
1

MONITOR
584
391
813
436
Average number of years to finish game
meanvalue
2
1
11

MONITOR
824
389
930
434
Unfinished games
unfinishedvalue
17
1
11

TEXTBOX
251
10
634
50
Snakes and Ladders
24
0.0
1

TEXTBOX
587
40
933
124
The graph shows the distribution of how many games were completed for a certain number of dice rolls.The longer it takes to reach maturity the less resiient a coral reef is to deleterious events.
12
0.0
1

TEXTBOX
24
334
205
362
To run many games automatically set the number then press below
11
0.0
1

@#$#@#$#@
## ## WHAT IS IT?

This model was set up to provide a working conceptual model of coral reef dynamics in the face of climate change. Climate change threatens a wide range of ecosystem processes that underpin the world's coral reefs.  The implementation of conservation actions to manage fishing pressure and water quality has already shown resilience benefits, however ongoing public support is critical to ensure these and future actions can successfully counter the deleterious effects of climate change. Public understanding of resilience theory and the complexity of stochastic events effecting coral reefs is limited, in part, by the model format presented. Here we present a model used as a basis for the simple game known as ‘Snakes and Ladders’ to assist in the understanding of resilience potential and stochastic events in coral reef ecology. 

## ## HOW IT WORKS

The simplicity of the game is the essence of why we selected it. We used a 10 by 10 checkered board numbered sequentially from 1 to 100.  The lower numbers represent an unspecified state that is poor (low coral cover or low biodiversity or low resilience) while the higher numbers represent the healthiest state a reef can achieve. Therefore each player’s chip can represent a coral reef within a common region in order to minimize environmental heterogeneity. Each player starts at the lowest number and using the dice values of 1 to 6 precede along the board. With a slight twist on the original game the number of moves required to reach the final square is the measure of success. 
However the game is complicated by the addition of ‘snakes’ and ‘ladders’ that either accelerate or retard a ‘coral reef’ chip’s progress. Without these complications each ‘coral reef’ chip would take between 17 (17 x 6 moves = 102 squares) and 100 (100 x 1 move =100 squares) moves and winning would simply be a game of lucky dice rolls. With the inclusion of snakes and ladder elements the layout of the board will determine the minimum number of moves possible.  Snakes can represent many different processes (over fishing, disease, Acanthuses planci outbreaks, cyclones, thermal bleaching, shipping disaster etc.) that span from retarding growth (perhaps a small magnitude that is less than dice throw) or severely reducing coral reef health (large magnitude).  Likewise the ladders can be used to represent a combination of management actions and natural conditions including marine reserves, shipping control, anchoring protection, strong recruitment, and favorable growth conditions etc. 


## ## HOW TO USE IT

The player has the option of firstly selecting the number of snakes and then ladders. The mean size of the snakes/ladders is also altered if desirable. The player can then keep throwing a single dice and watch the movement of the coral reef step by step. Otherwise they can run many thousands of games (as specified) by a click of a button.
The outputs show the number of games that were completed with a specified number of dice rolls. Clearly the faster the coral reef can complete a 'game' the more resilient it is to bounce back from disasterous events. Ladders can help here but are often hard to implement in practise. Climate change is rapidly adding more snakes.

## ## THINGS TO NOTICE

Notice how the coral reefs can end up oscillating at a lower state if the number of snakes is just too many.

## ## THINGS TO TRY

Try playing with the size of the snakes and ladders.

## ## EXTENDING THE MODEL

Clearly this model is not trying to inform scientists about the dynamics of coral reef growth but the model could be extended by making the players more adaptable and perhaps more interactive.

## ## NETLOGO FEATURES

We placed a picture of coral reefs in the background to provide some interesting context. Ideally we would have liked better looking snakes and ladders but this proved very difficult to code up.

## ## CREDITS AND REFERENCES

This model was created from discussons held at the Great Barrier Reef Marine Park Authority in 2012. 
Lead netlogo coder was Stefan Dulman with some assistance from Stuart Kininmonth. Graphics were the artistic effort of Dieter Tracey and climate change orientation was from Roger Beeden and Stuart Kininmonth.  This model is part of an effort to educate the public on climate change. 
The implications are discussed in a paper titled "Snakes and Ladders: Resilience modeling of coral reef ecosystems for public education " by Kininmonth, Stuart, Beeden, Roger , Dulman, Stefan  & Dieter Tracey pubished in Journal of Environmental Education 2013. 
Questions concerning the model can be directed at stuart.kininmonth@stockholmresilience.su.se

This model is provided free and without limits to non-profit applications.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
0
Rectangle -7500403 true true 151 225 180 285
Rectangle -7500403 true true 47 225 75 285
Rectangle -7500403 true true 15 75 210 225
Circle -7500403 true true 135 75 150
Circle -16777216 true false 165 76 116

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.0.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 1.0 0.0
0.0 1 1.0 0.0
0.2 0 1.0 0.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

ladder
0.0
-0.2 1 2.0 2.0
0.0 1 4.0 4.0
0.2 1 2.0 2.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

snake
3.0
-0.2 0 0.0 1.0
0.0 1 4.0 4.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@