;;--------------------------------------------------------------------------------
;;
;; value-iteration.nlogo
;;
;; A program which simulates a robot moving around on a grid world. Each patch is 
;; a square in the grid, and may contain an obstacle. The robot is trying to find
;; its way to a goal patch.
;;
;; Written by: Simon Parsons
;; October 2010

;;--------------------------------------------------------------------------------
;;
;; We have one breed and a few global variables

breed [robots robot]
globals [g-xcor g-ycor r-xcor r-ycor done ]


;; We have stored state variables for each patch containing reward of the patch and
;; utility of the patch and the new value of utility during calculating the utility
;; value in each iteration of algorithm
patches-own [reward utility utility-new soil-type]


;;--------------------------------------------------------------------------------
;;
;; Code to set up the environment

;; setup
;;
;; To setup we get rid of any existing robots, color the background, pick obstacle
;; locations and a goal, and then put the robot down in a random position


to setup
  reset-ticks         
  no-display             
  
  ask turtles [die]
  paint-patches
  generate-obstacles
  set-goal
  position-robot
  
  set-rewards            ;; set rewards of patches
  set-utilities          ;; set utilities of patches  
  
  set done false
  
  display                
end

;; make
  
;; do new computations for new settings in the same world
  
to make
  no-display
  
  ;; so you can set a new coordinations for robot location in s-xcor and s-ycor input fields
  set r-xcor s-xcor
  set r-ycor s-ycor
  
  set-rewards
  set-utilities
  
  reset
end

;; paint-patches

to paint-patches
  ask patches [
    set pcolor green
    set plabel-color white
    set soil-type "free"            ;; soil-type of free spaces is "free"
  ]
end

;; generate-obstacles

to generate-obstacles
  repeat obstacles [ask one-of patches [
      set pcolor black              
      set soil-type "block"         ;; soil-type of obstacles is "block"
    ]
  ]
end

;; set-goal

to set-goal
  ask one-of patches [
    set pcolor red
    set g-xcor pxcor
    set g-ycor pycor
    set soil-type "free"            ;; soil-type of goal state is "free"
    ]
end

;; position-robot

to position-robot
  
  ;; setup the robot breed
  
  set-default-shape robots "robot"
  create-robots 1 [set color black]
  
  ;; place the robot
  
    ;; remember the initial location of the robot to allow us to reset
  
  set r-xcor free-x-cor
  set r-ycor free-y-cor
  
  ;; set default values of inout coordination fields s-xcor and s-ycor
  set s-xcor r-xcor  
  set s-ycor r-ycor
  
  ask robots [set xcor r-xcor]
  ask robots [set ycor r-ycor]
  ask robots [set heading 0]
    
  ;; make sure there isn't an obstacle at the robot's initial position
  
  ask patches [if ((pxcor = r-xcor) and (pycor = r-ycor)) [
    set pcolor green
    set plabel-color white
    
    set soil-type "free"
 ]]
end

;; set-rewards

to set-rewards
  ask patches with [soil-type = "free"]  [set reward free-space-reward]
  ask patches with [soil-type = "block"] [set reward 0]
  ask patch g-xcor g-ycor [set reward goal-reward]
end

;; set-utilities

to set-utilities
  ask patches [ 
    set plabel ""
      set utility 0
      set utility-new 0
  ]
  
  if movement != "random"
  [
    if-else value-iteration = "same-as-movement" [
      
      ;; inverted-value-iteration is true then instead of calculating deterministic value iteration
      ;; do not deterministic value iteration 
      if-else movement = "non-deterministic-actions" [
        non-deterministic-value-iteration
      ]
      [
        deterministic-value-iteration
      ]
    ]
    [
      if-else value-iteration = "deterministic" [
        deterministic-value-iteration
      ]
      [
        non-deterministic-value-iteration
      ]
    ]
  ]
end

;; deterministic-value-iteration
;; 
;; 
to deterministic-value-iteration
  repeat value-iteration-loops
  [
    ask patches with [soil-type = "free"]
    [
      ;; utilities of each direction (in the case of obstacle, utility of self)
      let u_north ifelse-value (obstacle "north" self) [utility] [[utility] of patch-at 0  1]
      let u_south ifelse-value (obstacle "south" self) [utility] [[utility] of patch-at 0 -1]
      let u_east  ifelse-value (obstacle "east" self)  [utility] [[utility] of patch-at 1  0]
      let u_west  ifelse-value (obstacle "west" self)  [utility] [[utility] of patch-at -1 0]
      
      ;; the best value of directions
      let best-value ifelse-value(u_north > u_south and u_north > u_east and u_north > u_west)[u_north]
        [ifelse-value(u_south > u_east and u_south > u_west) [u_south][ifelse-value(u_east > u_west) [u_east][u_west]]]
      
      ;; new utility is   
      set utility-new (reward + discount * best-value)
    ]
    
    ;; replace utility with new utility in each iteration  
    ask patches
    [
      set utility utility-new
    ]
  ]
end

;; non-deterministic-value-iteration
;;

to non-deterministic-value-iteration
  repeat value-iteration-loops
  [
    ask patches with [soil-type = "free"] [
     
      ;; set direction utilities in diterministic environment
      let u_north ifelse-value (obstacle "north" self) [utility] [[utility] of patch-at 0  1]
      let u_south ifelse-value (obstacle "south" self) [utility] [[utility] of patch-at 0 -1]
      let u_east  ifelse-value (obstacle "east" self)  [utility] [[utility] of patch-at 1  0]
      let u_west  ifelse-value (obstacle "west" self)  [utility] [[utility] of patch-at -1 0]
      
      ;; find directions utilities in non-deterministic environment
      let north (.7 * u_north + .1 * u_west +  .1 * u_east +  .1 * utility)
      let south (.7 * u_south + .1 * u_west +  .1 * u_east +  .1 * utility)
      let east  (.7 * u_east  + .1 * u_south + .1 * u_north + .1 * utility)
      let west  (.7 * u_west  + .1 * u_south + .1 * u_north + .1 * utility)
      
      let best-value ifelse-value(north > south and north > east and north > west)[north]
        [ifelse-value(south > east and south > west) [south][ifelse-value(east > west) [east][west]]]
        
      set utility-new (reward + discount * best-value)
    ]
  
    ask patches [
      set utility utility-new
    ]
  ]
end

;; free-x-cor free-y-cor
;;
;; These are supposed to generate random locations that aren't obstacles. For
;; now they just report 0 or a random location (depending on the value of 
;; robot-position, and we adjust the obstacles to avoid them.

to-report free-x-cor
  if-else robot-position = "center"[
    report 0
  ]
  [
    report random-pxcor
  ]
end

to-report free-y-cor
  if-else robot-position = "center"[
    report 0
  ]
  [
    report random-pycor
  ]
end

;; reset
;;
;; Reset allows you to return the robot to its initial position to run more
;; than once in the same environment.

to reset
  no-display
  
  ask patches [ 
    set pcolor ifelse-value(soil-type = "free") [green][black] 
    set plabel-color white
    set plabel ""
  ]
  
  ask patch g-xcor g-ycor [ set pcolor red ]
  
  ask robots [
    set color black
    set xcor r-xcor
    set ycor r-ycor
  ]
  
  reset-ticks
  
  set done false
  display
end


;;--------------------------------------------------------------------------------
;;
;; 

;; go
;;
;; The top level loop. Make the robot take a step forward, tick, and stop if the 
;; robot is at the goal (which stops the clock).

to go
  run-robot
  tick
  ask robots [at-goal-test]
  if done[
    stop
  ]
end

;; run-robot
;;
;; The high level call to make the robots move --- as long as you aren't at the 
;; goal, make a move.

to run-robot 
  ask robots [
    if-else not at-goal [
      robot-move
    ]
    [
      set color green
    ]
  ]
end

;; robot-move
;;
;; The place where we plug in different ways to move the robot. The basic
;; mechanism is just to make a random move. Here would be the place to have
;; the robot use the value it has 

to robot-move
  if-else movement = "random" [
    robot-random-move  
  ]
  [
    other-movement
  ]
end

;; robot-random-move
;;
;; Pick a direction, randomly and with equal probability

to robot-random-move
 let direction random 4
 ;;show direction
 if direction = 0 [
   move "north"
 ]
 if direction = 1 [
   move "south"
 ]
 if direction = 2 [
   move "east"
 ]
 if direction = 3 [
   move "west"
 ]
end

;; other-movement
;;
;; This is just a placeholder

to other-movement
  if-else movement = "deterministic-actions" [
    robot-deterministic-move
  ]
  [
    robot-non-deterministic-move
  ]
end

;; robot-deterministic-move

to robot-deterministic-move
  
      let u_north ifelse-value (obstacle "north" self) [utility] [[utility] of patch-at 0  1]
      let u_south ifelse-value (obstacle "south" self) [utility] [[utility] of patch-at 0 -1]
      let u_east  ifelse-value (obstacle "east"  self) [utility] [[utility] of patch-at  1 0]
      let u_west  ifelse-value (obstacle "west"  self) [utility] [[utility] of patch-at -1 0]
      
      ;; move to the best value
      move (ifelse-value (u_north > u_east and u_north > u_west and u_north > u_south)
        ["north"][ifelse-value (u_south > u_east and u_south > u_west)
          ["south"][ifelse-value (u_east > u_west)
            ["east"]["west"]]])

end

;; robot-non-deterministic-move

to robot-non-deterministic-move
 
      let u_north ifelse-value (obstacle "north" self) [utility] [[utility] of patch-at 0 1]
      let u_south ifelse-value (obstacle "south" self) [utility] [[utility] of patch-at 0 -1]
      let u_east  ifelse-value (obstacle "east" self) [utility] [[utility] of patch-at 1 0]
      let u_west  ifelse-value (obstacle "west" self) [utility] [[utility] of patch-at -1 0]
      
      ;; randomly move to the best value
      let direction ifelse-value (u_north > u_east and u_north > u_west and u_north > u_south)
        ["north"][ifelse-value (u_south > u_east and u_south > u_west and u_south > u_north)
          ["south"][ifelse-value (u_east > u_west and u_east > u_south and u_east > u_north)
            ["east"][ifelse-value (u_west > u_east and u_west > u_south and u_west > u_north)["west"]["EQ"]]]]
      
      if-else direction = "EQ"
      [
        rand-move (prob-choice u_north u_south u_east u_west)
      ]
      [
        rand-move direction
      ]      
end
          
to-report prob-choice [north south east west]
  let rand random 4
  
  if-else north = south and south = east and east = west
  [
    report (ifelse-value (rand = 0)["north"][ifelse-value(rand = 1)["south"][ifelse-value(rand = 2)["east"]["west"]]])
  ]
  [
    set rand random 3
    if-else north = south and south = east
    [
      report (ifelse-value (rand = 0)["north"][ifelse-value(rand = 1)["south"]["east"]])
    ]
    [
      if-else north = south and south = west
      [
        report (ifelse-value (rand = 0)["north"][ifelse-value(rand = 1)["south"]["west"]])
      ]
      [
        if-else north = east and east = west
        [
          report (ifelse-value (rand = 0)["north"][ifelse-value(rand = 1)["east"]["west"]])
        ]
        [
          if-else south = east and east = west
          [
            report (ifelse-value (rand = 0)["south"][ifelse-value(rand = 1)["east"]["west"]])
          ]
          [
            set rand random 2
            if-else south = east and east > west and east > north
            [
              report (ifelse-value (rand = 0)["south"]["east"])
            ]
            [
              if-else south = west and west > east and west > north
              [
                report (ifelse-value (rand = 0)["south"]["west"])
              ]
              [
                if-else south = north and north > east and north > west
                [
                  report (ifelse-value (rand = 0)["south"]["north"])
                ]
                [
                  if-else north = west and north > east and north > south
                  [
                    report (ifelse-value (rand = 0)["west"]["north"])
                  ]
                  [
                    if-else north = east and north > west and north > south
                    [
                      report (ifelse-value (rand = 0)["east"]["north"])
                    ]
                    [
                      report (ifelse-value (rand = 0)["west"]["north"])
                    ]
                  ]
                ]
              ]
            ]
          ]
        ]
      ]
    ]
  ]
end          

;; rand-move

;; randomly move to the direction (based on the given probablities)

to rand-move [direction]
    let rand random 10
    
    if rand < 7 [
      move direction
    ] 
    
    let left-handside ""
    let right-handside ""
    
    ;; find left and right direction of the given direction
    if direction = "north" [
      set right-handside "east"
      set left-handside "west"
    ]
    if direction = "south" [
      set right-handside "west"
      set left-handside "east"
    ]
    if direction = "east" [
      set right-handside "south"
      set left-handside "north"
    ]
    if direction = "west" [
      set right-handside "north"
      set left-handside "south"
    ]
    
;;  if rand = 7 [self-loop]

    if rand = 8 [
      move right-handside
    ]
    
    if rand = 9 [
      move left-handside
    ]
end

;; move
;;
;; You can move in a direction as long as there is no obstacle.

to move [direction]
  ask robots [
    if not obstacle direction patch-here[
      step direction
    ]
  ]
end

;; obstacle
;;
;; We spot an obstacle by identifying if there is a black patch in the 
;; requisite direction, or if we are against the edge of the world.

to-report obstacle[direction my-patch]

  let soil "free"
  
  ;; First look at the color of the patch in the right direction, taking care of 
  ;; the edges of the field, and repeat for all four directions.
  
  if direction = "north" [
    if-else patch ([pxcor] of my-patch) (([pycor] of my-patch) + 1) = nobody [  
      set soil "block"            
    ]
    [ 
      set soil [soil-type] of patch ([pxcor] of my-patch) (([pycor] of my-patch) + 1)
    ]
  ]
  if direction = "south" [
     if-else patch ([pxcor] of my-patch) (([pycor] of my-patch) - 1) = nobody [  
      set soil "block"
    ]
    [ 
      set soil [soil-type] of patch ([pxcor] of my-patch) (([pycor] of my-patch) - 1)
    ]
  ]
  if direction = "east" [
     if-else patch (([pxcor] of my-patch) + 1) ([pycor] of my-patch) = nobody [  
      set soil "block"
    ]
    [ 
      set soil [soil-type] of patch (([pxcor] of my-patch) + 1) ([pycor] of my-patch)
    ]
  ]
  if direction = "west" [
    if-else patch (([pxcor] of my-patch) - 1) ([pycor] of my-patch) = nobody [  
      set soil "block"
    ]
    [     
      set soil [soil-type] of patch (([pxcor] of my-patch) - 1) ([pycor] of my-patch)
    ]
  ]
  
  ;; Then report based on the color
  
  if-else soil = "block" [
    report true
  ]
  [
    report false
  ]
end

;; step
;;
;; Move in the requisite direction, making each step exactly one patch.

to step [direction]
  if direction = "north" [
    set ycor [pycor] of patch-at 0 1
  ]
  if direction = "south" [
    set ycor [pycor] of patch-at 0 -1
  ]
  if direction = "east" [
    set xcor [pxcor] of patch-at 1 0
  ]
  if direction = "west" [
    set xcor [pxcor] of patch-at -1 0
  ]
end

;; at-goal-test
;;
;; robot signals it has got to the goal so that we can stop the simulation

to at-goal-test
  if is-goal patch-here [
    set done true
  ]
end

;; at-goal
;;
;; robot knows it has reached the goal

to-report at-goal
  if-else is-goal patch-here [
    report true
  ]
  [
    report false
  ]
end

;; is-goal
;;

to-report is-goal [my-patch]
  let x-cor [pxcor] of my-patch
  let y-cor [pycor] of my-patch 
  if-else ((x-cor = g-xcor) and  (y-cor = g-ycor))[
    report true
  ]
  [
    report false
  ]
end

;; light-up
;;
;; lights up the world with value of each free patch

to light-up
  no-display
  
  let color-range -1
  let this-utility min [utility] of patches with [soil-type = "free" and not(pxcor = g-xcor and pycor = g-ycor)]
  let loop-var true
  while [loop-var]
  [
    carefully [ 
      set this-utility min [utility] of patches with [soil-type = "free" and not(pxcor = g-xcor and pycor = g-ycor) and utility > this-utility]
    ]
    [ set loop-var false ]
    set color-range color-range + 1
  ]
  set this-utility min [utility] of patches with [soil-type = "free" and not(pxcor = g-xcor and pycor = g-ycor)]
  
  
  if-else color-range = 0  [   
    ask patches with [soil-type = "free" and not(pxcor = g-xcor and pycor = g-ycor)] [set pcolor black]  
  ]
  [
    let scale -1
    repeat color-range + 1
    [
      set scale scale + 1
      ask patches with [soil-type = "free" and not(pxcor = g-xcor and pycor = g-ycor) and utility = this-utility]
      [
        set pcolor (scale-color green (scale) 0 (color-range))
        set plabel-color (scale-color red (color-range - scale) 0 (color-range))
      ]
      carefully [ 
        set this-utility min [utility] of patches with [soil-type = "free" and not(pxcor = g-xcor and pycor = g-ycor) and utility > this-utility]
      ]
      [  print "finished rendering..."  ]
    ]
  ]

  ;ask patch g-xcor g-ycor [ set pcolor red ]
  ask robots [ set color orange]                ;; change robot color so you can see it
  
  display
end

;;        0x00 0x01 0x02 0x03 0x04 0x05 0x06 0x07 0x08 0x09 0x0A 0x0B 0x0C 0x0D 0x0E 0x0F
;;0x2500   ─    ━    │    ┃    ┄    ┅    ┆    ┇    ┈    ┉    ┊    ┋    ┌    ┍    ┎    ┏   

;;0x2510   ┐    ┑    ┒    ┓    └    ┕    ┖    ┗    ┘    ┙    ┚    ┛    ├    ┝    ┞    ┟

;;0x2520   ┠    ┡    ┢    ┣    ┤    ┥    ┦    ┧    ┨    ┩    ┪    ┫    ┬    ┭    ┮    ┯
 
;;0x2530   ┰    ┱    ┲    ┳    ┴    ┵    ┶    ┷    ┸    ┹    ┺    ┻    ┼    ┽    ┾    ┿

;;0x2540   ╀    ╁    ╂    ╃    ╄    ╅    ╆    ╇    ╈    ╉    ╊    ╋    ╌    ╍    ╎    ╏

;;0x2550   ═    ║    ╒    ╓    ╔    ╕    ╖    ╗    ╘    ╙    ╚    ╛    ╜    ╝    ╞    ╟

;;0x2560   ╠    ╡    ╢    ╣    ╤    ╥    ╦    ╧    ╨    ╩    ╪    ╫    ╬    ╭    ╮    ╯

;;0x2570   ╰    ╱    ╲    ╳    ╴    ╵    ╶    ╷    ╸    ╹    ╺    ╻    ╼    ╽    ╾    ╿


;;space[ ]

to show-path
  no-display
  
  ;;if movement = "deterministic-actions"
  ;;[
    ask patches with [soil-type = "free" and not( pxcor = g-xcor and pycor = g-ycor) ]
    [
      let north ifelse-value (obstacle "north" self) [utility] [[utility] of patch-at 0  1]
      let south ifelse-value (obstacle "south" self) [utility] [[utility] of patch-at 0 -1]
      let east  ifelse-value (obstacle "east"  self) [utility] [[utility] of patch-at  1 0]
      let west  ifelse-value (obstacle "west"  self) [utility] [[utility] of patch-at -1 0]

      if-else north > south and north > west and north > east [
        set plabel " ╨ "
      ][
        if-else north = south and north = east and north = west [
          set plabel " ╬ "
        ][
          if-else north = south and north = east and north > west [
            set plabel " ╠ "
          ][
            if-else north = south and north = west and north > east [
              set plabel " ╣ "
            ][
              if-else north = west and north = east and north > south [
                set plabel " ╩ "
              ][
                if-else north = south and north > west and north > east [
                  set plabel " ║ "
                ][
                  if-else north = west and north > east and north > south [
                    set plabel " ╝ "
                  ][
                    if-else north = east and north > west and north > south [
                      set plabel " ╚ "
                    ][
                      if-else south > west and south > east [
                        set plabel " ╥ "
                      ][
                        if-else south = west and south > east
                        [
                          set plabel " ╗ "
                        ][
                          if-else south = east and south > west [
                            set plabel " ╔ "
                          ][
                            if-else south = east and south = west [
                              set plabel " ╦ "
                            ][
                              if-else east > west
                              [
                                set plabel " ╞ "
                              ][
                                if-else east = west
                                [
                                  set plabel " ═ "
                                ]
                                [
                                  set plabel " ╡ "
                                ]
                              ]
                            ]
                          ]
                        ]
                      ]
                    ]
                  ]
                ]
              ]
            ]
          ]
        ]
      ]
    ]
  ;;]
  
  display
end  
;;---------------------------------------------------------------------------
;;
;; A couple of utilities you may find useful

;; find-surrounding-nodes
;;
;; given a patch and a list of patches, finds the patches north, south, east
;; and west of the given patch that are in the field and not obstacles, and
;; returns them

to-report find-surrounding-nodes [my-patch]
  let node-list []
  let new-patch nobody
  if not obstacle "north" my-patch [
    ask my-patch [set new-patch patch-at 0 1]
    if new-patch != nobody [
      set node-list lput new-patch node-list
    ]
  ]
  set new-patch 0
  if not obstacle "south" my-patch [
    ask my-patch [set new-patch patch-at 0 -1]
    if new-patch != nobody [
      set node-list lput new-patch node-list
    ]
  ]
  set new-patch 0
  if not obstacle "east" my-patch [
    ask my-patch [set new-patch patch-at 1 0]
    if new-patch != nobody [
      set node-list lput new-patch node-list
    ]
  ]
  set new-patch 0
  if not obstacle "west" my-patch [
    ask my-patch [set new-patch patch-at -1 0]
    if new-patch != nobody [
      set node-list lput new-patch node-list
    ]
  ]
  report node-list
end

;; append
;; 
;; Join two lists together, tacking its second argument onto the end of the first 
;; argument.
;;
;; I have it on good authority that this basic list handling functionality is in Netlogo
;; under another name, but I can't find it.

to-report append [list1 list2]
  foreach list2 [
    set list1 lput ? list1
  ]
  report list1
end
@#$#@#$#@
GRAPHICS-WINDOW
219
14
649
465
10
10
20.0
1
15
1
1
1
0
0
0
1
-10
10
-10
10
0
0
1
ticks
30.0

BUTTON
12
12
67
45
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
11
47
206
80
obstacles
obstacles
0
300
208
1
1
NIL
HORIZONTAL

BUTTON
10
224
73
257
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

MONITOR
10
262
102
307
NIL
ticks\n
0
1
11

BUTTON
82
224
141
258
reset
reset
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

CHOOSER
11
82
205
127
movement
movement
"random" "deterministic-actions" "non-deterministic-actions"
1

CHOOSER
10
176
205
221
robot-position
robot-position
"center" "random"
0

SLIDER
9
325
205
358
discount
discount
0.01
2
0.99
0.01
1
NIL
HORIZONTAL

SLIDER
8
360
205
393
value-iteration-loops
value-iteration-loops
1
1000
232
1
1
NIL
HORIZONTAL

BUTTON
150
224
205
257
NIL
make
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

INPUTBOX
104
262
154
322
s-xcor
0
1
0
Number

INPUTBOX
155
262
205
322
s-ycor
0
1
0
Number

BUTTON
70
12
128
45
NIL
light-up
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
8
431
205
464
free-space-reward
free-space-reward
-10
10
-1
0.01
1
NIL
HORIZONTAL

SLIDER
8
395
205
428
goal-reward
goal-reward
1
1000
100
1
1
NIL
HORIZONTAL

CHOOSER
11
129
205
174
value-iteration
value-iteration
"same-as-movement" "deterministic" "non-deterministic"
0

BUTTON
131
12
206
45
NIL
show-path
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

@#$#@#$#@
## WHAT IS IT?

This section could give a general understanding of what the model is trying to show or explain.

## HOW IT WORKS

This section could explain what rules the agents use to create the overall behavior of the model.

## HOW TO USE IT

This section could explain how to use the model, including a description of each of the items in the interface tab.

## THINGS TO NOTICE

This section could give some ideas of things for the user to notice while running the model.

## THINGS TO TRY

This section could give some ideas of things for the user to try to do (move sliders, switches, etc.) with the model.

## EXTENDING THE MODEL

This section could give some ideas of things to add or change in the procedures tab to make the model more complicated, detailed, accurate, etc.

## NETLOGO FEATURES

This section could point out any especially interesting or unusual features of NetLogo that the model makes use of, particularly in the Procedures tab.  It might also point out places where workarounds were needed because of missing features.

## RELATED MODELS

This section could give the names of models in the NetLogo Models Library or elsewhere which are of related interest.

## CREDITS AND REFERENCES

This section could contain a reference to the model's URL on the web if it has one, as well as any other necessary credits or references.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

robot
true
0
Circle -7500403 false true 2 2 297
Line -7500403 true 150 0 150 105

robot2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Rectangle -7500403 true true 150 30 150 135
Rectangle -7500403 true true 135 30 160 138

sheep
false
0
Rectangle -7500403 true true 151 225 180 285
Rectangle -7500403 true true 47 225 75 285
Rectangle -7500403 true true 15 75 210 225
Circle -7500403 true true 135 75 150
Circle -16777216 true false 165 76 116

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.0.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 1.0 0.0
0.0 1 1.0 0.0
0.2 0 1.0 0.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

vi-arrow
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Polygon -7500403 true true 120 180 210 180 90 180
Rectangle -1 true false 135 180 165 300
Polygon -1 true false 105 210 135 195 165 195 195 210 150 150 105 210

@#$#@#$#@
0
@#$#@#$#@