globals [ BUILD-THRESHOLD ]
patches-own [ attraction ]

breed [ houses house ]
breed [ seekers seeker ]

houses-own [ stay-counter ]
seekers-own [ patience-counter ]

to setup
  clear-all
  setup-patches
  setup-turtles
  set BUILD-THRESHOLD floor (max-attraction / 2)
  reset-ticks
end

to setup-patches
  ask patches
  [
    set attraction ( random max-attraction )
  ]
  repeat smoothness
  [
    diffuse attraction .4
  ]
  ask patches
  [
    set pcolor scale-color green attraction 2.5 10
  ]
end

to setup-turtles
  create-seekers population
  [
    set color sky
    set shape "default"
    set patience-counter seeker-patience
    set size .75
  ]
  ask turtles
  [
    setxy 0 0
  ]
  ;; if you want to start the turtles at the most attractive location on the map,
  ;; uncomment the following line
  ; ask turtles [ move-to max-one-of patches [ attraction ] ]
end

to go
  ask seekers
  [
    ifelse (want-to-build?)
    [
      set breed houses
      set shape "blue-house"
      set stay-counter wait-between-seeking
    ]
    [
      if (patience-counter) > 0
      [
        turn-toward-attraction
        fd 0.5
        set patience-counter patience-counter - 1
        set attraction attraction + .01
      ]
    ]

  ]
  ask houses
  [

    ifelse attraction <= (max-attraction * 2)
      [ set attraction attraction + .05 ]
      [ set attraction 0 ]

    set stay-counter stay-counter - 1
    if (stay-counter) <= 0
    [
      set breed seekers
      set patience-counter seeker-patience
      set shape "default"
    ]
  ]
  ask patches [ set pcolor scale-color green attraction 2.5 10 ]
  tick
end

to-report want-to-build?
  report random attraction >= BUILD-THRESHOLD or patience-counter = 0
end

to turn-toward-attraction
  let ahead [attraction] of patch-ahead 1
  let myright [attraction] of patch-right-and-ahead seeker-search-angle 1
  let myleft [attraction] of patch-left-and-ahead seeker-search-angle 1
  ifelse ((myright > ahead) and (myright > myleft))
  [
    rt random seeker-search-angle
  ]
  [
    if (myleft > ahead)
      [ lt random seeker-search-angle ]
  ]
end


; Copyright 2007 Uri Wilensky.
; See Info tab for full copyright and license.
@#$#@#$#@
GRAPHICS-WINDOW
225
10
655
461
17
17
12.0
1
10
1
1
1
0
1
1
1
-17
17
-17
17
1
1
1
ticks
30.0

BUTTON
40
60
103
93
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
25
130
205
163
smoothness
smoothness
1
20
15
1
1
NIL
HORIZONTAL

BUTTON
115
60
178
93
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
25
170
205
203
max-attraction
max-attraction
0
30
15
1
1
NIL
HORIZONTAL

SLIDER
25
275
202
308
seeker-search-angle
seeker-search-angle
1
360
84
1
1
NIL
HORIZONTAL

SLIDER
25
210
205
243
population
population
1
750
200
1
1
NIL
HORIZONTAL

SLIDER
25
315
205
348
seeker-patience
seeker-patience
0
120
60
1
1
NIL
HORIZONTAL

SLIDER
25
365
205
398
wait-between-seeking
wait-between-seeking
5
60
15
1
1
NIL
HORIZONTAL

@#$#@#$#@
## WHAT IS IT?

This model demonstrates a simplified version of city growth and how it leads to urban sprawl and the problems connected with it (e.g. leapfrogging).  Since the rules by which the environment changes and the agents interact are quite simple, the strength of this model is less in attempting to realistically model urban development in detail, and more in demonstrating that certain patterns of behavior and land usage can emerge without requiring overly-complex rules.

## HOW IT WORKS

At the beginning of the model, a topography of attractiveness is established (lighter grid squares are more attractive and darker grid squares are less attractive).  All development starts from a densely populated center (e.g. a city).
The agents in the model roughly represent residential population.  This agent may be in one of two states -- either "seeker" or "house".

In the "seeker" state, the agents sample the grid square that is directly ahead of them, and the grid squares that are at a specified angle (SEEKER-SEARCH-ANGLE) to the right and to the left of their current heading.  If it finds that the rightward patch is the best choice, it turns a random amount rightward.  If the leftward patch is the best choice, it turns a random amount leftward.  Otherwise it continues to move straight.  This has an approximate effect of following a gradient toward higher attractiveness, though with a significant random factor, because at most 3 patches are tested, and the seeker does not turn directly towards the patch.  Each time step (tick) the seeker moves one half of the width of a grid square.

Each tick a seeker also decides whether or not to settle (become a "house") on the current grid square.  A random number is chosen between 0 and the attraction value of the patch.  If the chosen random number is greater than half of the MAX-ATTRACTION value for patches, then the seeker settles.  Every tick a seeker also faintly increases the attraction value of the grid square that it is currently over.  The assumption is that areas of activity or growth become more attractive, following the principle of positive feedback.

House agents do very little.  In fact, they just stay put on the square they were settled on for the number of ticks that is specified by the WAIT-BETWEEN-SEEKING value.  While they sit there, they slowly increase the attraction of the square they are sitting on.

There is one additional rule -- the attractiveness values for land do not increase forever.  Instead, too much activity on a given piece of land decreases its attractiveness.  Thus, when attractiveness of a grid square reaches the threshold of MAX-ATTRACTIVENESS, it is reset to having no attractiveness.  This abrupt change in attractiveness is admittedly not very realistic, but the idea that the attractiveness of continually re-occupied land degrades over time is not unreasonable.  Furthermore, this model could be extended to use a more sophisticated mathematical function to account for this degradation.

## HOW TO USE IT

Press SETUP to prepare the model for running.  This creates a topography of attractiveness.

The SMOOTHNESS-SLIDER determines how smooth this attractiveness landscape will be -- setting it at 1 permits very rough landscapes with drastic changes in attractiveness from square to square, whereas setting it at 20 causes the initial landscape to be very smooth with only very gradual changes in attractiveness.

The initial attractiveness landscape is also affected by the MAX-ATTRACTION slider, since attraction values are doled out randomly from between 0 and MAX-ATTRACTION.

The SETUP button also places a population of seeker agents all in the center of the world grid.  The POPULATION slider controls how many agents there are.  This number will remain fixed over the course of the model run (though the seeker agents will transform into house agents, and vice versa).

Press GO to run the model.  If the model is running too quickly to observe the actions of the agents, you can move NetLogo's speed slider to the left to slow it down.  Conversely, it is possible to speed the model by moving the speed slider to the right.  The speed slider accelerates the model by reducing the display frame rate.   Because most of the CPU time for this model is spent rendering the visual display, it is quite effective to speed up the model by using the speed slider.

The SEEKER-SEARCH-ANGLE slider determines the angle to each side that the seekers look when they are comparing attractiveness of nearby grid squares, and deciding which direction to turn.  The maximum turn amount is also controlled by this slider.

The SEEKER-PATIENCE slider controls how long the seekers will search for high attraction squares before giving up and settling wherever they happen to be.

The WAIT-BETWEEN-SEEKING slider controls how long seekers will stay a house in the location where they settle, before they turn back into a seeker again.

## THINGS TO NOTICE

After the initial sprawl and expansion, squares within the dark unattractive areas eventually grow to be attractive again, here and there.  Do you think this is realistic?  It could represent urban renewal efforts, where certain areas become more desirable to live in as a result of city planning and residential effort.  Or it might represent semi-random fluctuations in property values, employment opportunities, quality of school districts, and other factors.  On the other hand, it could be just an unintended result of the over-simplified rules used for modeling how attractiveness changes and how agents make decisions.

## THINGS TO TRY

To get an idea of how a single agent acts, try setting the population size to 1, and watch the behavior.  How do the patterns that form in the world compare to when the population is reasonable large?

Try setting SEEKER-PATIENCE to 0.  What happens?  Can you explain it?  Is it what you expected?  What if you set SEEKER-PATIENCE to 1?  Are the patterns that form different than if SEEKER-PATIENCE is large, such as 120?

## EXTENDING THE MODEL

As noted in the "HOW IT WORKS" section above, it seems somewhat unreasonable that once a certain attractiveness threshold is reached, the attractiveness plummets all the way down to zero.  Try to modify this model so that the decrease in attractiveness happens more gradually.

Right now land values of grid squares are not affected (at least directly) by the land value of neighboring squares.  If one area has become a dirty garbage dump fraught with crime, should it be possible to have highly attractive luxury condominiums right nearby?  Modify this model so that attractiveness is diffused (very slowly) between neighboring patches while the model runs.

## NETLOGO FEATURES

Although breeds are often used in NetLogo models, it is less common for agents to change what breed they are during the course of the model.  One approach to this problem would be to hatch an agent of the new breed, and kill the agent of the old breed.  However, this work is unnecessary -- one can merely write "SET BREED HOUSES" or "SET BREED SEEKERS" to change the breed of an agent.

## RELATED MODELS

This model is related to all of the other models in the "Urban Suite".  In particular, this model shows elements of positive feedback (the concept demonstrated in the Urban Suite - Positive Feedback model).

Also, the creation of the smooth attraction topology is directly related to the model "Urban Suite - Structure from Randomness 1".

Some of the patterns that form are reminiscent of Cellular Automata, or perhaps the "Vants" model.

## CREDITS AND REFERENCES

This model was based on a model originally written by William Rand and Derek Robinson as part of the Sluce Project at the University of Michigan (http://www.cscs.umich.edu/sluce).  For more about the original model (SOME) that was the basis for this model, please see:

Brown D.G., Robinson D.T., Nassauer J.I., An L., Page S.E., Low B., Rand W., Zellner M., and R. Riolo (In Press) "Exurbia from the Bottom-Up: Agent-Based Modeling and Empirical Requirements." Geoforum.

This model was then extended and expanded during the Sprawl/Swarm Class at Illinois Institute of Technology in Fall 2006 under the supervision of Sarah Dunn and Martin Felsen, by the following group of students: Christian Eichinger, Sara Martinez-Bravo, Kit Ottsen, John Wolters.  See http://www.sprawlcity.us/ for more details.

Further modifications and refinements were made by members of the Center for Connected Learning and Computer-Based Modeling before releasing it as an Urban Suite model.

The Urban Suite models were developed as part of the Procedural Modeling of Cities project, under the sponsorship of NSF ITR award 0326542, Electronic Arts & Maxis.

Please see the project web site ( http://ccl.northwestern.edu/cities/ ) for more information.


## HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

* Felsen, M. and Wilensky, U. (2007).  NetLogo Urban Suite - Sprawl Effect model.  http://ccl.northwestern.edu/netlogo/models/UrbanSuite-SprawlEffect.  Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.
* Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

## COPYRIGHT AND LICENSE

Copyright 2007 Uri Wilensky.

![CC BY-NC-SA 3.0](http://i.creativecommons.org/l/by-nc-sa/3.0/88x31.png)

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License.  To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

blue-house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 195 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120
Line -13345367 false 45 285 45 120
Line -13345367 false 15 120 150 15
Line -13345367 false 285 120 150 15
Line -13345367 false 255 285 255 120
Line -13345367 false 255 285 45 285

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.1.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@