breed [points point]                  ;data points to become Delaunay triangulated vertices
points-own [value super?]             ;value to be contoured, flag indicating "super" vertices of encompassing square
breed [triangles triangle]            ;triangle objects, defined by three unique vertex points
triangles-own [Ux Uy rad2             ;circumcenter coordinates, circumcircle radius squared
               bad?                   ;flag for removal from triangulation
               vertices sides]        ;vertex and side pointers
undirected-link-breed [edges edge]    ;triangle edges
edges-own [keep?]                     ;retention flag for triangulation
undirected-link-breed [isos iso]      ;isopleth segments
breed [tics tic]                      ;endpoints for isopleth segments

globals [error?
         contour-list
         tic-list
         Pause-between-increments?
         numpoints
         triangulated?
         baseptsize
         minz maxz zrange]

to setup
  ca
  zoom 100
  set error? true set triangulated? false
  set Pause-between-increments? false;for debugging or viewing progress of Delaunay triangulation
  set numpoints 30                   ;adjust if interface expanded to include more points
  set baseptsize .6
  ;input data from interface, starting with index = 1
  let xlist (list 0 x1 x2 x3 x4 x5 x6 x7 x8 x9 x10 x11 x12 x13 x14 x15 x16 x17 x18 x19 x20 x21 x22 x23 x24 x25 x26 x27 x28 x29 x30)
  let ylist (list 0 y1 y2 y3 y4 y5 y6 y7 y8 y9 y10 y11 y12 y13 y14 y15 y16 y17 y18 y19 y20 y21 y22 y23 y24 y25 y26 y27 y28 y29 y30)
  let vallist (list 0 val1 val2 val3 val4 val5 val6 val7 val8 val9 val10 val11 val12 val13 val14 val15
                      val16 val17 val18 val19 val20 val21 val22 val23 val24 val25 val26 val27 val28 val29 val30)
  let onlist (list false point1 point2 point3 point4 point5 point6 point7 point8 point9 point10 point11 point12 point13 point14 point15
                         point16 point17 point18 point19 point20 point21 point22 point23 point24 point25 point26 point27 point28 point29 point30)
  ;error on out-of-bounds coordinates  - note border
  let border ceiling (world-width / 4)
  if max xlist > max-pxcor - border or max ylist > max-pycor - border or min xlist < min-pxcor + border or min ylist < min-pycor + border
    [;beep    ;not functional for NLweb
     user-message "One or more coordinate values are outside the screen range.  Please check your inputs and try again"
     stop]
  let scalerange max (list (max xlist - min xlist) (max ylist - min ylist))
  let scale (min (list world-width world-height) - 2 * border) / scalerange
  let xctr (min xlist + max xlist) / 2
  let yctr (min ylist + max ylist) / 2

  ;create data points
  create-points numpoints + 1 [ set shape "circle" set size baseptsize set color red
                      set hidden? not item who onlist
                      setxy item who xlist item who ylist
                      if fit-to-frame? [setxy (xcor - xctr) * scale + (max-pxcor + min-pxcor) / 2
                                              (ycor - yctr) * scale + (max-pycor + min-pycor) / 2]
                      set value item who vallist
                      set label value set label-color white
                      set super? false
                      face patch 0 0 0
  ]
  mapvals
  ;error on too few data points
  if count points with [not hidden?] < 3 [user-message "You will need at least three active points to triangulate" stop]
  ;error on duplicated coordinates
  ask points with [not hidden?]
    [if distance min-one-of other points with [not hidden?] [distance myself] = 0
      [;beep    ;not functional for NLweb
       user-message "Two or more active points have identical coordinates.  Please halt, revise your inputs and try again"
       stop]]
  ;create super-vertices at corners
  create-points 1 [set hidden? true set super? true setxy (min-pxcor + 1) (min-pycor + 1)] ; who numpoints + 1
  create-points 1 [set hidden? true set super? true setxy (min-pxcor + 1) (max-pycor - 1)] ; who numpoints + 2
  create-points 1 [set hidden? true set super? true setxy (max-pxcor - 1) (max-pycor - 1)] ; who numpoints + 3
  create-points 1 [set hidden? true set super? true setxy (max-pxcor - 1) (min-pycor + 1)] ; who numpoints + 4

  set error? false
end

to update-vals
  let vallist (list 0 val1 val2 val3 val4 val5 val6 val7 val8 val9 val10 val11 val12 val13 val14 val15 val16 val17 val18 val19 val20)
  ask points with [who <= 20] [set value item who vallist set label value]
  set minz min (list min [value] of points with [not hidden?] alt-min-val)
  set maxz max (list max [value] of points with [not hidden?] alt-max-val)
  set zrange maxz - minz
end

to mapvals
  update-vals
  ifelse show3D?
  [ask points [set zcor min-pzcor + world-depth / 4 + (world-depth / 2) * (value - minz) / zrange]]
  [ask points [set zcor 0]]
end

to triangulate
  setup
  if error? [stop]
  ;create super-triangles
  make-triangle point (numpoints + 1) point (numpoints + 2) point (numpoints + 3) ; super-triangle 1
  make-triangle point (numpoints + 3) point (numpoints + 4) point (numpoints + 1) ; super-triangle 2

  let triset (sort-on [xcor] points with [not hidden?]) ;process left to right
  foreach triset ; for each point in the pointlist
    [p ->
     ask triangles [if inside-circum? p self [set bad? true]] ; for each triangle in the triangulation flag points within circumcircle

     let edgelist []           ; initialize
     ask triangles with [bad?] ; for each new bad triangle
      [ if Pause-between-increments? ;for debugging or viewing progress of Delaunay triangulation
          [ask link-set sides [set color yellow] ask p [set size 2] user-message "Next step?" ask p [set size 1]]
        ask link-set sides [set edgelist ifelse-value member? self edgelist [remove self edgelist] ;remove if duplicated - i.e. inside the polygonal hole
                                                                            [lput self edgelist]]] ;add if unique
          clean-up                  ; remove unused

     foreach edgelist [ed -> make-triangle [end1] of ed [end2] of ed p] ;create new triangles by connecting to vertices of the poly hole
     ]

    ; remove the super vertices and associated edges
    ask triangles with [((member? point (numpoints + 1) vertices) or (member? point (numpoints + 2) vertices)
                      or (member? point (numpoints + 3) vertices) or (member? point (numpoints + 4) vertices))][set bad? true]
    if Pause-between-increments? [ user-message "Complete triangulation?"]
    clean-up
    ask links with [color = red][die]
    set triangulated? true
end

to make-triangle [p1 p2 p3] ;define triangle by vertices
  let me 0
  create-triangles 1
   [set hidden? true
    set bad? false
    set vertices turtle-set (list p1 p2 p3)
    let Ax [xcor] of p1
    let Ay [ycor] of p1
    let Bx [xcor] of p2
    let By [ycor] of p2
    let Cx [xcor] of p3
    let Cy [ycor] of p3
    let midx (max-pxcor + min-pxcor) / 2
    let midy (max-pycor + min-pycor) / 2
    ; Adjustment to Bowyer-Watson to ensure convex hull - super vertices to "infinity"
    if [super?] of p1 [set Ax midx - 10000 * (midx - Ax) set Ay midx - 10000 * (midy - Ay)]
    if [super?] of p2 [set Bx midx - 10000 * (midx - Bx) set By midx - 10000 * (midy - By)]
    if [super?] of p3 [set Cx midx - 10000 * (midx - Cx) set Cy midx - 10000 * (midy - Cy)]
    let d1x Bx - Ax
    let d1y Ay - By
    let d2x Cx - Bx
    let d2y By - Cy
    let d3x Ax - Cx
    let d3y Cy - Ay
    let A2 (Ax ^ 2 + Ay ^ 2)
    let B2 (Bx ^ 2 + By ^ 2)
    let C2 (Cx ^ 2 + Cy ^ 2)
    let D 2 * (Ax * d2y + Bx * d3y + Cx * d1y)
    set Ux (A2 * d2y + B2 * d3y + C2 * d1y) / D ;circumcenter coordinates
    set Uy (A2 * d2x + B2 * d3x + C2 * d1x) / D ;circumcenter coordinates
    set rad2 ((Ax - Ux) ^ 2 + (Ay - Uy) ^ 2)    ;circumcircle radius squared
    set me who
   ]

   ask [vertices] of triangle me [create-edges-with other [vertices] of triangle me [set thickness .3 set hidden? false]] ;will not duplicate undirected links
   let vwho [who] of [vertices] of triangle me                                                           ;unordered list of vertex identifiers
   ask triangle me [set sides (list edge item 0 vwho item 1 vwho
                                    edge item 1 vwho item 2 vwho
                                    edge item 2 vwho item 0 vwho)] ;create list of sides
end

to-report inside-circum? [pt tri] ;inputs a point and a triangle
 let r1sq ([xcor] of pt - [Ux] of tri ) ^ 2 + ([ycor] of pt - [Uy] of tri ) ^ 2
 report r1sq < [rad2] of tri
end

to clean-up
  ask edges [set keep? false]
  ask triangles [ifelse bad? [die][ask link-set sides [set keep? true set color green]]] ;remove bad triangles
  ask edges with [not keep?][set color red]                                              ;remove unused edges
end

to contour
  if triangulated? = 0 [user-message "You will need a triangulation to generate a contour" stop]
  if not triangulated? [user-message "You will need a triangulation to generate a contour" stop]
  set tic-list []
  ask tics [die] ask isos [die]
  update-vals
  ;determine interval to 3 sig figs
  let vrexp 3 - ceiling log zrange 10
  let valint precision (zrange / num-intervals) vrexp
  set contour-list n-values (num-intervals + 1) [ n -> precision ((precision minz vrexp) + n * valint) vrexp ]
  ask triangles[
    let vlist (sort-on [value] vertices)
    let maxv item 2 vlist
    let midv item 1 vlist
    let minv item 0 vlist
    let ranget [value] of maxv - [value] of minv ;total range
    let range1 [value] of midv - [value] of minv ;lower range
    let range2 [value] of maxv - [value] of midv ;upper range
    let dxt [xcor] of maxv - [xcor] of minv
    let dx1 [xcor] of midv - [xcor] of minv
    let dx2 [xcor] of maxv - [xcor] of midv
    let dyt [ycor] of maxv - [ycor] of minv
    let dy1 [ycor] of midv - [ycor] of minv
    let dy2 [ycor] of maxv - [ycor] of midv
    let dzt [zcor] of maxv - [zcor] of minv
    let dz1 [zcor] of midv - [zcor] of minv
    let dz2 [zcor] of maxv - [zcor] of midv
    let my-contours filter [i -> i > [value] of minv and i < [value] of maxv] contour-list ;find contours within triangle
    foreach my-contours
      [n -> let longwho 0
            hatch-tics 1
            [set color white set shape "dot" set hidden? true
             setxyz [xcor] of minv + (n - [value] of minv) * dxt / ranget ;linear interpolation along total side
                    [ycor] of minv + (n - [value] of minv) * dyt / ranget ;linear interpolation along total side
                    [zcor] of minv + (n - [value] of minv) * dzt / ranget ;linear interpolation along total side
             set longwho who
            ]
            hatch-tics 1
            [set color sky set shape "dot" set hidden? true
             ifelse (n < [value] of midv)
              [setxyz [xcor] of minv + (n - [value] of minv) * dx1 / range1  ;linear interpolation along low side
                      [ycor] of minv + (n - [value] of minv) * dy1 / range1  ;linear interpolation along low side
                      [zcor] of minv + (n - [value] of minv) * dz1 / range1] ;linear interpolation along low side
              [setxyz [xcor] of midv + (n - [value] of midv) * dx2 / range2  ;linear interpolation along up side
                      [ycor] of midv + (n - [value] of midv) * dy2 / range2  ;linear interpolation along up side
                      [zcor] of midv + (n - [value] of midv) * dz2 / range2] ;linear interpolation along up side
              create-iso-with tic longwho [set color yellow set thickness .3 set label n set label-color yellow] ;connect tics with isoline segments
            ]

      ]
  ]
  foreach contour-list
    [n -> let these-isos isos with [label = n]
      if count these-isos > 1 [ask one-of these-isos [ask other these-isos [set label ""]]]] ;reduce to a single contour label
end
@#$#@#$#@
GRAPHICS-WINDOW
0
0
1004
1005
-1
-1
12.0
1
10
1
1
1
0
1
1
1
-41
41
-41
41
-20
20
1
1
1
ticks
30.0

SWITCH
5
53
108
86
point1
point1
0
1
-1000

SWITCH
5
84
108
117
point2
point2
0
1
-1000

SWITCH
5
115
108
148
point3
point3
0
1
-1000

SWITCH
5
145
108
178
point4
point4
0
1
-1000

SWITCH
5
176
108
209
point5
point5
0
1
-1000

SWITCH
5
206
108
239
point6
point6
0
1
-1000

SWITCH
5
236
108
269
point7
point7
0
1
-1000

SWITCH
5
267
108
300
point8
point8
0
1
-1000

SWITCH
5
297
108
330
point9
point9
0
1
-1000

SWITCH
5
328
108
361
point10
point10
0
1
-1000

SWITCH
5
372
108
405
point11
point11
0
1
-1000

SWITCH
5
402
108
435
point12
point12
0
1
-1000

SWITCH
5
432
108
465
point13
point13
0
1
-1000

SWITCH
5
462
108
495
point14
point14
0
1
-1000

SWITCH
5
493
108
526
point15
point15
0
1
-1000

SWITCH
5
524
108
557
point16
point16
0
1
-1000

SWITCH
5
555
108
588
point17
point17
0
1
-1000

SWITCH
5
586
108
619
point18
point18
0
1
-1000

SWITCH
5
617
108
650
point19
point19
0
1
-1000

SWITCH
5
648
108
681
point20
point20
0
1
-1000

INPUTBOX
114
53
164
113
x1
15.0
1
0
Number

INPUTBOX
276
53
326
113
x2
14.3
1
0
Number

INPUTBOX
114
115
164
175
x3
16.7
1
0
Number

INPUTBOX
276
116
326
176
x4
11.5
1
0
Number

INPUTBOX
114
177
164
237
x5
18.0
1
0
Number

INPUTBOX
276
178
326
238
x6
9.7
1
0
Number

INPUTBOX
114
238
164
298
x7
13.7
1
0
Number

INPUTBOX
162
53
212
113
y1
0.8
1
0
Number

INPUTBOX
210
53
260
113
val1
0.0
1
0
Number

INPUTBOX
324
53
374
113
y2
9.3
1
0
Number

INPUTBOX
372
53
422
113
val2
115.0
1
0
Number

INPUTBOX
162
115
212
175
y3
9.3
1
0
Number

INPUTBOX
210
115
260
175
val3
5.0
1
0
Number

INPUTBOX
372
116
422
176
val4
120.0
1
0
Number

INPUTBOX
210
177
260
237
val5
0.0
1
0
Number

INPUTBOX
372
178
422
238
val6
83.0
1
0
Number

INPUTBOX
210
238
260
298
val7
172.0
1
0
Number

INPUTBOX
324
116
374
176
y4
9.4
1
0
Number

INPUTBOX
162
177
212
237
y5
2.2
1
0
Number

INPUTBOX
324
178
374
238
y6
11.6
1
0
Number

INPUTBOX
162
238
212
298
y7
3.2
1
0
Number

INPUTBOX
325
239
375
299
y8
10.7
1
0
Number

INPUTBOX
162
299
212
359
y9
5.0
1
0
Number

INPUTBOX
114
299
164
359
x9
17.2
1
0
Number

INPUTBOX
114
372
164
432
x11
15.8
1
0
Number

INPUTBOX
114
433
164
493
x13
14.2
1
0
Number

INPUTBOX
114
494
164
554
x15
17.7
1
0
Number

INPUTBOX
276
239
326
299
x8
11.5
1
0
Number

INPUTBOX
276
300
326
360
x10
13.1
1
0
Number

INPUTBOX
276
370
326
430
x12
10.8
1
0
Number

INPUTBOX
276
431
326
491
x14
11.2
1
0
Number

INPUTBOX
210
299
260
359
val9
23.0
1
0
Number

INPUTBOX
211
372
261
432
val11
0.0
1
0
Number

INPUTBOX
211
433
261
493
val13
300.0
1
0
Number

INPUTBOX
114
556
164
616
x17
16.3
1
0
Number

INPUTBOX
114
618
164
678
x19
12.3
1
0
Number

INPUTBOX
275
618
325
678
x20
13.2
1
0
Number

INPUTBOX
276
494
326
554
x16
7.0
1
0
Number

INPUTBOX
276
556
326
616
x18
18.9
1
0
Number

INPUTBOX
163
372
213
432
y11
5.0
1
0
Number

INPUTBOX
324
370
374
430
y12
3.3
1
0
Number

INPUTBOX
163
433
213
493
y13
5.0
1
0
Number

INPUTBOX
324
431
374
491
y14
5.3
1
0
Number

INPUTBOX
162
494
212
554
y15
7.0
1
0
Number

INPUTBOX
211
494
261
554
val15
4.0
1
0
Number

INPUTBOX
162
556
212
616
y17
7.4
1
0
Number

INPUTBOX
373
239
423
299
val8
100.0
1
0
Number

INPUTBOX
325
300
375
360
y10
5.4
1
0
Number

INPUTBOX
373
300
423
360
val10
360.0
1
0
Number

INPUTBOX
373
370
423
430
val12
0.0
1
0
Number

INPUTBOX
373
431
423
491
val14
195.0
1
0
Number

INPUTBOX
373
494
423
554
val16
0.0
1
0
Number

INPUTBOX
373
556
423
616
val18
0.0
1
0
Number

INPUTBOX
372
618
422
678
val20
82.0
1
0
Number

INPUTBOX
210
556
260
616
val17
55.0
1
0
Number

INPUTBOX
210
618
260
678
val19
210.0
1
0
Number

INPUTBOX
162
618
212
678
y19
7.9
1
0
Number

INPUTBOX
325
494
375
554
y16
6.8
1
0
Number

INPUTBOX
324
556
374
616
y18
7.0
1
0
Number

INPUTBOX
324
618
374
678
y20
10.6
1
0
Number

BUTTON
342
10
423
43
NIL
contour
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
7
10
82
43
display
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
85
10
183
43
NIL
triangulate
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
442
10
589
43
num-intervals
num-intervals
3
12
6.0
1
1
NIL
HORIZONTAL

MONITOR
599
10
782
55
contours
contour-list
1
1
11

BUTTON
442
195
574
228
Toggle triangles
ask edges [set hidden? not hidden?]
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

MONITOR
440
134
522
179
minimum x
min-pxcor + ceiling (world-width / 4)
1
1
11

MONITOR
522
133
608
178
maximum x
max-pxcor - ceiling (world-width / 4)
1
1
11

MONITOR
618
133
699
178
minimum y
min-pycor + ceiling (world-width / 4)
1
1
11

MONITOR
699
133
784
178
maximum y
max-pycor - ceiling (world-width / 4)
1
1
11

INPUTBOX
514
62
594
122
alt-min-val
1.0
1
0
Number

INPUTBOX
676
62
758
122
alt-max-val
2.0
1
0
Number

MONITOR
441
62
513
107
Min Value
min [value] of points with [not hidden?]
2
1
11

MONITOR
600
63
674
108
Max value
max [value] of points with [not hidden?]
2
1
11

SWITCH
584
235
696
268
show3D?
show3D?
1
1
-1000

BUTTON
582
195
699
228
Toggle points
ask points [set size ifelse-value (size = baseptsize) [.1][baseptsize]]\nask points [set label ifelse-value (label = value) [\"\"][value]]
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SWITCH
443
370
548
403
point21
point21
0
1
-1000

SWITCH
443
401
548
434
point22
point22
0
1
-1000

SWITCH
443
432
548
465
point23
point23
0
1
-1000

SWITCH
443
463
548
496
point24
point24
0
1
-1000

SWITCH
443
494
548
527
point25
point25
0
1
-1000

SWITCH
443
525
548
558
point26
point26
0
1
-1000

SWITCH
443
557
548
590
point27
point27
0
1
-1000

SWITCH
443
588
548
621
point28
point28
0
1
-1000

SWITCH
443
619
548
652
point29
point29
0
1
-1000

SWITCH
443
651
548
684
point30
point30
0
1
-1000

INPUTBOX
553
370
603
430
x21
9.7
1
0
Number

INPUTBOX
553
431
603
491
x22
15.4
1
0
Number

INPUTBOX
553
492
603
552
x23
14.2
1
0
Number

INPUTBOX
553
553
603
613
x24
18.8
1
0
Number

INPUTBOX
553
614
603
674
x25
12.2
1
0
Number

INPUTBOX
713
369
763
429
x26
9.8
1
0
Number

INPUTBOX
713
430
763
490
x27
5.7
1
0
Number

INPUTBOX
713
491
763
551
x28
15.6
1
0
Number

INPUTBOX
712
552
762
612
x29
7.4
1
0
Number

INPUTBOX
712
613
762
673
x30
17.5
1
0
Number

INPUTBOX
602
370
652
430
y21
15.3
1
0
Number

INPUTBOX
602
431
652
491
y22
7.6
1
0
Number

INPUTBOX
602
492
652
552
y23
12.5
1
0
Number

INPUTBOX
602
553
652
613
y24
8.8
1
0
Number

INPUTBOX
602
614
652
674
y25
6.6
1
0
Number

INPUTBOX
761
369
811
429
y26
0.2
1
0
Number

INPUTBOX
761
430
811
490
y27
4.1
1
0
Number

INPUTBOX
761
491
811
551
y28
3.7
1
0
Number

INPUTBOX
761
551
811
611
y29
13.7
1
0
Number

INPUTBOX
760
613
810
673
y30
3.0
1
0
Number

INPUTBOX
651
370
701
430
val21
32.0
1
0
Number

INPUTBOX
651
431
701
491
val22
245.0
1
0
Number

INPUTBOX
651
492
701
552
val23
0.0
1
0
Number

INPUTBOX
650
553
700
613
val24
0.0
1
0
Number

INPUTBOX
650
614
700
674
val25
375.0
1
0
Number

INPUTBOX
810
369
860
429
val26
0.0
1
0
Number

INPUTBOX
810
430
860
490
val27
0.0
1
0
Number

INPUTBOX
810
489
860
549
val28
0.0
1
0
Number

INPUTBOX
810
551
860
611
val29
64.0
1
0
Number

INPUTBOX
810
613
860
673
val30
0.0
1
0
Number

SWITCH
443
235
581
268
fit-to-frame?
fit-to-frame?
0
1
-1000

@#$#@#$#@
## WHAT IS IT?

This model constructs an isopleth (or "contour") map of a value that varies in 2-dimensional space, interpolating from a set of up to 30 values and associated coordinates. 

## HOW IT WORKS

The model first divides the 2-dimensional space into triangles with vertices at each coordinate pair in the "point set". These triangles are created such that the minimum angle of each triangle is maximized, which avoids sliver triangles (thin triangles with two highly acute angles). This construction, known as a Delaunay Triangulation, also has the defining characteristic that the circumcircle of every triangle contains none of the (other) points in the set.

The model uses the Bowyer-Watson algorithm for computing the Delaunay triangulation, establishing four points in a "super square" around the original point set, and then incrementally considering each point within the square, removing and adding connections to maintain a viable triangulation. The added vertices are then removed from consideration leaving the desired triangulation.

The sides of each triangular element are then divided into increments using linear interpolation that compares the values at each vertex to the distances between.  Increments of similar value along each side of a triangle are then connected with segments to create lines of equal value, i.e. isopleths or contour lines.


## HOW TO USE IT

X1,Y1,X2,Y2,...: The user can enter a desired set of coordinates into the provided input boxes being sure that the values stay within the range listed as 'minimum x','maximum x','minimum y' and 'maximum y' in the monitors below the viewscreen. Each ordered pair should also be unique. Screen size can be expanded using SETTINGS which will be reflected in the min-max monitors.

POINT1, POINT2, ...: Each spatial point can be toggled ON or OFF using the switch to have the point included in (ON) or excluded from (OFF) the point set, but note that each active point should have a unique location to avoid an error message.

VAL1, VAL2,...: These input boxes are provided to associate a scalar value with each spatial point.  These are values that will be interpolated to create the contour map.

DISPLAY: When pressed, just displays all the active points with an identifying label

TRIANGULATE: When pressed, displays all the active points with an identifying label and then calculates and displayes the Delaunay triangulation of the active spatial points. Intermediate triangulations following the Bowyer-Watson algorithm are temporarily displayed but may not be visible unless the model is adjusted to a slower speed.

CONTOUR: When pressed, calculates a series of intervals based on the value of the NUM-INTERVALS slider and displays isopleth values for each interval boundary in the 'contours' monitor (one more than the number of intervals).  It then constructs and displays isopleths in the triangulation with labels.  Only functions if a triangulation has been already computed, but will recalculate new contours if adjustments have been made to VAL# values.

NUM-INTERVALS: Establishes the number of intervals to be visualized with contour lines, spaced at equal intervals between the minimum and maximum active values in the point set OR the range values specified by ALT-MIN-VAL and ALT-MAX-VAL. Note that the interval is rounded to 3 significant digits.

ALT-MIN-VAL: Establishes an alternative value for the lowest value contour line, only if it is less than the smallest of the current active data points (as displayed in the 'Min value' monitor).

ALT-MAX-VAL: Establishes an alternative value for the highest value contour line, only if it is greater than the largest of the current active data points (as displayed in the 'Max value' monitor).

TOGGLE TRIANGLES: When pressed, renders the triangulation lines invisible (or visible), allowing for better view of the contour lines.

TOGGLE POINTS: When pressed, renders the data point markers and labels invisible (or visible), allowing for better view of triangulation and/or contour lines.

FIT-TO-FRAME?: If ON when DISPLAY or TRIANGULATE is pressed, the data points will be scaled in the x and y dimensions and recentered in the 3D View

SHOW3D?: If OFF when DISPLAY or TRIANGULATE is pressed, the data points will be plotted with a z-coordinate value of 0.  If ON, each point will be plotted with a z-coordinate scaled to the associated value.

## THINGS TO TRY

Adjust the speed slider towards "slower" to watch a visualization of the Bowyer-Watson calculation.  

Gather data (eg. precipitation, temperature, elevation) from an online resource or classroom experiment and create a contour plot.  Note that you may need to scale units, particularly the spatial coordinates.

Turn many of the points in a data set "Off" and generate a contour with limited data.
Turn some of the points back "On" and regenerate the contour.  Consider how the addition of data changes the contour and the estimated values in other spatial locations.

## NETLOGO FEATURES

Each point in the point-set is associated with a mobile agent (a turtle of breed "point") and triangle sides and isolines are established as undirected links (of breed "edge" and "iso"). Additional agents of breed "triangle" are created to establish connectivity and to facilitate the logic for determining whether a point is within the circumcircle of a given triangle (by comparing the distance of that point from the circumcenter of the triangle to the radius of the circumcircle).

The model makes extensive use of anonymous procedures ("->" syntax) to deal with the sets of different agent types.


## AUTHORSHIP
Created Jan 2018
Garrett Love, Ph.D.
Engineering Instructor
NC School of Science and Math

This work supported by the National Science Foundation
STEM + C Award 1543228
Comp Hydro: Integrating data, computation, and visualization for model-based water literacy

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/4.0/.

## CREDITS AND REFERENCES

En.wikipedia.org. (2017). Bowyer–Watson algorithm. [online] Available at: https://en.wikipedia.org/wiki/Bowyer-Watson_algorithm [Accessed 20 Dec. 2017].

Bowyer, Adrian (1981). "Computing Dirichlet tessellations". Comput. J. 24 (2): 162–166. 

Watson, David F. (1981). "Computing the n-dimensional Delaunay tessellation with application to Voronoi polytopes". Comput. J. 24 (2): 167–172. 
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
15
Circle -1 true true 203 65 88
Circle -1 true true 70 65 162
Circle -1 true true 150 105 120
Polygon -7500403 true false 218 120 240 165 255 165 278 120
Circle -7500403 true false 214 72 67
Rectangle -1 true true 164 223 179 298
Polygon -1 true true 45 285 30 285 30 240 15 195 45 210
Circle -1 true true 3 83 150
Rectangle -1 true true 65 221 80 296
Polygon -1 true true 195 285 210 285 210 240 240 210 195 210
Polygon -7500403 true false 276 85 285 105 302 99 294 83
Polygon -7500403 true false 219 85 210 105 193 99 201 83

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

wolf
false
0
Polygon -16777216 true false 253 133 245 131 245 133
Polygon -7500403 true true 2 194 13 197 30 191 38 193 38 205 20 226 20 257 27 265 38 266 40 260 31 253 31 230 60 206 68 198 75 209 66 228 65 243 82 261 84 268 100 267 103 261 77 239 79 231 100 207 98 196 119 201 143 202 160 195 166 210 172 213 173 238 167 251 160 248 154 265 169 264 178 247 186 240 198 260 200 271 217 271 219 262 207 258 195 230 192 198 210 184 227 164 242 144 259 145 284 151 277 141 293 140 299 134 297 127 273 119 270 105
Polygon -7500403 true true -1 195 14 180 36 166 40 153 53 140 82 131 134 133 159 126 188 115 227 108 236 102 238 98 268 86 269 92 281 87 269 103 269 113

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270
@#$#@#$#@
NetLogo 3D 6.0.4
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180
@#$#@#$#@
0
@#$#@#$#@