;;;;;;;;;;;;
;; BREEDS ;;
;;;;;;;;;;;;

breed [librarygoers librarygoer]
breed [noisemakers noisemaker]
breed [librarians librarian]

;;;;;;;;;;;;;;;
;; VARIABLES ;;
;;;;;;;;;;;;;;;

globals ; note: these are all in the interface but included here for readability
[
;  initial-librarygoers
;  initial-noisemakers
;  regulation-mode
]

librarygoers-own
[ state               ; "seated", "relocating", "entering", or "leaving"
  target-destination  ; the patch the agent is moving toward
  noise-threshold     ; max amount of perceived noise a librarygoer can coexist with
  shush-threshold  ; noise level reached for a librarygoer to become confrontational
  time-under-noise ]  ; how long a librarygoer has been subject to unacceptable noise

noisemakers-own
[ state               ; "seated", "entering", or "leaving"
  target-destination  ; the patch the agent is moving toward
  making-noise?       ; whether or not noisemaker is currently being noisy
  loudness            ; amount of noise emitted by noisemaker
  time-after-shushed  ; ticks passed after having been shushed
  shushed-count ]     ; number of times noisemaker has been shushed

patches-own
[ patch-noisiness ]   ; audible level of noise at each patch

;;;;;;;;;;;;;;;;;;;;;;
;; SETUP PROCEDURES ;;
;;;;;;;;;;;;;;;;;;;;;;

to setup
  ca
  reset-ticks
  draw-library                                                 ; set up library
  setup-existing-turtles                                       ; create turtles based on numbers set in interface
  ask patches [ set patch-noisiness 0 ]                        ; resetting patch noisiness
  if regulation-mode = "librarian" or regulation-mode = "both" ; creating librarian based on regulation mode
  [ setup-librarian ]
end


to setup-existing-turtles                   ; context: observer, in go
  create-librarygoers initial-librarygoers  ; initialising librarygoers and their variables
  [ set-lg-defaults
    set state "seated"
    set target-destination nobody ]
  create-noisemakers initial-noisemakers    ; initialising noisemakers and their variables
  [ set-nm-defaults
    set state "seated"
    set target-destination nobody ]
  carefully                                 ; seating turtles if there are available seats. otherwise, display error message
  [ ask turtles
    [ move-to one-of patches with [pcolor = 2 and not any? turtles-here] ] ]
  [ user-message (word "Library capacity ("count patches with [pcolor = 2]" seats) exceeded! Please reduce number of librarygoers or noisemakers.")]
end

to setup-librarian                   ; context: observer, in go
  ask patch -15.5 -15.5              ; spawning librarian at librarian's desk and initialising their variables
  [ sprout-librarians 1
    [ set shape "person student"
      set color green
      set size 2 ]
  ]
end

;;;;;;;;;;;;;;;;;;;
;; GO PROCEDURES ;;
;;;;;;;;;;;;;;;;;;;

to go
  update-patch-noisiness  ; update audible noise level at each patch
  check-noise             ; librarygoers and/or librarian assess noise and decide course of action
  noisy-again             ; noisemakers may resume noise after being shushed
  check-shushed-count     ; check how many times noisemakers have been shushed
  update-visuals          ; update visuals based on states/noise
  move                    ; agents move to target-destination, if any
  tick
end

to check-noise  ; context: observer, in go
  if member? regulation-mode ["librarygoers" "both"]               ; if both librarygoers and librarians can shush
  [ ask librarygoers with [ state = "seated" ]
    [ ifelse [ patch-noisiness ] of patch-here >= noise-threshold  ; first, check if perceived noise exceeds their tolerable noise level

      [ set time-under-noise time-under-noise + 1                  ; second, update how long librarygoers have been subject to noise above their threshold
                                                                   ; this allows them to assess if the noise is a persistent situation...
                                                                   ; ...so that they are not overly trigger-happy to leave or shush noisemakers

        if time-under-noise >= 15                                  ; third, check if perceived noise is high AND persistent (>= 15 ticks) enough to motivate them to shush noisemakers...
                                                                   ; ...otherwise, librarygoers vacate their seat
        [ ifelse [patch-noisiness] of patch-here >= shush-threshold
          [ shush ]
          [ relocate-or-leave ] ] ]
      [ set time-under-noise 0 ] ] ]                               ; remains at 0 if noise level is acceptable

  if member? regulation-mode ["librarian" "both"]
  [ ask librarians
    [ let valid-patches neighbors with            ; librarians move around valid patches at random...
      [ pcolor != 2 and                           ; not tables
        pcolor != 108 and                         ; not seats
        not any? other turtles-here]              ; no other agents
      ifelse patch-ahead 1 != nobody and member? patch-ahead 1 valid-patches
      [ fd 0.5 ]
      [ let next-patch one-of valid-patches
       face next-patch
       fd 0.5 ]
      shush ] ]                                   ; ... and shush noisy noisemakers

  if regulation-mode = "none"
  [ ask librarygoers with [ state = "seated" ]
    [ ifelse [ patch-noisiness ] of patch-here >= noise-threshold  ; first, check if perceived noise exceeds their tolerable noise level
      [ set time-under-noise time-under-noise + 1
     if time-under-noise >= 15
        [ relocate-or-leave ] ]
      [ set time-under-noise 0 ] ] ]
end


to shush  ; context: librarians and/or librarygoers, depending on regulation mode
  let target nobody                                                   ; initialising temporary variable for noisy noisemaker to be shushed
  let og-color color                                                  ; storing librarygoer's and librarian's original colour for use in flashing procedure

  ifelse is-librarygoer? self
  [ set target min-one-of noisemakers with                            ; librarygoers target the nearest noisy noisemaker
    [ state = "seated" and making-noise? = true] [distance myself] ]
  [ set target one-of noisemakers with                                ; librarians target any noisy noisemaker they come into contact with while patrolling
    [ state = "seated" and making-noise? = true] in-radius 3 ]

  if target != nobody
  [ repeat 2                  ; librarian/librarygoers flash orange twice when shushing a noisemaker
  [ set color orange
    wait 0.2
    set color og-color
    wait 0.2 ]

  ask target                  ; targeted noisemaker shuts up for now
  [ set making-noise? false
    set loudness 0
    set time-after-shushed 0
    set shushed-count shushed-count + 1 ] ]
end


to relocate-or-leave  ; context: seated librarygoers
  let avail-seats patches with
  [ pcolor = 2 and not any? turtles-here ]                  ; librarygoers look for available seats
  let good-seats avail-seats with
  [ patch-noisiness < [ noise-threshold ] of myself ]       ; of the available seats, find those with an acceptably low noise level
  ifelse any? good-seats                                    ; decide to relocate to the nearest quiet seats if any are available
  [ let new-seat min-one-of good-seats [ distance myself ]
    set target-destination new-seat
    set state "relocating" ]
  [ set target-destination one-of patches with [pcolor = 5] ; decide to leave if no quiet seats available
    set state "leaving" ]
end

to noisy-again  ; context: observer, in go
  ask noisemakers with [ making-noise? = false ]            ; update how many ticks since being shushed
  [ set time-after-shushed time-after-shushed + 1 ]
  ask noisemakers with
  [ making-noise? = false and time-after-shushed >= 10 ]    ; after 10 ticks, shushed noisemakers may resume being noisy with 50% probability
    [ if random-float 1 < 0.5
      [ set making-noise? true                              ; if so, noisemaking variables are reinstated
        set loudness random-in-range 40 80
        set time-after-shushed 0 ] ]
end

to check-shushed-count                                      ; context: observer, in go
  ask noisemakers with [ shushed-count >= 3 ]               ; noisemakers leave if they have been shushed thrice
  [ set target-destination one-of patches with [ pcolor = 5 ]
    set state "leaving" ]
end

to update-visuals  ; context: observer, in go
  ask librarygoers                              ; as a rule, librarygoers are always white, are happy at an acceptable noise level and sad otherwise.
  [ if state = "entering"                       ; noisemakers are red and happy when they're noisy; white and sad when they are shut up.
    [ set color white
      set shape "face happy" ]

    if state = "seated"
    [ set color white
      ifelse patch-noisiness > noise-threshold
      [ set shape "face sad" ]
      [ set shape "face happy" ] ]

    if state = "relocating"                     ; relocating agents are blue for visibility
    [ set color blue
      set shape "face sad" ]

    if state = "leaving"
    [ set color white
      set shape "face sad" ] ]

  ask noisemakers
  [ ifelse making-noise? = true
    [ set color red
      set shape "face happy" ]
    [ set color white
      set shape "face sad"]

    if state = "entering"
    [ set color red
      set shape "face happy" ]

    if state = "leaving"
    [ set color red
      set shape "face sad" ] ]
end

to update-patch-noisiness  ; context: observer, in go
  ask patches
  [ let total-noise 0                                             ; placeholder initialising value for audible noise at patch
    ask noisemakers with [ state = "seated" and making-noise? = true ]
    [ let distance-decay (1 / sqrt (1 + distance myself))         ; aggregating noise from seated noisy noisemakers, incorporating distance decay function...
      set total-noise total-noise + (loudness * distance-decay) ] ; ...so that audible noise decreases as we move further from a noisy noisemaker
    set patch-noisiness total-noise ]
end

to move  ; context: observer, in go. directed towards agents entering, relocating, or leaving
ask (turtle-set librarygoers with [ state = "relocating" or state = "entering" ] noisemakers with [ state = "relocating" or state = "entering" ])
  [ if any? other turtles-on target-destination       ; checking again if seat has been taken while moving towards it
    [ let new-seat one-of patches with [ pcolor = 2 and not any? other turtles-here ]
      ifelse new-seat != nobody
      [ set target-destination new-seat ]
      [ user-message (word "Couldn't find a seat! Please try again.") ] ]

    if not any? other turtles-on target-destination
    [ ifelse distance target-destination < 1          ; agents stop when they reach target seat, resetting state and target destination
      [ move-to target-destination
        set state "seated"
        set target-destination nobody ]
      [ find-path ] ] ]                               ; else, agents execute pathfinding to their target seat

ask (turtle-set librarygoers with [state = "leaving"] noisemakers with [state = "leaving"])
  [ ifelse distance target-destination < 1
    [ move-to target-destination ; leaving agents stop and leave the library when they reach target
      die ]
    [ find-path ] ]              ; else, agents execute pathfinding to the exit
end

to find-path  ; context: any agents that haven't yet reached their target destination
  let current-distance distance target-destination     ; first, establish current distance from target
  let possible-steps patches in-radius 4 with          ; second, assess all valid next patches (note: in-radius 4 is best to go AROUND the table if blocked)
    [ pcolor != 108 and                                  ; not the table
      (not any? neighbors with [pcolor = 108]            ; not passing through table-adjacent patches (i.e. seats)
        or self = [target-destination] of myself) and    ; UNLESS it's the target seat
      not any? other turtles-here and                    ; checking for no other agents
      self != [patch-here] of myself ]                   ; avoiding doubling back on route

  if any? possible-steps                             ; third, identify all patches closer to destination
  [ let efficient-steps possible-steps with [distance [target-destination] of myself < current-distance]

    ifelse any? efficient-steps                      ; fourth, pick the patch closest to destination
      [ let next-step min-one-of efficient-steps [distance [target-destination] of myself]
        face next-step                               ; finally, move in the direction of the identified best patch
        carefully
        [ fd 1 ]
        [ right random 360                           ; if cannot move forward, turn in random direction and try again
          fd 1 ] ]

      [ let next-step min-one-of possible-steps [distance [target-destination] of myself] ; if there are no patches offering a shorter direct distance to target-destination, ...
        face next-step                                                                    ; agent chooses from all valid patches and moves in target's general direction
        carefully
        [ fd 1 ]
        [ right random 360
          fd 1 ] ] ]
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ADDING NEW AGENTS (interface buttons) ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to add-librarygoer  ; context: observer, in interface
  let available-seats patches with [pcolor = 2 and not any? turtles-here] ; identifying available seats
  ifelse total-people < library-capacity                                  ; first, check that library capacity has not been exceeded
  [ ask one-of patches with [pcolor = 5]                                  ; second, spawn at entrance and set attributes
    [ sprout-librarygoers 1
      [ set state "entering"
        set-lg-defaults
        set target-destination one-of available-seats ] ] ]               ; librarygoer chooses an available seat at random

  [ user-message (word "Library capacity ("count patches with [pcolor = 2]" seats) exceeded! Please reduce number of librarygoers or noisemakers.")]
end

to add-noisemaker  ; context: observer, in interface
  let available-seats patches with [pcolor = 2 and not any? turtles-here] ; identifying available seats
  ifelse total-people < library-capacity                                  ; first, check that library capacity has not been exceeded
  [ ask one-of patches with [pcolor = 5]                                  ; second, spawn at entrance and set attributes
    [ sprout-noisemakers 1
      [ set state "entering"
        set-nm-defaults
        set target-destination one-of available-seats ] ] ]               ; noisemaker chooses an available seat at random
  [ user-message (word "Library capacity ("count patches with [pcolor = 2]" seats) exceeded! Please reduce number of librarygoers or noisemakers.")]
end

to add-librarian  ; context: observer, in interface
  ask patch -15.5 -15.5
  [ sprout-librarians 1
    [ set-lib-defaults ] ]
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; AGENT DEFAULT SETTINGS ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to set-lg-defaults  ; default variable values for librarygoers
  set shape "face happy"
  set color white
  set time-under-noise 0
  set noise-threshold random-in-range 35 85
  set shush-threshold random-in-range 35 85
end

to set-nm-defaults  ; default variable values for noisemakers
  set shape "face happy"
  set color red
  set making-noise? true
  set loudness random-in-range 40 80
  set time-after-shushed 0
  set shushed-count 0
end

to set-lib-defaults  ; default visuals for librarians
  set shape "person student"
  set color green
  set size 2
end

;;;;;;;;;;;;;;;
;; REPORTERS ;;
;;;;;;;;;;;;;;;

to-report random-in-range [low high]  ; for utility
  report low + random (high - low + 1)
end


to-report mean-noise-level  ; average noise level of all patches
  let total-noise sum [patch-noisiness] of patches
  let patch-count count patches
  report total-noise / patch-count
end

to-report library-capacity  ; i.e. total number of seats
  report count patches with [pcolor = 2]
end

to-report total-people  ; all library patrons
  report count librarygoers + count noisemakers
end

;;;;;;;;;;;;;;;;;;;
;; LIBRARY SETUP ;;
;;;;;;;;;;;;;;;;;;;

to draw-library ; note: world is square of [-16,16]
  ; tables
  ask patches with [(pxcor > -5) and (pxcor < 5) and (pycor > 4) and (pycor < 10)]
  [ set pcolor 108 ]

  ask patches with [(pxcor > -5) and (pxcor < 5) and (pycor > -10) and (pycor < -4)]
  [ set pcolor 108 ]

  ; seats for top table
  ask patch -5 8 [set pcolor 2]
  ask patch -5 6 [set pcolor 2]
  ask patch -3 10 [set pcolor 2]
  ask patch -3 4 [set pcolor 2]
  ask patch -1 10 [set pcolor 2]
  ask patch -1 4 [set pcolor 2]
  ask patch 1  10 [set pcolor 2]
  ask patch 1  4 [set pcolor 2]
  ask patch 3  10 [set pcolor 2]
  ask patch 3  4 [set pcolor 2]
  ask patch 5 8  [set pcolor 2]
  ask patch 5 6  [set pcolor 2]

  ; seats for bottom table
  ask patch -5 -8  [set pcolor 2]
  ask patch -5 -6  [set pcolor 2]
  ask patch -3 -4  [set pcolor 2]
  ask patch -3 -10 [set pcolor 2]
  ask patch -1 -4  [set pcolor 2]
  ask patch -1 -10 [set pcolor 2]
  ask patch 1  -4  [set pcolor 2]
  ask patch 1  -10 [set pcolor 2]
  ask patch 3  -4  [set pcolor 2]
  ask patch 3  -10 [set pcolor 2]
  ask patch 5  -6  [set pcolor 2]
  ask patch 5  -8  [set pcolor 2]

  ; entrance/exit
  ask patches with [(pxcor = -16) and (pycor > -2) and (pycor < 2)] [ set pcolor 5 ]

  ; librarian's desk
  ask patches with [(pxcor < -14) and (pycor < -14)] [ set pcolor 52 ]
end
@#$#@#$#@
GRAPHICS-WINDOW
195
10
730
546
-1
-1
15.97
1
10
1
1
1
0
0
0
1
-16
16
-16
16
0
0
1
ticks
30.0

BUTTON
58
323
124
356
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
19
382
82
415
step
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
99
382
162
415
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
577
567
710
600
NIL
add-noisemaker
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
389
567
520
600
NIL
add-librarygoer\n
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

CHOOSER
13
254
188
299
regulation-mode
regulation-mode
"librarygoers" "librarian" "both" "none"
3

SLIDER
12
130
184
163
initial-librarygoers
initial-librarygoers
0
24
5.0
1
1
NIL
HORIZONTAL

SLIDER
13
193
185
226
initial-noisemakers
initial-noisemakers
0
24
1.0
1
1
NIL
HORIZONTAL

BUTTON
212
567
325
600
NIL
add-librarian
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

PLOT
748
300
1045
463
Average Noise Level
Time
Noise
0.0
10.0
0.0
100.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" "plot mean-noise-level"

PLOT
749
100
1044
281
Quiet vs Noisy Folk
Time
Count
0.0
10.0
0.0
10.0
true
true
"" ""
PENS
"Noisy" 1.0 0 -2674135 true "" "plot count noisemakers with [making-noise? = true]"
"Quiet" 1.0 0 -13791810 true "" "plot count librarygoers + count noisemakers with [making-noise? = false]"

MONITOR
748
37
1049
82
Proportion of noisy people
(count noisemakers with [making-noise? = true]) / total-people
17
1
11

@#$#@#$#@
## WHAT IS IT?

This model simulates people in a library and how they respond to others disregarding or enforcing the expectation of silence. It can be interpreted as a way of modelling how dominant social norms affect who is welcome and who is made to leave in a society. The optional presence of a librarian simulates the effect of an enforcing authority in regulating population behaviour.

## HOW IT WORKS

At setup, user-determined starting numbers of quiet agents (LIBRARYGOERS) and noisy agents (NOISEMAKERS) are placed at random seats in the library. Buttons are also available to add additional LIBRARYGOERS or NOISEMAKERS, as long as there are available seats. Once seated, at each tick, LIBRARYGOERS assess the perceivable noise level at their seat, based on any NOISEMAKERS in the vicinity. If it is unacceptably high, they may shush the nearest NOISEMAKER if it is noisy enough for them to become confrontational. Otherwise, they leave their seat in favour of an acceptably quiet one, or leave the library if there are none. 

LIBRARIANS patrol the library in a random route and shush any NOISEMAKERS upon seeing them.

NOISEMAKERS, upon being shushed, have a 50-50 chance of staying quiet or resuming making noise. Upon being shushed thrice, they too grow upset and leave the library.


## HOW TO USE IT

Set the INITIAL-LIBRARYGOERS and INITIAL-NOISEMAKERS sliders before pressing SETUP to initiate the model with a starting number of each. LIBRARYGOERS are initialised with random noise tolerance thresholds and confrontation thresholds. NOISEMAKERS are initialised with random loudness.

Choose a REGULATION-MODE: "LIBRARYGOERS" mode means that library occupants self-enforce silence via quiet LIBRARYGOERS shushing NOISEMAKERS; "LIBRARIAN" mode means that all shushing is done by LIBRARIANS only; "BOTH" means that both LIBRARYGOERS and LIBRARIANS shush NOISEMAKERS; "NONE" means that nobody shushes NOISEMAKERS.

The buttons "ADD-LIBRARYGOER/NOISEMAKER/LIBRARIAN" introduces one member of the specified type to the library. Added LIBRARYGOERS/NOISEMAKERS route to a random available seat (space allowing) while added LIBRARIANS spawn at the librarian's desk and start patrolling the library.

Press SETUP to create the library and its occupants. GO runs the simulation continuously. STEP runs one tick.

The two plots show the populations of quiet (including shushed NOISEMAKERS) and noisy people over time, and the average noise level of the library's patches over time.


## THINGS TO NOTICE

Depending on the selected REGULATION-MODE, how NOISEMAKERS survive in the space differs. LIBRARYGOERS only intervene when their confrontational noise threshold has been crossed; otherwise, they simply choose to remove themselves from the situation by changing seats or leaving the library. NOISEMAKERS may thus be permitted to stay if the LIBRARYGOERS present have a high enough noise threshold to tolerate them.  On the other hand, LIBRARIANS shush any noisy NOISEMAKER they spot, so NOISEMAKERS eventually all leave the library upon multiple shushings from the LIBRARIAN.

## THINGS TO TRY

Try varying the INITIAL-LIBRARYGOERS and INITIAL-NOISEMAKERS populations, as well as the presence of a LIBRARIAN, or more than one LIBRARIAN. These affect how well LIBRARYGOERS and NOISEMAKERS survive in the library.

## EXTENDING THE MODEL

One way this model could be extended is to incorporate peer influence dynamics: NOISEMAKERS could have a higher propensity for re-offending (being noisy again after being shushed) if there are other NOISEMAKERS nearby, emboldening them. Conversely, if quiet LIBRARYGOERS outnumber NOISEMAKERS, they could be pressured to remain quiet while LIBRARYGOERS would be more likely (i.e. confident) to shush the non-conforming NOISEMAKER. 
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

exclamation
false
0
Circle -7500403 true true 103 198 95
Polygon -7500403 true true 135 180 165 180 210 30 180 0 120 0 90 30

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

person student
false
0
Polygon -13791810 true false 135 90 150 105 135 165 150 180 165 165 150 105 165 90
Polygon -7500403 true true 195 90 240 195 210 210 165 105
Circle -7500403 true true 110 5 80
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Polygon -1 true false 100 210 130 225 145 165 85 135 63 189
Polygon -13791810 true false 90 210 120 225 135 165 67 130 53 189
Polygon -1 true false 120 224 131 225 124 210
Line -16777216 false 139 168 126 225
Line -16777216 false 140 167 76 136
Polygon -7500403 true true 105 90 60 195 90 210 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
15
Circle -1 true true 203 65 88
Circle -1 true true 70 65 162
Circle -1 true true 150 105 120
Polygon -7500403 true false 218 120 240 165 255 165 278 120
Circle -7500403 true false 214 72 67
Rectangle -1 true true 164 223 179 298
Polygon -1 true true 45 285 30 285 30 240 15 195 45 210
Circle -1 true true 3 83 150
Rectangle -1 true true 65 221 80 296
Polygon -1 true true 195 285 210 285 210 240 240 210 195 210
Polygon -7500403 true false 276 85 285 105 302 99 294 83
Polygon -7500403 true false 219 85 210 105 193 99 201 83

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

wolf
false
0
Polygon -16777216 true false 253 133 245 131 245 133
Polygon -7500403 true true 2 194 13 197 30 191 38 193 38 205 20 226 20 257 27 265 38 266 40 260 31 253 31 230 60 206 68 198 75 209 66 228 65 243 82 261 84 268 100 267 103 261 77 239 79 231 100 207 98 196 119 201 143 202 160 195 166 210 172 213 173 238 167 251 160 248 154 265 169 264 178 247 186 240 198 260 200 271 217 271 219 262 207 258 195 230 192 198 210 184 227 164 242 144 259 145 284 151 277 141 293 140 299 134 297 127 273 119 270 105
Polygon -7500403 true true -1 195 14 180 36 166 40 153 53 140 82 131 134 133 159 126 188 115 227 108 236 102 238 98 268 86 269 92 281 87 269 103 269 113

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270
@#$#@#$#@
NetLogo 6.4.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180
@#$#@#$#@
0
@#$#@#$#@